lfinfo.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lfinfo_fort                                            &
&                     (lfi, krep, knumer, cdnoma, klong, kposex )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        SOUS-PROGRAMME CHARGE DE RENSEIGNER SUR EXISTENCE ET CARACTERI-
!     STIQUES ( LONGUEUR, POSITION ) D'UN ARTICLE LOGIQUE, POUR UNE
!     UNITE LOGIQUE OUVERTE PAR LE LOGICIEL DE FICHIERS INDEXES *LFI*.
!**
!    ARGUMENTS : KREP   (SORTIE) ==> CODE-REPONSE DU SOUS-PROGRAMME;
!                KNUMER (ENTREE) ==> LFI%NUMERO DE L'UNITE LOGIQUE;
!                CDNOMA (ENTREE) ==> NOM DE L'ARTICLE A CHERCHER;
!                KLONG  (SORTIE) ==> LONGUEUR DE L'ARTICLE;
!                KPOSEX (SORTIE) ==> POSITION ( DANS LE FICHIER, DU PRE-
!                                    MIER MOT ) DE L'ARTICLE SUIVANT.
!
!       Noter que si l'unite logique est ouverte pour le logiciel LFI et
!     que l'article demande n'y est pas trouve, KREP, KLONG et KPOSEX
!     sont retournes a ZERO.
!
!
TYPE(lficom) :: LFI
CHARACTER CDNOMA*(*), CLNOMA*(lfi%jpncpn)
!
INTEGER (KIND=JPLIKB) KREP, KNUMER, KLONG, KPOSEX 
INTEGER (KIND=JPLIKB) IREP, IRANG, ILCLNO, ILCDNO
INTEGER (KIND=JPLIKB) IDECBL, IPOSBL, IARTEX, IRGPIM 
INTEGER (KIND=JPLIKB) INIMES, INBALO, IRETIN
!
LOGICAL LLVERF
!
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!**
!     1.  -  CONTROLES DES PARAMETRES D'APPEL, PUIS INITIALISATIONS.
!-----------------------------------------------------------------------
!
!        Appel legerement anticipe a LFINUM, garantissant l'initialisa-
!     tion des variables globales du logiciel a la 1ere utilisation.
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFINFO_FORT',0,zhook_handle)

clacti=''

CALL lfinum_fort                    &
&               (lfi, knumer,irang)
llverf=.false.
ilcdno=int(len(cdnoma), jplikb)
klong=0
kposex=0
!
IF (ilcdno.LE.0) THEN
  irep=-15
  clnoma=lfi%CHINCO(:lfi%JPNCPN)
  ilclno=lfi%JPNCPN
  GOTO 1001
ELSEIF (cdnoma.EQ.' ') THEN
  irep=-18
  clnoma=' '
  ilclno=1
  GOTO 1001
ENDIF
!
!        Recherche de la longueur "utile" du nom d'article specifie.
!        (c'est-a-dire sans tenir compte des blancs terminaux eventuels)
!
idecbl=0
!
101 CONTINUE
iposbl=idecbl+int(index(cdnoma(idecbl+1:),' '), jplikb)
!
IF (iposbl.LE.idecbl) THEN
  ilclno=ilcdno
ELSEIF (cdnoma(iposbl:).EQ.' ') THEN
  ilclno=iposbl-1
ELSE
  idecbl=iposbl
  GOTO 101
ENDIF
!
IF (ilclno.LE.lfi%JPNCPN) THEN
  clnoma=cdnoma(:ilclno)
ELSE
  clnoma=cdnoma(:lfi%JPNCPN)
  ilclno=lfi%JPNCPN
  irep=-15
  GOTO 1001
ENDIF
!
IF (irang.EQ.0) THEN
  irep=-1
  GOTO 1001
ENDIF
!
 IF (lfi%LMULTI) CALL lfiver_fort                              &
&                                (lfi, lfi%VERRUE(irang),'ON')
llverf=lfi%LMULTI
!
inbalo=lfi%MDES1D(ixm(lfi%JPNALO,irang))
!
IF (inbalo.NE.0) THEN
!**
!     2.  -  EXPLORATION DES (PAIRES DE) PAGES ET ARTICLES D'INDEX,
!            A LA RECHERCHE DE L'ARTICLE LOGIQUE DEMANDE.
!-----------------------------------------------------------------------
!
  CALL lfiran_fort                                  &
&                 (lfi, irep,irang,clnoma(:ilclno), &
&                  irgpim,iartex,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
ELSE
  iartex=0
  irep=0
ENDIF
!
IF (iartex.EQ.0) THEN
  klong=0
  kposex=0
ELSE
!
!        ON COMPLETE LES CARACTERISTIQUES DE L'ARTICLE.
!
  IF (.NOT.lfi%LPHASP(irgpim)) THEN
!
    CALL lfipha_fort                                &
&                   (lfi, irep,irang,irgpim,iretin)
!
    IF (iretin.EQ.1) THEN
      GOTO 903
    ELSEIF (iretin.EQ.2) THEN
      GOTO 904
    ELSEIF (iretin.NE.0) THEN
      GOTO 1001
    ENDIF
!
  ENDIF
!
  klong=lfi%MLGPOS(ixm(2*iartex-1,irgpim))
  kposex=lfi%MLGPOS(ixm(2*iartex,irgpim))
!
!        On met a jour ce qui a trait aux acces pseudo-sequentiels...
!     ceci surtout pour ne pas faire 2 recherches dans l'index lors
!     d'un appel a LFILEC qui suivrait l'appel a LFINFO.
!
  lfi%NDERGF(irang)=lfi%JPNAPP*lfi%MFACTM(irang)* &
&                    (lfi%MRGPIF(irgpim)-1)+iartex
  lfi%CNDERA(irang)=clnoma(:ilclno)
  lfi%NSUIVF(irang)=lfi%JPNIL
  lfi%NPRECF(irang)=lfi%JPNIL
ENDIF
!
GOTO 1001
!**
!     9.  - CI-DESSOUS, ETIQUETTES DE BRANCHEMENT EN CAS D'ERREUR E/S.
!-----------------------------------------------------------------------
!
903 CONTINUE
clacti='WRITE'
GOTO 909
!
904 CONTINUE
clacti='READ'
!
909 CONTINUE
!
!      AU CAS OU, ON FORCE LE CODE-REPONSE ENTREE/SORTIE A ETRE POSITIF.
!
irep=abs(irep)
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "LFIEMS" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
IF (irang.NE.0) THEN
  lfi%NDEROP(irang)=7
  lfi%NDERCO(irang)=irep
   IF (llverf) CALL lfiver_fort                               &
&                              (lfi, lfi%VERRUE(irang),'OFF')
ENDIF
!
IF (llfata.OR.ixnims(irang).EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('LFINFO_FORT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='LFINFO'
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3,            &
&       '', CDNOMA='''''',A,'''''', KLONG='',I7,'',KPOSEX='',I10)') &
&     krep,knumer,clnoma(:ilclno),klong,kposex
CALL lfiems_fort                                 &
&               (lfi, knumer,inimes,irep,llfata, &
&                clmess,clnspr,clacti)
!
IF (lhook) CALL dr_hook('LFINFO_FORT',1,zhook_handle)

CONTAINS

#include "lficom2.ixm.h"
#include "lficom2.ixnims.h"
#include "lficom2.llmoer.h"

END SUBROUTINE lfinfo_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfinfo64                             &
&           (krep, knumer, cdnoma, klong, kposex)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKB)  KLONG                                  !   OUT
INTEGER (KIND=JPLIKB)  KPOSEX                                 !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfinfo_fort                                      &
&           (lfi, krep, knumer, cdnoma, klong, kposex)

END SUBROUTINE lfinfo64

SUBROUTINE lfinfo                               &
&           (krep, knumer, cdnoma, klong, kposex)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKM)  KLONG                                  !   OUT
INTEGER (KIND=JPLIKM)  KPOSEX                                 !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfinfo_mt                                       &
&           (lfi, krep, knumer, cdnoma, klong, kposex)

END SUBROUTINE lfinfo

SUBROUTINE lfinfo_mt                                 &
&           (lfi, krep, knumer, cdnoma, klong, kposex)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKM)  KLONG                                  !   OUT
INTEGER (KIND=JPLIKM)  KPOSEX                                 !   OUT
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  ILONG                                  !   OUT
INTEGER (KIND=JPLIKB)  IPOSEX                                 !   OUT
! Convert arguments

inumer     = int(    knumer, jplikb)

CALL lfinfo_fort                                      &
&           (lfi, irep, inumer, cdnoma, ilong, iposex)

krep       = int(      irep, jplikm)
klong      = int(     ilong, jplikm)
kposex     = int(    iposex, jplikm)

END SUBROUTINE lfinfo_mt

!INTF KREP            OUT 
!INTF KNUMER        IN    
!INTF CDNOMA        IN    
!INTF KLONG           OUT 
!INTF KPOSEX          OUT