lfiecd.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI
SUBROUTINE lfiecd_fort                                 &
&                     (lfi, krep, krang, ktab, klong,  &
&                      kposec, kretin )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        SOUS-PROGRAMME *INTERNE* DU LOGICIEL DE FICHIERS INDEXES LFI
!     ECRITURE DES DONNEES PROPREMENT DITES, UNE FOIS L'ARTICLE LOGIQUE
!     DEFINI (PAR NOM, OU PAR POSITION) .
!**
!    ARGUMENTS : KREP   (SORTIE) ==> CODE-REPONSE DU SOUS-PROGRAMME;
!                KRANG  (ENTREE) ==> RANG ( DANS LA TABLE *LFI%NUMERO* )
!                                    DE L'UNITE LOGIQUE CONCERNEE;
!                KTAB   (ENTREE) ==> PREMIER MOT A ECRIRE;
!                KLONG  (ENTREE) ==> LONGUEUR DE L'ARTICLE A ECRIRE;
!                KPOSEC (ENTREE) ==> POSITION ( DANS LE FICHIER ) OU
!                                    COMMENCER A ECRIRE L'ARTICLE;
!                KRETIN (SORTIE) ==> CODE-RETOUR INTERNE.
!
!
TYPE(lficom) :: LFI
INTEGER (KIND=JPLIKB) KREP, KRANG, KLONG, KPOSEC, KRETIN
INTEGER (KIND=JPLIKB)  KTAB (klong), IFOURT (lfi%jplarx)
INTEGER (KIND=JPLIKB) INUCPL (lfi%jpnpdf), INAPHY 
INTEGER (KIND=JPLIKB) INUMER, ILARPH, IPODEB, IPOFIN
INTEGER (KIND=JPLIKB) IARDEB, IARFIN, IDCDEB, IDCFIN 
INTEGER (KIND=JPLIKB) ICPLTI, ICPLTF, ICPTTN
INTEGER (KIND=JPLIKB) ICPTTX, INCPLT, INUMAP, J, JD 
INTEGER (KIND=JPLIKB) IDECDE, IPAREC, ITAMLI
INTEGER (KIND=JPLIKB) INUMPJ, INUMPD, IARTIC, INPDRE 
INTEGER (KIND=JPLIKB) INPDTA, INPDIS, INDIK1
INTEGER (KIND=JPLIKB) INDIK2, INDIC1, INDIC2, JI 
INTEGER (KIND=JPLIKB) IFACTM, IRETOU, INIMES
INTEGER (KIND=JPLIKB) IRETIN
!
LOGICAL LLADON, LLDERN
!
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!**
!     1.  -  CONTROLES DES PARAMETRES D'APPEL, PUIS INITIALISATIONS.
!-----------------------------------------------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFIECD_FORT',0,zhook_handle)
clacti=''
iretou=0
!
IF (krang.LE.0.OR.krang.GT.lfi%JPNXFI.OR.kposec.EQ.0) &
&     THEN
  krep=-16
  GOTO 1001
ENDIF
!
inumer=lfi%NUMERO(krang)
ifactm=lfi%MFACTM(krang)
ilarph=lfi%JPLARD*ifactm
krep=0
!**
!     2.  -   PARTIE ECRITURE DES DONNEES .
!-----------------------------------------------------------------------
!*
!     2.1 - UTILISATION DES ARTICLES PHYSIQUES PRESENTS EN MEMOIRE,
!           ET QUE L'ON S'APPRETE A ECRIRE *EN ENTIER*.
!-----------------------------------------------------------------------
!
ipodeb=kposec
ipofin=kposec+klong-1
iardeb=1+(ipodeb-1)/ilarph
iarfin=1+(ipofin-1)/ilarph
idcdeb=mod(ipodeb-1,ilarph)
idcfin=mod(ipofin  ,ilarph)
lldern=idcfin.NE.0.AND.((iarfin.NE.iardeb)                      &
&                        .OR.(iarfin.EQ.iardeb.AND.idcdeb.EQ.0))
icplti=iardeb+(idcdeb+ilarph-1)/ilarph
icpltf=iarfin-1+(ilarph-idcfin)/ilarph
icpttn=icpltf+1
icpttx=icplti-1
incplt=0
!
IF (lfi%LMISOP) THEN
 WRITE (unit=lfi%NULOUT,fmt=*)'KPOSEC= ',kposec, &
&                            ', IPODEB= ',ipodeb, &
&                            ', IPOFIN= ',ipofin
 WRITE (unit=lfi%NULOUT,fmt=*)'IARDEB= ',iardeb, &
&                            ', IARFIN= ',iarfin, &
&                            ', IDCDEB= ',idcdeb
 WRITE (unit=lfi%NULOUT,fmt=*)'IDCFIN= ',idcfin, &
&                            ', ICPLTI= ',icplti, &
&                            ', ICPLTF= ',icpltf
 WRITE (unit=lfi%NULOUT,fmt=*)'ICPTTN= ',icpttn, &
&                            ', ICPTTX= ',icpttx
ENDIF
!
IF (icpltf.GE.icplti) THEN
!
  DO j=0,lfi%JPNPDF-1
  inumap=lfi%NUMAPD(j,krang)
!
  IF (inumap.GE.icplti.AND.inumap.LE.icpltf) THEN
    incplt=incplt+1
    inucpl(incplt)=inumap
    icpttn=min(icpttn,inumap)
    icpttx=max(icpttx,inumap)
    idecde=(inumap-iardeb)*ilarph-idcdeb
!
    DO jd=1,ilarph
    lfi%MTAMPD(ixt(jd,j,krang))=ktab(idecde+jd)
    ENDDO
!
    lfi%NLONPD(j,krang)=ilarph
    lfi%LECRPD(j,krang)=.true.
    IF (incplt.GT.(icpltf-icplti)) GOTO 220
  ENDIF
!
  ENDDO
!
ENDIF
!
220 CONTINUE
!*
!     2.2 - TRAITEMENT DE LA PREMIERE PAGE DE DONNEES, SI L'ARTICLE
!           LOGIQUE NE COMMENCE PAS JUSTE EN DEBUT D'ARTICLE PHYSIQUE.
!           CETTE PAGE EST CONSERVEE... DES FOIS QUE LE PROCHAIN ACCES
!           AU FICHIER SOIT POUR L'ARTICLE LOGIQUE IMMEDIATEMENT DEVANT
!           ( CAS DE BALAYAGE INVERSE DU FICHIER, PAR EXEMPLE ) .
!-----------------------------------------------------------------------
!
idecde=0
!
IF (idcdeb.EQ.0) THEN
  iparec=0
  itamli=lfi%JPNPDF
ELSE
  iparec=min(ilarph*iardeb,ipofin)-kposec+1
  itamli=lfi%JPNPDF-1
!
!           L'ARTICLE DE DONNEES A ECRIRE NE COMMENCE PAS AU DEBUT D'UN
!         ARTICLE PHYSIQUE. IL FAUT DONC AVOIR CET ARTICLE PHYSIQUE
!         EN MEMOIRE POUR LE COMPLETER.
!
  DO j=1,lfi%JPNPDF
  inumpj=mod(lfi%NDERPD(krang)+j,lfi%JPNPDF)
!
  IF (lfi%NUMAPD(inumpj,krang).EQ.iardeb) THEN
!
!           ARTICLE PHYSIQUE CHERCHE EN MEMOIRE.
!
    IF (lfi%NLONPD(inumpj,krang).LT.idcdeb                     &
&        .AND.iardeb.LE.lfi%MDES1D(ixm(lfi%JPAXPD,krang))) THEN
!
!           LA PAGE DE DONNEES EST INSUFFISAMMENT REMPLIE, ET A
!       UN ARTICLE ASSOCIE SUR FICHIER; IL FAUT DONC LIRE CET ARTICLE,
!       ET RECOLLER LES MORCEAUX...
!
      inaphy=iardeb
      CALL lfildo_fort                                  &
&                     (lfi, krep,inumer,iardeb,ifourt,&
&                      lfi%NBREAD(krang),ifactm,      &
&                      lfi%YLFIC (krang),iretin)
!
      IF (iretin.NE.0) THEN
        GOTO 904
      ENDIF
!
      DO jd=lfi%NLONPD(inumpj,krang)+1,ilarph
      lfi%MTAMPD(ixt(jd,inumpj,krang))=ifourt(jd)
      ENDDO
!
      lfi%NLONPD(inumpj,krang)=ilarph
    ENDIF
!
    inumpd=inumpj
    GOTO 223
  ENDIF
!
  ENDDO
!
!     ARTICLE PHYSIQUE CHERCHE PAS EN MEMOIRE... ON DOIT DONC LE LIRE.
!
  inumpd=mod(1+lfi%NDERPD(krang),lfi%JPNPDF)
  inaphy=0
!
  IF (lfi%LECRPD(inumpd,krang)) THEN
!
    CALL lfivid_fort                                       &
&                   (lfi, krep,krang,inumpd,ifourt,iretin)
!
    IF (iretin.EQ.1) THEN
      GOTO 903
    ELSEIF (iretin.EQ.2) THEN
      GOTO 904
    ELSEIF (iretin.NE.0) THEN
      GOTO 1001
    ENDIF
!
  ENDIF
!
  lfi%NUMAPD(inumpd,krang)=lfi%JPNIL
  inaphy=iardeb
  CALL lfildo_fort                                            &
&                 (lfi, krep,inumer,iardeb,                 &
&                  lfi%MTAMPD(ixt(1_jplikb ,inumpd,krang)), &
&                  lfi%NBREAD(krang),ifactm,                &
&                  lfi%YLFIC (krang),iretin)
!
  IF (iretin.NE.0) THEN
    GOTO 904
  ENDIF
!
  lfi%NUMAPD(inumpd,krang)=iardeb
  lfi%NLONPD(inumpd,krang)=ilarph
!
223 CONTINUE
!
!         COMPLEMENT DE LA PAGE DE DONNEES ASSOCIEE AU PREMIER ARTICLE
!       PHYSIQUE OU DOIVENT ETRE STOCKEES LES DONNEES A ECRIRE.
!
  DO jd=1,iparec
  lfi%MTAMPD(ixt(idcdeb+jd,inumpd,krang))=ktab(jd)
  ENDDO
!
  lfi%LECRPD(inumpd,krang)=.true.
  lfi%NLONPD(inumpd,krang)=max(lfi%NLONPD(inumpd,krang), &
&                                 idcdeb+iparec)
  lfi%NDERPD(krang)=inumpd
ENDIF
!*
!     2.3 - ECRITURE DES ARTICLES PHYSIQUES COMPLETS NE TENANT PAS OU NE
!           DEVANT PAS ETRE STOCKES DANS LES PAGES DE DONNEES "TAMPON".
!           S'IL Y EN A, LES EVENTUELLES PAGES DE DONNEES COPIEES AUX
!           PARAGRAPHES PRECEDENTS (2.1 ET 2.2) PRECEDANT CES ARTICLES
!           DANS LE FICHIER SERONT ALORS ELLES AUSSI ECRITES SUR DISQUE.
!-----------------------------------------------------------------------
!
IF (.NOT.lfi%LTAMPE(krang)) THEN
  itamli=0
ELSEIF (lldern) THEN
  itamli=itamli-1
ENDIF
!
iartic=icplti-1
inpdre=(klong-iparec-idcfin+ilarph-1)/ilarph-incplt
inpdta=min(inpdre,itamli)
inpdis=inpdre-itamli
indik1=1
indik2=incplt
lladon=.true.
!
DO j=1,inpdis
!
231 CONTINUE
iartic=iartic+1
IF (lfi%LMISOP) WRITE (unit=lfi%NULOUT,fmt=*)                &
& 'BOUCLE 235, J= ',j,', IARTIC= ',iartic,', IDECDE= ',idecde
!
IF (iartic.GE.icpttn.AND.iartic.LE.icpttx) THEN
  IF (iartic.EQ.icpttn) icpttn=icpttn+1
  IF (iartic.EQ.icpttx) icpttx=icpttx-1
  indic1=indik1
  indic2=indik2
!
!          ON FILTRE LES ARTICLES PHYSIQUES DEJA STOCKES DANS DES PAGES
!        DE DONNEES LORS DE LA PARTIE 2.1 ...
!
  DO ji=indic1,indic2
!
  IF (iartic.EQ.inucpl(ji)) THEN
    IF (ji.EQ.indik1) indik1=indik1+1
    IF (ji.EQ.indik2) indik2=indik2-1
    GOTO 231
  ENDIF
!
  ENDDO
!
ENDIF
!
idecde=(iartic-iardeb)*ilarph-idcdeb
inaphy=0
CALL lfiecx_fort                                        &
&               (lfi, krep,krang,iartic,ktab(idecde+1), &
&                lladon,iretin)
!
IF (iretin.EQ.1) THEN
  GOTO 903
ELSEIF (iretin.EQ.2) THEN
  GOTO 904
ELSEIF (iretin.NE.0) THEN
  GOTO 1001
ENDIF
!
ENDDO
!*
!     2.4 - ECRITURE DES ARTICLES PHYSIQUES COMPLETS QUE L'ON PEUT STOC-
!           KER DANS LES PAGES DE DONNEES "TAMPON".
!           ( TOUT EN PRESERVANT LES EMPLACEMENTS DE LA PREMIERE ET/OU
!             DE LA DERNIERE PAGE DE DONNEES, SI INCOMPLETE(S) )
!-----------------------------------------------------------------------
!
DO j=1,inpdta
inumpd=mod(lfi%NDERPD(krang)+j,lfi%JPNPDF)
!
241 CONTINUE
iartic=iartic+1
!
IF (iartic.GE.icpttn.AND.iartic.LE.icpttx) THEN
  IF (iartic.EQ.icpttn) icpttn=icpttn+1
  IF (iartic.EQ.icpttx) icpttx=icpttx-1
  indic1=indik1
  indic2=indik2
!
!          ON FILTRE LES ARTICLES PHYSIQUES DEJA STOCKES DANS DES PAGES
!        DE DONNEES LORS DE LA PARTIE 2.1 ...
!
  DO ji=indic1,indic2
!
  IF (iartic.EQ.inucpl(ji)) THEN
    IF (ji.EQ.indik1) indik1=indik1+1
    IF (ji.EQ.indik2) indik2=indik2-1
    GOTO 241
  ENDIF
!
  ENDDO
!
ENDIF
!
!         SI NECESSAIRE, "VIDAGE" SUR FICHIER DE LA PAGE A UTILISER.
!
inaphy=0
!
IF (lfi%LECRPD(inumpd,krang)) THEN
!
  CALL lfivid_fort                                       &
&                 (lfi, krep,krang,inumpd,ifourt,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
ENDIF
!
idecde=(iartic-iardeb)*ilarph-idcdeb
!
DO jd=1,ilarph
lfi%MTAMPD(ixt(jd,inumpd,krang))=ktab(idecde+jd)
ENDDO
!
lfi%LECRPD(inumpd,krang)=.true.
lfi%NUMAPD(inumpd,krang)=iartic
lfi%NLONPD(inumpd,krang)=ilarph
ENDDO
!
lfi%NDERPD(krang)=mod(lfi%NDERPD(krang)+inpdta,lfi%JPNPDF)
!*
!     2.5 - TRAITEMENT DE LA DERNIERE PAGE DE DONNEES SI ELLE EST
!           INCOMPLETE, ET SI ON EST DANS L'UN DES 2 CAS SUIVANTS:
!           SOIT ELLE DIFFERE DE LA PREMIERE, SOIT C'EST LA MEME QUE LA
!           PREMIERE ET ELLE COMMENCE JUSTE EN DEBUT D'ARTICLE PHYSIQUE.
!           CETTE PAGE EST CONSERVEE...EN ESPERANT QUE LE PROCHAIN ACCES
!           AU FICHIER SERA POUR L'ARTICLE LOGIQUE IMMEDIATEMENT
!           DERRIERE ( CAS DE CREATION DU FICHIER, PAR EXEMPLE ) .
!-----------------------------------------------------------------------
!
IF (lldern) THEN
!
  DO j=1,lfi%JPNPDF
  inumpj=mod(lfi%NDERPD(krang)+j,lfi%JPNPDF)
!
  IF (lfi%NUMAPD(inumpj,krang).EQ.iarfin) THEN
!
!           ARTICLE PHYSIQUE CHERCHE EN MEMOIRE.
!
    inumpd=inumpj
    GOTO 253
  ENDIF
!
  ENDDO
!
!           ARTICLE PHYSIQUE CHERCHE PAS EN MEMOIRE...
!
  inumpd=mod(1+lfi%NDERPD(krang),lfi%JPNPDF)
  inaphy=0
!
  IF (lfi%LECRPD(inumpd,krang)) THEN
!
    CALL lfivid_fort                                       &
&                   (lfi, krep,krang,inumpd,ifourt,iretin)
!
    IF (iretin.EQ.1) THEN
      GOTO 903
    ELSEIF (iretin.EQ.2) THEN
      GOTO 904
    ELSEIF (iretin.NE.0) THEN
      GOTO 1001
    ENDIF
!
  ENDIF
!
  IF (iarfin.LE.lfi%MDES1D(ixm(lfi%JPAXPD,krang))) THEN
    lfi%NUMAPD(inumpd,krang)=lfi%JPNIL
    inaphy=iarfin
    CALL lfildo_fort                                            &
&                   (lfi, krep,inumer,iarfin,                 &
&                    lfi%MTAMPD(ixt(1_jplikb ,inumpd,krang)), &
&                    lfi%NBREAD(krang),ifactm,                &
&                    lfi%YLFIC (krang),iretin)
!
    IF (iretin.NE.0) THEN
      GOTO 904
    ENDIF
!
    lfi%NLONPD(inumpd,krang)=ilarph
  ELSE
    lfi%NLONPD(inumpd,krang)=0
  ENDIF
!
  lfi%NUMAPD(inumpd,krang)=iarfin
!
253 CONTINUE
  idecde=(iarfin-iardeb)*ilarph-idcdeb
!
!         COMPLEMENT DE LA PAGE DE DONNEES ASSOCIEE AU DERNIER ARTICLE
!       PHYSIQUE OU DOIVENT ETRE STOCKEES LES DONNEES A ECRIRE.
!
  DO jd=1,idcfin
  lfi%MTAMPD(ixt(jd,inumpd,krang))=ktab(idecde+jd)
  ENDDO
!
  lfi%LECRPD(inumpd,krang)=.true.
  lfi%NLONPD(inumpd,krang)=max(lfi%NLONPD(inumpd,krang),idcfin)
  lfi%NDERPD(krang)=inumpd
ENDIF
!
GOTO 1001
!**
!     9.  - CI-DESSOUS, ETIQUETTES DE BRANCHEMENT EN CAS D'ERREUR E/S.
!      AU CAS OU, ON FORCE LE CODE-REPONSE ENTREE/SORTIE A ETRE POSITIF.
!-----------------------------------------------------------------------
!
903 CONTINUE
iretou=1
clacti='WRITE'
GOTO 909
!
904 CONTINUE
iretou=2
clacti='READ'
!
909 CONTINUE
krep=abs(krep)
IF (inaphy.NE.0) lfi%NUMAPH(krang)=inaphy
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE INTERNE EVENTUELLE,
!            VIA LE SOUS-PROGRAMME "LFIEMS", PUIS RETOUR.
!-----------------------------------------------------------------------
!
1001 CONTINUE
llfata=llmoer(krep,krang)
!
IF (krep.EQ.0) THEN
  kretin=0
ELSEIF (krep.GT.0) THEN
  kretin=iretou
ELSE
  kretin=3
ENDIF
!
IF (lfi%LMISOP.OR.llfata) THEN
  inimes=2
  clnspr='LFIECD'
  WRITE (unit=clmess,fmt='(''KREP='',I4,'', KRANG='',I3, &
&  '', KLONG='',I7,'', KPOSEC='',I8,'', KRETIN='',I2)')   &
&   krep, krang, klong, kposec, kretin
  CALL lfiems_fort                                  &
&                 (lfi, inumer,inimes,krep,.false., &
&                  clmess,clnspr,clacti)
ENDIF
!
IF (lhook) CALL dr_hook('LFIECD_FORT',1,zhook_handle)

CONTAINS

#include "lficom2.ixm.h"
#include "lficom2.ixt.h"
#include "lficom2.llmoer.h"

END SUBROUTINE lfiecd_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfiecd64                                  &
&           (krep, krang, ktab, klong, kposec, kretin)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KRANG                                  ! IN   
INTEGER (KIND=JPLIKB)  KLONG                                  ! IN   
INTEGER (KIND=JPLIKB)  KTAB       (klong)                     ! IN   
INTEGER (KIND=JPLIKB)  KPOSEC                                 ! IN   
INTEGER (KIND=JPLIKB)  KRETIN                                 !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfiecd_fort                                          &
&           (lfi, krep, krang, ktab, klong, kposec, kretin)

END SUBROUTINE lfiecd64

SUBROUTINE lfiecd                                    &
&           (krep, krang, ktab, klong, kposec, kretin)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KRANG                                  ! IN   
INTEGER (KIND=JPLIKM)  KLONG                                  ! IN   
INTEGER (KIND=JPLIKB)  KTAB       (klong)                     ! IN   
INTEGER (KIND=JPLIKM)  KPOSEC                                 ! IN   
INTEGER (KIND=JPLIKM)  KRETIN                                 !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfiecd_mt                                            &
&           (lfi, krep, krang, ktab, klong, kposec, kretin)

END SUBROUTINE lfiecd

SUBROUTINE lfiecd_mt                                      &
&           (lfi, krep, krang, ktab, klong, kposec, kretin)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KRANG                                  ! IN   
INTEGER (KIND=JPLIKM)  KLONG                                  ! IN   
INTEGER (KIND=JPLIKB)  KTAB       (klong)                     ! IN   
INTEGER (KIND=JPLIKM)  KPOSEC                                 ! IN   
INTEGER (KIND=JPLIKM)  KRETIN                                 !   OUT
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  IRANG                                  ! IN   
INTEGER (KIND=JPLIKB)  ILONG                                  ! IN   
INTEGER (KIND=JPLIKB)  IPOSEC                                 ! IN   
INTEGER (KIND=JPLIKB)  IRETIN                                 !   OUT
! Convert arguments

irang      = int(     krang, jplikb)
ilong      = int(     klong, jplikb)
iposec     = int(    kposec, jplikb)

CALL lfiecd_fort                                          &
&           (lfi, irep, irang, ktab, ilong, iposec, iretin)

krep       = int(      irep, jplikm)
kretin     = int(    iretin, jplikm)

END SUBROUTINE lfiecd_mt

!INTF KREP            OUT                                                              
!INTF KRANG         IN                                                                 
!INTF KTAB          IN    DIMS=KLONG                     KIND=JPLIKB                   
!INTF KLONG         IN                                                                 
!INTF KPOSEC        IN                                                                 
!INTF KRETIN          OUT