lfiecr.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lfiecr_fort                                          &
&                     (lfi, krep, knumer, cdnoma, ktab, klong )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        SOUS-PROGRAMME D'ECRITURE D'UN ARTICLE (DE DONNEES) SUR UNE
!     UNITE LOGIQUE OUVERTE POUR LE LOGICIEL DE FICHIERS INDEXES LFI;
!     L'ARTICLE DOIT ETRE UN "BLOC" DE DONNEES ADJACENTES.
!**
!    ARGUMENTS : KREP   (SORTIE) ==> CODE-REPONSE DU SOUS-PROGRAMME;
!                KNUMER (ENTREE) ==> LFI%NUMERO DE L'UNITE LOGIQUE;
!                CDNOMA (ENTREE) ==> NOM DE L'ARTICLE A ECRIRE;
!                KTAB   (ENTREE) ==> PREMIER MOT A ECRIRE
!                KLONG  (ENTREE) ==> LONGUEUR DE L'ARTICLE A ECRIRE.
!
!
TYPE(lficom) :: LFI
CHARACTER CDNOMA*(*), CLNOMA*(lfi%jpncpn)
!
INTEGER (KIND=JPLIKB) KREP, KNUMER, KLONG
INTEGER (KIND=JPLIKB)  KTAB (klong)
INTEGER (KIND=JPLIKB) IRANG, IREP, ILCLNO, IDECBL 
INTEGER (KIND=JPLIKB) IPOSBL, INBALO, INBPIR
INTEGER (KIND=JPLIKB) IFACTM, ILARPH, INALPP, IRPIEX 
INTEGER (KIND=JPLIKB) IARTEX, ILONEX, IRPIEC
INTEGER (KIND=JPLIKB) IARTEC, IPOSEC, IDTROU, ILONUT 
INTEGER (KIND=JPLIKB) INPPIM, IRETIN, IRGPI, J
INTEGER (KIND=JPLIKB) IRGPIM, ILFORC, INPILE, INAPHY 
INTEGER (KIND=JPLIKB) IRANGM, INAPXX, INDMAX
INTEGER (KIND=JPLIKB) IMDESC, INIMES, ILCDNO
!
LOGICAL LLLECT, LLECR, LLVERF
!
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!**
!     1.  -  CONTROLES DES PARAMETRES D'APPEL, PUIS INITIALISATIONS.
!-----------------------------------------------------------------------
!
!        Appel legerement anticipe a LFINUM, garantissant l'initialisa-
!     tion des variables globales du logiciel a la 1ere utilisation.
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFIECR_FORT',0,zhook_handle)
clacti=''
CALL lfinum_fort                    &
&               (lfi, knumer,irang)
llverf=.false.
ilcdno=int(len(cdnoma), jplikb)
!
IF (ilcdno.LE.0) THEN
  irep=-15
  clnoma=lfi%CHINCO(:lfi%JPNCPN)
  ilclno=lfi%JPNCPN
  GOTO 1001
ELSEIF (cdnoma.EQ.' ') THEN
  irep=-18
  clnoma=' '
  ilclno=1
  GOTO 1001
ENDIF
!
!        Recherche de la longueur "utile" du nom d'article specifie.
!        (c'est-a-dire sans tenir compte des blancs terminaux eventuels)
!
idecbl=0
!
101 CONTINUE
iposbl=idecbl+int(index(cdnoma(idecbl+1:),' '), jplikb)
!
IF (iposbl.LE.idecbl) THEN
  ilclno=ilcdno
ELSEIF (cdnoma(iposbl:).EQ.' ') THEN
  ilclno=iposbl-1
ELSE
  idecbl=iposbl
  GOTO 101
ENDIF
!
IF (ilclno.LE.lfi%JPNCPN) THEN
  clnoma=cdnoma(:ilclno)
ELSE
  clnoma=cdnoma(:lfi%JPNCPN)
  ilclno=lfi%JPNCPN
  irep=-15
  GOTO 1001
ENDIF
!
IF (klong.LE.0) THEN
  irep=-14
  GOTO 1001
ELSEIF (irang.EQ.0) THEN
  irep=-1
  GOTO 1001
ENDIF
!
 IF (lfi%LMULTI) CALL lfiver_fort                              &
&                                (lfi, lfi%VERRUE(irang),'ON')
llverf=lfi%LMULTI
!
IF (lfi%NEXPOR(irang).GT.0) THEN
!
!         Fichier en cours d'export... ne devant donc pas etre modifie.
!
  irep=-37
  GOTO 1001
ENDIF
!
lllect=.true.
llecr =.false.
inbalo=lfi%MDES1D(ixm(lfi%JPNALO,irang))
inbpir=lfi%MDES1D(ixm(lfi%JPNPIR,irang))
ifactm=lfi%MFACTM(irang)
ilarph=lfi%JPLARD*ifactm
inalpp=lfi%JPNAPP*ifactm
!**
!     2.  -  EXPLORATION DES (PAIRES DE) PAGES ET ARTICLES D'INDEX,
!            A LA RECHERCHE DE L'ARTICLE LOGIQUE ET/OU D'UN "TROU"
!            DANS L'INDEX, SUFFISANT POUR Y "CASER" LEDIT ARTICLE.
!-----------------------------------------------------------------------
!
inaphy=0
CALL lfiree_fort                                               &
&               (lfi, irep,irang,clnoma(:ilclno),klong,irpiex, &
&                iartex, ilonex,irpiec,iartec,iposec,          &
&                idtrou,ilonut,iretin)
!
IF (iretin.EQ.1) THEN
  GOTO 903
ELSEIF (iretin.EQ.2) THEN
  GOTO 904
ELSEIF (iretin.NE.0) THEN
  GOTO 1001
ENDIF
!
inppim=lfi%NPPIMM(irang)
!
IF (iartex.NE.0.AND.lfi%NEXPOR(irang).GT.0) THEN
!
!         Fichier en cours d'export... la seule modification acceptee
!         est l'ajout de nouveaux articles.
!
  irep=-37
  GOTO 1001
ENDIF
!**
!     3.  -   PARTIE ECRITURE DES DONNEES .
!-----------------------------------------------------------------------
!
CALL lfiecd_fort                                           &
&               (lfi, irep,irang,ktab,klong,iposec,iretin)
!
IF (iretin.EQ.1) THEN
  GOTO 903
ELSEIF (iretin.EQ.2) THEN
  GOTO 904
ELSEIF (iretin.NE.0) THEN
  GOTO 1001
ENDIF
!**
!     4.  -   MODIFICATION(S) EVENTUELLE(S) DE L'INDEX.
!-----------------------------------------------------------------------
!
IF (iartex.NE.0.AND.iartec.NE.iartex) THEN
!*
!     4.1 - CAS OU L'ON CREE UN TROU DANS L'INDEX.
!-----------------------------------------------------------------------
!
!           RECHERCHE OU MISE EN MEMOIRE DE L'ARTICLE D'INDEX "NOMS"
!        CONTENANT LES CARACTERISTIQUES DE L'ARTICLE LOGIQUE
!        QUE L'ON "TROUE".
!
  DO j=1,inppim
  irgpi=lfi%MRGPIM(j,irang)
!
  IF (lfi%MRGPIF(irgpi).EQ.irpiex) THEN
    irgpim=irgpi
    GOTO 413
  ENDIF
!
  ENDDO
!
  ilforc=1
  inpile=1
  inaphy=0
  CALL lfipim_fort                                       &
&                 (lfi, irep,irang,irangm,irgpim,irpiex, &
&                  ilforc,inpile, iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
  inppim=max(inppim,irangm)
!
413 CONTINUE
  lfi%CNOMAR(ixc(iartex,irgpim))=' '
  lfi%LECRPI(irgpim,1)=.true.
!
  IF (ilonex.NE.ilonut) THEN
!
!           STOCKAGE DE LA LONGUEUR TOTALE UTILISABLE DU TROU .
!         DANS CE CAS, ON EST SUR QUE LA PAGE D'INDEX "LONG./POS."
!         EST TOUJOURS PHASEE.
!
    lfi%MLGPOS(ixm(2*iartex-1,irgpim))=ilonut
    lfi%LECRPI(irgpim,2)=.true.
  ENDIF
!
ENDIF
!
IF (inalpp*(irpiec-1)+iartec.GT.inbalo) THEN
!*
!     4.2 - CAS OU L'ON A CREE UN ARTICLE LOGIQUE SUPPLEMENTAIRE.
!-----------------------------------------------------------------------
!
  lfi%MDES1D(ixm(lfi%JPNALO,irang))=inbalo+1
!
  IF (inbalo.NE.0.AND.iartec.EQ.1) THEN
!
!             ON DOIT CREER UNE P.A.I. SUPPLEMENTAIRE.
!
    IF (irpiec.GT.inbpir) THEN
!
!             CETTE NOUVELLE P.A.I. EST "EXCEDENTAIRE".
!             RECHERCHE DU PREMIER ARTICLE PHYSIQUE DISPONIBLE
!             POUR Y ECRIRE (ULTERIEUREMENT) CETTE P.A.I. EXCEDENTAIRE.
!             LE CONTROLE DE DEPASSEMENT DE CAPACITE DE L'INDEX
!             DU FICHIER A ETE FAIT DANS LE SOUS-PROGRAMME *LFIREE*.
!
      inapxx=lfi%MDES1D(ixm(lfi%JPAXPD,irang))
      indmax=lfi%JPNIL
!
      DO j=0,lfi%JPNPDF-1
!
      IF (lfi%NUMAPD(j,irang).GT.inapxx) THEN
        inapxx=lfi%NUMAPD(j,irang)
        indmax=j
      ENDIF
!
      ENDDO
!
      IF (irpiec.GT.(inbpir+1)) THEN
        imdesc=lfi%MDES1D(ixm(ilarph+2-irpiec+inbpir,irang))
        inapxx=max(inapxx,imdesc+1)
      ENDIF
!
      lfi%MDES1D(ixm(ilarph+1-irpiec+inbpir,irang))=inapxx+1
!
!      L'ON A AUSSI CREE, EN GENERAL, UNE ZONE "PERDUE" (MAIS NEANMOINS
!     REUTILISABLE DANS UNE CERTAINE MESURE) A LA FIN DU DERNIER
!     ARTICLE PHYSIQUE DES DONNEES QUE L'ON VIENT D'ECRIRE.
!           IL EST ALORS NECESSAIRE DE "COMPLETER" LA ZONE PERDUE,
!     POUR NE PAS AVOIR DE PROBLEME ULTERIEUR DANS *LFIECX*.
!
      IF (indmax.NE.lfi%JPNIL) THEN
!
        DO j=lfi%NLONPD(indmax,irang)+1,ilarph
        lfi%MTAMPD(ixt(j,indmax,irang))=0
        ENDDO
!
        lfi%NLONPD(indmax,irang)=ilarph
      ENDIF
!
    ENDIF
!
    ilforc=1
    inpile=0
    inaphy=0
    CALL lfipim_fort                                       &
&                   (lfi, irep,irang,irangm,irgpim,irpiec, &
&                    ilforc,inpile, iretin)
!
    IF (iretin.EQ.1) THEN
      GOTO 903
    ELSEIF (iretin.EQ.2) THEN
      GOTO 904
    ELSEIF (iretin.NE.0) THEN
      GOTO 1001
    ENDIF
!
    lfi%NPODPI(irang)=irangm
!
!           REMARQUE: LA DERNIERE P.P.I. EST TOUJOURS "PHASEE".
!
    lfi%LPHASP(irgpim)=.true.
  ELSE
    irgpim=lfi%MRGPIM(lfi%NPODPI(irang),irang)
  ENDIF
!
  lfi%NALDPI(irang)=iartec
  lfi%CNOMAR(ixc(iartec,irgpim))=clnoma(:ilclno)
  lfi%MLGPOS(ixm(2*iartec-1,irgpim))=klong
  lfi%MLGPOS(ixm(2*iartec  ,irgpim))=iposec
  lfi%LECRPI(irgpim,1)=.true.
  lfi%LECRPI(irgpim,2)=.true.
!
ELSEIF (iartex.EQ.0.OR.klong.NE.ilonex) THEN
!*
!     4.3 - CAS OU L'ON REUTILISE UN ARTICLE OU TROU QUI EXISTAIT
!           AU PREALABLE, EN MODIFIANT SES CARACTERISTIQUES DE NOM ET/OU
!           DE LONGUEUR.
!-----------------------------------------------------------------------
!
  DO j=1,inppim
  irgpi=lfi%MRGPIM(j,irang)
!
  IF (lfi%MRGPIF(irgpi).EQ.irpiec) THEN
    irangm=j
    irgpim=irgpi
!
!           L'ARTICLE D'INDEX "NOMS" CORRESPONDANT EST EN MEMOIRE...
!       PHASAGE EVENTUEL DE LA PAGE D'INDEX "LONG/POS" .
!
    inaphy=0
!
    IF (.NOT.lfi%LPHASP(irgpim)) THEN
!
      CALL lfipha_fort                                &
&                     (lfi, irep,irang,irgpim,iretin)
!
      IF (iretin.EQ.1) THEN
        GOTO 903
      ELSEIF (iretin.EQ.2) THEN
        GOTO 904
      ELSEIF (iretin.NE.0) THEN
        GOTO 1001
      ENDIF
!
    ENDIF
!
    GOTO 434
  ENDIF
!
  ENDDO
!
!            ARTICLE D'INDEX CORRESPONDANT NON PRESENT EN MEMOIRE...
!         ON L'Y AMENE.
!
  ilforc=1
  inpile=2
  inaphy=0
  CALL lfipim_fort                                       &
&                 (lfi, irep,irang,irangm,irgpim,irpiec, &
&                  ilforc,inpile, iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
434 CONTINUE
!
  IF (iartec.NE.iartex.OR.irpiec.NE.irpiex) THEN
    lfi%CNOMAR(ixc(iartec,irgpim))=clnoma(:ilclno)
    lfi%LECRPI(irgpim,1)=.true.
  ENDIF
!
  lfi%MLGPOS(ixm(2*iartec-1,irgpim))=klong
  lfi%LECRPI(irgpim,2)=.true.
!
ENDIF
!**
!     5.  -   MISE A JOUR: STATISTIQUES, TABLES, PAGE DOCUMENTAIRE.
!-----------------------------------------------------------------------
!
IF (iartex.EQ.0) THEN
  lfi%NBNECR(irang)=lfi%NBNECR(irang)+1
ELSEIF (klong.EQ.ilonex) THEN
  lfi%NREESP(irang)=lfi%NREESP(irang)+1
ELSEIF (klong.LT.ilonex) THEN
  lfi%NREECO(irang)=lfi%NREECO(irang)+1
  lfi%LMIMAL(irang)=lfi%LMIMAL(irang).OR.                   &
&                ilonex.EQ.lfi%MDES1D(ixm(lfi%JPLXAL,irang))
ELSE
  lfi%NREELO(irang)=lfi%NREELO(irang)+1
  lfi%LMIMAL(irang)=lfi%LMIMAL(irang).OR.                   &
&                ilonex.EQ.lfi%MDES1D(ixm(lfi%JPLNAL,irang))
ENDIF
!
lfi%NBTROU(irang)=lfi%NBTROU(irang)+idtrou
IF (lfi%LMISOP) WRITE (unit=lfi%NULOUT,fmt=*)                      &
&        'IDTROU = ',idtrou,', ILONEX = ',ilonex,', KLONG = ',klong
!
!        On met a jour ce qui a trait aux acces pseudo-sequentiels...
!
lfi%NDERGF(irang)=inalpp*(irpiec-1)+iartec
lfi%CNDERA(irang)=clnoma(:ilclno)
lfi%NSUIVF(irang)=lfi%JPNIL
lfi%NPRECF(irang)=lfi%JPNIL
!
imdesc=lfi%MDES1D(ixm(lfi%JPLNAL,irang))
lfi%MDES1D(ixm(lfi%JPLNAL,irang))=min(imdesc,klong)
imdesc=lfi%MDES1D(ixm(lfi%JPLXAL,irang))
lfi%MDES1D(ixm(lfi%JPLXAL,irang))=max(imdesc,klong)
lfi%MDES1D(ixm(lfi%JPLTAL,irang))=                          &
&             lfi%MDES1D(ixm(lfi%JPLTAL,irang))+klong-ilonex
IF (inbalo.EQ.0) lfi%MDES1D(ixm(lfi%JPLNAL,irang))=klong
!
IF (.NOT.lfi%LMODIF(irang)) THEN
!
!         CAS DE LA PREMIERE ECRITURE DEPUIS L'OUVERTURE DU FICHIER.
!
  lfi%LMODIF(irang)=.true.
  inaphy=0
  CALL lfimoe_fort                         &
&                 (lfi, irep,irang,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
ENDIF
!
irep=0
lfi%NBMOEC(irang)=lfi%NBMOEC(irang)+klong
GOTO 1001
!**
!     9.  - CI-DESSOUS, ETIQUETTES DE BRANCHEMENT EN CAS D'ERREUR E/S.
!-----------------------------------------------------------------------
!
903 CONTINUE
clacti='WRITE'
GOTO 909
!
904 CONTINUE
clacti='READ'
!
909 CONTINUE
!
!      AU CAS OU, ON FORCE LE CODE-REPONSE ENTREE/SORTIE A ETRE POSITIF.
!
irep=abs(irep)
IF (inaphy.NE.0) lfi%NUMAPH(irang)=inaphy
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "LFIEMS" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
IF (irang.NE.0) THEN
  lfi%NDEROP(irang)=1
  lfi%NDERCO(irang)=irep
   IF (llverf) CALL lfiver_fort                               &
&                              (lfi, lfi%VERRUE(irang),'OFF')
ENDIF
!
IF (llfata.OR.ixnims(irang).EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('LFIECR_FORT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='LFIECR'
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', CDNOMA='''''',A,'''''', KLONG='',I7)')       &
&     krep,knumer,clnoma(:ilclno),klong
CALL lfiems_fort                                 &
&               (lfi, knumer,inimes,irep,llfata, &
&                clmess,clnspr,clacti)
!
IF (lhook) CALL dr_hook('LFIECR_FORT',1,zhook_handle)

CONTAINS

#include "lficom2.ixc.h"
#include "lficom2.ixm.h"
#include "lficom2.ixnims.h"
#include "lficom2.ixt.h"
#include "lficom2.llmoer.h"

END SUBROUTINE lfiecr_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfiecr64                           &
&           (krep, knumer, cdnoma, ktab, klong)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKB)  KLONG                                  ! IN   
INTEGER (KIND=JPLIKB)  KTAB       (klong)                     ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfiecr_fort                                    &
&           (lfi, krep, knumer, cdnoma, ktab, klong)

END SUBROUTINE lfiecr64

SUBROUTINE lfiecr                             &
&           (krep, knumer, cdnoma, ktab, klong)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKM)  KLONG                                  ! IN   
INTEGER (KIND=JPLIKB)  KTAB       (klong)                     ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfiecr_mt                                     &
&           (lfi, krep, knumer, cdnoma, ktab, klong)

END SUBROUTINE lfiecr

SUBROUTINE lfiecr_mt                               &
&           (lfi, krep, knumer, cdnoma, ktab, klong)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKM)  KLONG                                  ! IN   
INTEGER (KIND=JPLIKB)  KTAB       (klong)                     ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  ILONG                                  ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)
ilong      = int(     klong, jplikb)

CALL lfiecr_fort                                    &
&           (lfi, irep, inumer, cdnoma, ktab, ilong)

krep       = int(      irep, jplikm)

END SUBROUTINE lfiecr_mt

!INTF KREP            OUT                                                              
!INTF KNUMER        IN                                                                 
!INTF CDNOMA        IN                                                                 
!INTF KTAB          IN    DIMS=KLONG                     KIND=JPLIKB                   
!INTF KLONG         IN