lfinum.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lfinum_fort                      &
&                     (lfi, knumer, krang )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        CE SOUS-PROGRAMME CALCULE LE RANG DU LFI%NUMERO D'UNITE LOGIQUE
!     *KNUMER* DANS LA TABLE DES UNITES LOGIQUES *LFI%NUMERO*;
!     S'IL N'Y EST PAS TROUVE, LE RESULTAT EST ZERO.
!        CE SOUS-PROGRAMME, APPELE PAR *TOUS* LES SOUS-PROGRAMMES NON
!     GLOBAUX DU LOGICIEL DE FICHIERS INDEXES LFI, SE CHARGE LORS DE SON
!     PREMIER APPEL D'APPELER LE SOUS-PROGRAMME PREPARATOIRE LFIINI.
!**
!       ARGUMENTS : KNUMER (ENTREE) ==> LFI%NUMERO D'UNITE LOGIQUE CHERCHE;
!                   KRANG  (SORTIE) ==> RANG DANS LA TABLE DES FICHIERS
!                                       DU LOGICIEL LFI (0 SI ABSENT).
!
!
TYPE(lficom) :: LFI
INTEGER (KIND=JPLIKB) KNUMER, KRANG, J, IRESUL, IREP, INIMES
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI

!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFINUM_FORT',0,zhook_handle)
clacti=''
IF (lfi%LFINUM_LLPREA) THEN
  CALL lfiini_fort                 &
&                 (lfi, 2_jplikb )
  lfi%LFINUM_LLPREA=.false.
ENDIF
!
!          VERROUILLAGE GLOBAL (A CAUSE DE L'UTILISATION DE LFI%NBFIOU )
!
 IF (lfi%LMULTI) CALL lfiver_fort                       &
&                                (lfi, lfi%VERGLA,'ON')
!
DO j=1,lfi%NBFIOU
!
IF (knumer.EQ.lfi%NUMERO(lfi%NUMIND(j))) THEN
  iresul=lfi%NUMIND(j)
  GOTO 20
ENDIF
!
ENDDO
!
iresul=0
!
20 CONTINUE
!
!          DEVERROUILLAGE GLOBAL
!
 IF (lfi%LMULTI) CALL lfiver_fort                        &
&                                (lfi, lfi%VERGLA,'OFF')
krang=iresul
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE INTERNE EVENTUELLE,
!            VIA LE SOUS-PROGRAMME "LFIEMS", PUIS RETOUR.
!-----------------------------------------------------------------------
!
IF (lfi%LMISOP) THEN
  irep=0
  inimes=2
  clnspr='LFINUM'
  WRITE (unit=clmess,fmt='(''KNUMER='',I3,'', KRANG='',I3)') &
&    knumer,krang
  CALL lfiems_fort                                  &
&                 (lfi, knumer,inimes,irep,.false., &
&                  clmess,clnspr,clacti)
ENDIF
!
IF (lhook) CALL dr_hook('LFINUM_FORT',1,zhook_handle)
END SUBROUTINE lfinum_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfinum64           &
&           (knumer, krang)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  KRANG                                  !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfinum_fort                &
&           (lfi, knumer, krang)

END SUBROUTINE lfinum64

SUBROUTINE lfinum             &
&           (knumer, krang)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KRANG                                  !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfinum_mt                 &
&           (lfi, knumer, krang)

END SUBROUTINE lfinum

SUBROUTINE lfinum_mt             &
&           (lfi, knumer, krang)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KRANG                                  !   OUT
! Local integers
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  IRANG                                  !   OUT
! Convert arguments

inumer     = int(    knumer, jplikb)

CALL lfinum_fort                &
&           (lfi, inumer, irang)

krang      = int(     irang, jplikm)

END SUBROUTINE lfinum_mt

!INTF KNUMER        IN    
!INTF KRANG           OUT