pack_pgd.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE pack_pgd (DTCO, U, HPROGRAM, HSURF, G, OCOVER, PCOVER, PZS, PDIR     )  
!     ##############################################################
!
!!**** *PACK_PGD* packs ISBA physiographic fields from all surface points to ISBA points
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    03/2004
!!    Escobar J.  08/02/2005 : bug declare ILU local variable
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
USE modd_sfx_grid_n, ONLY : grid_t
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_pgd_grid,       ONLY : nl, cgrid, xgrid_par
!
USE modd_data_cover_par, ONLY : jpcover
!
USE modi_get_cover_n
USE modi_get_lcover_n
USE modi_get_zs_n
USE modi_pack_same_rank
USE modi_pack_grid
USE modi_latlon_grid
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_get_surf_mask_n
!
USE modi_get_type_dim_n
!
USE modi_get_luout
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(grid_t), INTENT(INOUT) :: G
!
 CHARACTER(LEN=6),        INTENT(IN) :: HPROGRAM  ! Type of program
 CHARACTER(LEN=6),        INTENT(IN) :: HSURF     ! surface type
!
LOGICAL, DIMENSION(:),   INTENT(OUT):: OCOVER    ! list of present cover
REAL,    DIMENSION(:,:), POINTER :: PCOVER    ! cover fraction
REAL,    DIMENSION(:),   INTENT(OUT):: PZS       ! zs
REAL,    DIMENSION(:),   INTENT(OUT), OPTIONAL :: PDIR ! angle of grid axis with N.
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER                        :: ILUOUT ! output listing logical unit
INTEGER                        :: IL     ! number of points
INTEGER                        :: ILU    ! expected physical size of full surface array
INTEGER                        :: JCOVER
INTEGER, DIMENSION(:), POINTER :: IMASK  ! mask for packing from complete field to nature field
REAL,    DIMENSION(SIZE(G%XLAT)) :: ZDIR
!
REAL, DIMENSION(NL)    :: ZCOVER ! cover  on all surface points
REAL, DIMENSION(NL)            :: ZZS    ! zs     on all surface points
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('PACK_PGD',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
!*    1.      Number of points and packing
!             ----------------------------
!
 CALL get_type_dim_n(dtco, u, hsurf,il)
!
ALLOCATE(imask(il))
ilu=0
 CALL get_surf_mask_n(dtco, u, hsurf,il,imask,ilu,iluout)
!
!-------------------------------------------------------------------------------
!
!*    2.      Packing of grid
!             ---------------
!
 CALL pack_grid(imask,cgrid,g%CGRID,xgrid_par,g%XGRID_PAR)
!
 CALL get_lcover_n(u,hprogram,jpcover,ocover)
!
IF (il==0) THEN
  ALLOCATE(pcover(0,0)) 
  IF (lhook) CALL dr_hook('PACK_PGD',1,zhook_handle)
  RETURN
ENDIF
!
!-------------------------------------------------------------------------------
!
!*    3.      Computes geographical quantities
!             --------------------------------
!
 CALL latlon_grid(g,il,zdir)
!
IF (PRESENT(pdir)) pdir = zdir
!
!-------------------------------------------------------------------------------
!
!*    4.      Packing of fields
!             -----------------
!
IF (hsurf=='NATURE') THEN
  !
  ALLOCATE(pcover(SIZE(g%XLAT),count(ocover)))
  !
  DO jcover=1,count(ocover)
    CALL get_cover_n(u,hprogram,jcover,zcover)
    CALL pack_same_rank(imask,zcover(:),pcover(:,jcover))
  ENDDO
  !
ELSE
  !
  ALLOCATE(pcover(0,0))
  !
ENDIF
!
 CALL get_zs_n(u, hprogram,nl,zzs)
!
!
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
 CALL pack_same_rank(imask,zzs(:),pzs(:))
!
!-------------------------------------------------------------------------------
!
DEALLOCATE(imask)
!
IF (lhook) CALL dr_hook('PACK_PGD',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE pack_pgd