fandar.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe FA
SUBROUTINE fandar_fort                           &
&                     (fa,  krep, knumer, kdatef)
USE fa_mod, ONLY : fa_com
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!      Sous-programme de definition d'une (Nouvelle) Date sur un fichier
!     ARpege.
!**
!    Arguments : KREP   (Sortie) ==> Code-reponse du sous-programme;
!                KNUMER (Entree) ==> Numero de l'unite logique;
!     (Tableau)  KDATEF (Entree) ==> Date elle-meme (FA%JPLDAT mots).
!*
!        En cas de modification effective (si le fichier etait deja muni
!     d'une date), il y a messagerie de niveau 1.
!
!
!
TYPE(fa_com) :: FA
INTEGER (KIND=JPLIKB) KREP, KNUMER
INTEGER (KIND=JPLIKB) KDATEF (fa%jpldat)
!
INTEGER (KIND=JPLIKB) IRANG, IREP, INIMES, J
INTEGER (KIND=JPLIKB) ILONG, IPOSEX
INTEGER (KIND=JPLIKB) IDATXF (fa%jpldat)
!
LOGICAL LLVERF, LLRLFI, LLMODA
!
CHARACTER(LEN=FA%JPXNOM) CLACTI 
CHARACTER(LEN=FA%JPLMES) CLMESS 
CHARACTER(LEN=FA%JPLSPX) CLNSPR
LOGICAL                  LLFATA

!**
!     1.  -  CONTROLES DES PARAMETRES D'APPEL, PUIS INITIALISATIONS.
!-----------------------------------------------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('FANDAR_MT',0,zhook_handle)
clacti=''
llverf=.false.
llrlfi=.false.
llmoda=.false.
idatxf=0
CALL fanumu_fort                 &
&               (fa, knumer,irang)
!
IF (irang.EQ.0) THEN
  irep=-51
  GOTO 1001
ENDIF
!
!         Verrouillage eventuel du fichier.
!
IF (fa%LFAMUL) CALL lfiver_fort                               &
&                              (fa%LFI, fa%FICHIER(irang)%VRFICH,'ON')
llverf=fa%LFAMUL
!**
!     2.  -  DEFINITION PROPREMENT DITE VIA LE SOUS-PROGRAMME "FANDAI".
!            ( controles, puis mise a jour de FA%MADATE(.,IRANG) )
!-----------------------------------------------------------------------
!
CALL fandai_fort                             &
&               (fa, irep,irang,kdatef,idatxf,llmoda)
!
IF (irep.EQ.0) THEN
  IF (fa%FICHIER(irang)%LNOMME) THEN
!**
!     3.  -  ECRITURE DE LA DATE SUR LE FICHIER.
!-----------------------------------------------------------------------
!
    CALL lfiecr_fort                                                 &
&                   (fa%LFI,irep,knumer,fa%CPDATE,kdatef,fa%JPLDAT)
    llrlfi=irep.NE.0
    fa%FICHIER(irang)%LCREAF=fa%FICHIER(irang)%LCREAF.AND.llrlfi
    CALL lfinfo_fort                                                 &
&                   (fa%LFI,irep,knumer,fa%CPDATX,ilong,iposex)
    IF (ilong > 0) THEN
      CALL lfisup_fort                                               &
&                     (fa%LFI,irep,knumer,fa%CPDATX,ilong)
      IF (irep /= 0) GOTO 1001
    ENDIF
  ELSE
    llrlfi=.false.
    fa%FICHIER(irang)%LCREAF=.false.
  ENDIF
ENDIF
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "FAIPAR" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
!        Deverrouillage eventuel du fichier.
!
IF (llverf) CALL lfiver_fort                                &
&                           (fa%LFI, fa%FICHIER(irang)%VRFICH,'OFF')
!
IF (llfata) THEN
  inimes=2
ELSEIF (irep.NE.0) THEN
  inimes=0
ELSE
  inimes=ixnvms(irang)
ENDIF
!
IF (.NOT.llfata.AND.inimes.EQ.0)  THEN 
  IF (lhook) CALL dr_hook('FANDAR_MT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='FANDAR'
!
IF (inimes.GE.1.AND.llmoda) THEN
  WRITE (unit=clmess,fmt=                                  &
&         '(''MODIFICATION DE LA DATE, UNITE'',I3)') knumer
  CALL faipar_fort                                      &
&                 (fa, knumer,inimes,irep,.false.,clmess, &
&                  clnspr,clacti,.false.)
ENDIF
!
IF (inimes.EQ.2) THEN
!***** FAZZZZ - KREP=iiii, KNUMER=iii, KDATEF(1:5)=iiiii/ii/ii iii:ii, *****
!*****          KDATEF(7:8)=iiiiii-iiiiii                              *****
  WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', KDATEF(1:5)='',I5,2(''/'',I2),I3,'':'',I2.2,   &
&       '', KDATEF(7:8)='',I6,''-'',I6)') krep,knumer,     &
&     (kdatef(j),j=1,5),(kdatef(j),j=7,8)
  CALL faipar_fort                                     &
&                 (fa, knumer,inimes,irep,llfata,clmess, &
&               clnspr,clacti,llrlfi)
ENDIF
!
IF (lhook) CALL dr_hook('FANDAR_MT',1,zhook_handle)

CONTAINS

#include "facom2.llmoer.h"
#include "facom2.ixnvms.h"

END SUBROUTINE fandar_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE fandar64              &
&           (krep, knumer, kdatef)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  KDATEF     (*)                 ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL fandar_fort                     &
&           (fa, krep, knumer, kdatef)

END SUBROUTINE fandar64

SUBROUTINE fandar                &
&           (krep, knumer, kdatef)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KDATEF     (*)                 ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL fandar_mt                       &
&           (fa, krep, knumer, kdatef)

END SUBROUTINE fandar

SUBROUTINE fandar_mt                 &
&           (fa, krep, knumer, kdatef)
USE fa_mod, ONLY : fa_com
USE lfi_precision
IMPLICIT NONE
! Arguments
type(fa_com)          fa                                     ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KDATEF     (fa%jpldat)                 ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  IDATEF     (fa%jpldat)                 ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)
idatef     = int(    kdatef, jplikb)

CALL fandar_fort                     &
&           (fa, irep, inumer, idatef)

krep       = int(      irep, jplikm)

END SUBROUTINE fandar_mt

!INTF KREP            OUT                               
!INTF KNUMER        IN                                  
!INTF KDATEF        IN    DIMS=FA%JPLDAT