lfisup.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lfisup_fort                                     &
&                     (lfi, krep, knumer, cdnoma, klonut )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        SOUS-PROGRAMME PERMETTANT DE *SUPPRIMER* UN ARTICLE LOGIQUE
!     (DE DONNEES) SUR UNE UNITE LOGIQUE OUVERTE POUR LE LOGICIEL
!     DE FICHIERS INDEXES *LFI*; L'ARTICLE EST TRANSFORME EN "TROU"
!     DANS L'INDEX.
!**
!    ARGUMENTS : KREP   (SORTIE) ==> CODE-REPONSE DU SOUS-PROGRAMME;
!                KNUMER (ENTREE) ==> LFI%NUMERO DE L'UNITE LOGIQUE;
!                CDNOMA (ENTREE) ==> NOM DE L'ARTICLE A RECHERCHER;
!                KLONUT (SORTIE) ==> LONGUEUR *REUTILISABLE*
!                                    DE L'ARTICLE SUPPRIME.
!
!
TYPE(lficom) :: LFI
CHARACTER CDNOMA*(*), CLNOMA*(lfi%jpncpn)
!
INTEGER (KIND=JPLIKB) KREP, KNUMER, KLONUT, IMDESC 
INTEGER (KIND=JPLIKB) IRANG, IREP, ILCDNO, ILCLNO
INTEGER (KIND=JPLIKB) IDECBL, IPOSBL, IARTEX, INBALO 
INTEGER (KIND=JPLIKB) IRGPIM, IRGPIF, ILONGA, J
INTEGER (KIND=JPLIKB) IPOSEX, IFACTM, ILARPH, INALPP 
INTEGER (KIND=JPLIKB) INALPI, INTPPI, INBPIR
INTEGER (KIND=JPLIKB) INPPIM, IRECPI, IREC, IRGPI 
INTEGER (KIND=JPLIKB) IRPIMS, INPILE, IRNGMS
INTEGER (KIND=JPLIKB) IRETIN, INIMES
!
LOGICAL LLVERF
!
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!**
!     1.  -  CONTROLES DES PARAMETRES D'APPEL, PUIS INITIALISATIONS.
!-----------------------------------------------------------------------
!
!        Appel legerement anticipe a LFINUM, garantissant l'initialisa-
!     tion des variables globales du logiciel a la 1ere utilisation.
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFISUP_FORT',0,zhook_handle)
clacti=''
CALL lfinum_fort                    &
&               (lfi, knumer,irang)
llverf=.false.
irep=0
klonut=0
ilcdno=int(len(cdnoma), jplikb)
!
IF (ilcdno.LE.0) THEN
  irep=-15
  clnoma=lfi%CHINCO(:lfi%JPNCPN)
  ilclno=lfi%JPNCPN
  GOTO 1001
ELSEIF (cdnoma.EQ.' ') THEN
  irep=-18
  clnoma=' '
  ilclno=1
  GOTO 1001
ENDIF
!
!        Recherche de la longueur "utile" du nom d'article specifie.
!        (c'est-a-dire sans tenir compte des blancs terminaux eventuels)
!
idecbl=0
!
101 CONTINUE
iposbl=idecbl+int(index(cdnoma(idecbl+1:),' '), jplikb)
!
IF (iposbl.LE.idecbl) THEN
  ilclno=ilcdno
ELSEIF (cdnoma(iposbl:).EQ.' ') THEN
  ilclno=iposbl-1
ELSE
  idecbl=iposbl
  GOTO 101
ENDIF
!
IF (ilclno.LE.lfi%JPNCPN) THEN
  clnoma=cdnoma(:ilclno)
ELSE
  clnoma=cdnoma(:lfi%JPNCPN)
  ilclno=lfi%JPNCPN
  irep=-15
  GOTO 1001
ENDIF
!
IF (irang.EQ.0) THEN
  irep=-1
  GOTO 1001
ENDIF
!
 IF (lfi%LMULTI) CALL lfiver_fort                              &
&                                (lfi, lfi%VERRUE(irang),'ON')
llverf=lfi%LMULTI
!
IF (lfi%NEXPOR(irang).GT.0) THEN
!
!         Fichier en cours d'export... la seule modification acceptee
!         est l'ajout de nouveaux articles.
!
  irep=-37
  GOTO 1001
ENDIF
!
iartex=0
inbalo=lfi%MDES1D(ixm(lfi%JPNALO,irang))
!
IF (inbalo.NE.0) THEN
!**
!     2.  -  EXPLORATION DES (PAIRES DE) PAGES ET ARTICLES D'INDEX,
!            A LA RECHERCHE DE L'ARTICLE LOGIQUE A SUPPRIMER.
!-----------------------------------------------------------------------
!
  CALL lfiran_fort                                  &
&                 (lfi, irep,irang,clnoma(:ilclno), &
&                  irgpim,iartex,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
ENDIF
!
IF (iartex.EQ.0) THEN
  irep=-20
  clacti=clnoma(:ilclno)
  GOTO 1001
ENDIF
!
!        ON COMPLETE LES CARACTERISTIQUES DE L'ARTICLE PAR SA LONGUEUR,
!     EXPRIMEE EN TERME DE DONNEES "LISIBLES" POUR L'UTILISATEUR.
!
irgpif=lfi%MRGPIF(irgpim)
!
IF (.NOT.lfi%LPHASP(irgpim)) THEN
!
  CALL lfipha_fort                                &
&                 (lfi, irep,irang,irgpim,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
ENDIF
!
ilonga=lfi%MLGPOS(ixm(2*iartex-1,irgpim))
iposex=lfi%MLGPOS(ixm(2*iartex,irgpim))
ifactm=lfi%MFACTM(irang)
ilarph=lfi%JPLARD*ifactm
inalpp=lfi%JPNAPP*ifactm
inalpi=min(inalpp,inbalo-(irgpif-1)*inalpp)
intppi=(inbalo-1+inalpp)/inalpp
inbpir=lfi%MDES1D(ixm(lfi%JPNPIR,irang))
inppim=lfi%NPPIMM(irang)
!**
!     3.  -  AFIN D'ASSURER UN MEILLEUR RECYCLAGE (EVENTUEL) DE CE FUTUR
!            TROU, ON CALCULE SA LONGUEUR EFFECTIVEMENT REUTILISABLE.
!-----------------------------------------------------------------------
!
IF (iartex.EQ.1.AND.irgpif.GT.inbpir) THEN
!
!            IL Y A EU DEBORDEMENT DES P.A.I. PREALLOUEES, ET IL Y A
!        EN OUTRE UNE P.A.I. SUR LE FICHIER, JUSTE DERRIERE L'ARTICLE
!        LOGIQUE AUQUEL ON S'INTERESSE.
!
  irecpi=lfi%MDES1D(ixm(ilarph+1-(irgpif-inbpir),irang))
  klonut=ilarph*(irecpi-1)-iposex+1
ELSEIF (iartex.EQ.inalpi.AND.irgpif.EQ.intppi) THEN
!
!           CAS OU L'ARTICLE TROUVE EST LE DERNIER ARTICLE LOGIQUE DE
!        DONNEES, SANS P.A.I. JUSTE DERRIERE.
!           LA DERNIERE POSITION REUTILISABLE SANS AUGMENTER LA TAILLE
!       DU FICHIER CORRESPOND A LA FIN DU DERNIER ARTICLE PHYSIQUE
!       CONTENANT DES DONNEES, OU A LA FIN DU DERNIER ARTICLE PHYSIQUE
!       EFFECTIVEMENT ECRIT SUR LE FICHIER.
!
  imdesc=lfi%MDES1D(ixm(lfi%JPNAPH,irang))
  irec=max(1+(iposex+ilonga-2)/ilarph,imdesc)
  klonut=ilarph*irec-iposex+1
!
!          EN ARRIVANT AU TEST CI-DESSOUS, ON EST DONC SUR QUE L'ARTICLE
!        TROUVE N'EST PAS LE DERNIER ARTICLE LOGIQUE.
!          ON VA CALCULER LA DISTANCE ENTRE LES DEBUTS D'ARTICLE,
!        CE QUI CONSTITUE LA LONGUEUR REUTILISABLE CHERCHEE.
!
ELSEIF (iartex.NE.inalpp) THEN
!
!           L'ARTICLE SUIVANT EST DANS LA MEME PAGE D'INDEX...
!
  klonut=lfi%MLGPOS(ixm(2*iartex+2,irgpim))-iposex
ELSE
!
!           L'ARTICLE TROUVE EST EN PLUS EN FIN DE PAGE D'INDEX...
!       RECHERCHE DANS LES P.P.I. DE LA P.A.I. SUIVANTE.
!
  DO j=2,inppim
  irgpi=lfi%MRGPIM(j,irang)
!
  IF (lfi%MRGPIF(irgpi).EQ.(irgpif+1)) THEN
!
    irpims=irgpi
!
    IF (.NOT.lfi%LPHASP(irpims)) THEN
!
      CALL lfipha_fort                                &
&                     (lfi, irep,irang,irpims,iretin)
!
      IF (iretin.EQ.1) THEN
        GOTO 903
      ELSEIF (iretin.EQ.2) THEN
        GOTO 904
      ELSEIF (iretin.NE.0) THEN
        GOTO 1001
      ENDIF
!
    ENDIF
!
    GOTO 305
!
  ENDIF
!
  ENDDO
!
!             LA P.A.I. SUIVANTE (EN RANG DANS LE FICHIER) N'EST PAS
!          EN MEMOIRE; DECIDEMENT, CELA SE GATE ! ... ON L'Y MET.
!
  inpile=2
  CALL lfipim_fort                                 &
&                 (lfi, krep,irang,irngms,irpims,  &
&                  irgpif+1,irgpif,inpile, iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
305 CONTINUE
!
  klonut=lfi%MLGPOS(ixm(2_jplikb ,irpims))-iposex
ENDIF
!**
!     4  -  TRANSFORMATION EFFECTIVE DE L'ARTICLE LOGIQUE DE DONNEES
!           EN "TROU" D'INDEX.
!-----------------------------------------------------------------------
!
lfi%CNOMAR(ixc(iartex,irgpim))=' '
IF (lfi%NDERGF(irang).NE.lfi%JPNIL.AND.   &
&    lfi%CNDERA(irang).EQ.clnoma(:ilclno)) &
&    lfi%CNDERA(irang)=' '
lfi%LECRPI(irgpim,1)=.true.
lfi%NBSUPP(irang)=lfi%NBSUPP(irang)+1
lfi%LMIMAL(irang)=lfi%LMIMAL(irang).OR.                       &
&                  ilonga.EQ.lfi%MDES1D(ixm(lfi%JPLNAL,irang)) &
&              .OR.ilonga.EQ.lfi%MDES1D(ixm(lfi%JPLXAL,irang))
lfi%NBTROU(irang)=lfi%NBTROU(irang)+1
lfi%MDES1D(ixm(lfi%JPLTAL,irang))=                         &
&                  lfi%MDES1D(ixm(lfi%JPLTAL,irang))-ilonga
!
IF (klonut.NE.ilonga) THEN
  lfi%MLGPOS(ixm(2*iartex-1,irgpim))=klonut
  lfi%LECRPI(irgpim,2)=.true.
ENDIF
!
IF (.NOT.lfi%LMODIF(irang)) THEN
!
!         CAS DE LA PREMIERE MODIFICATION DEPUIS L'OUVERTURE DU FICHIER.
!
  lfi%LMODIF(irang)=.true.
  CALL lfimoe_fort                         &
&                 (lfi, irep,irang,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
ENDIF
!
GOTO 1001
!**
!     9.  - CI-DESSOUS, ETIQUETTES DE BRANCHEMENT EN CAS D'ERREUR E/S.
!-----------------------------------------------------------------------
!
903 CONTINUE
clacti='WRITE'
GOTO 909
!
904 CONTINUE
clacti='READ'
!
909 CONTINUE
!
!      AU CAS OU, ON FORCE LE CODE-REPONSE ENTREE/SORTIE A ETRE POSITIF.
!
irep=abs(irep)
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "LFIEMS" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
IF (irang.NE.0) THEN
  lfi%NDEROP(irang)=15
  lfi%NDERCO(irang)=irep
   IF (llverf) CALL lfiver_fort                               &
&                              (lfi, lfi%VERRUE(irang),'OFF')
ENDIF
!
IF (llfata.OR.ixnims(irang).EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('LFISUP_FORT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='LFISUP'
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', CDNOMA='''''',A,'''''', KLONUT='',I8)')      &
&     krep,knumer,clnoma(:ilclno),klonut
CALL lfiems_fort                                 &
&               (lfi, knumer,inimes,irep,llfata, &
&                clmess,clnspr,clacti)
!
IF (lhook) CALL dr_hook('LFISUP_FORT',1,zhook_handle)

CONTAINS

#include "lficom2.ixc.h"
#include "lficom2.ixm.h"
#include "lficom2.ixnims.h"
#include "lficom2.llmoer.h"

END SUBROUTINE lfisup_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfisup64                      &
&           (krep, knumer, cdnoma, klonut)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKB)  KLONUT                                 !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfisup_fort                               &
&           (lfi, krep, knumer, cdnoma, klonut)

END SUBROUTINE lfisup64

SUBROUTINE lfisup                        &
&           (krep, knumer, cdnoma, klonut)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKM)  KLONUT                                 !   OUT

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfisup_mt                                &
&           (lfi, krep, knumer, cdnoma, klonut)

END SUBROUTINE lfisup

SUBROUTINE lfisup_mt                          &
&           (lfi, krep, knumer, cdnoma, klonut)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKM)  KLONUT                                 !   OUT
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  ILONUT                                 !   OUT
! Convert arguments

inumer     = int(    knumer, jplikb)

CALL lfisup_fort                               &
&           (lfi, irep, inumer, cdnoma, ilonut)

krep       = int(      irep, jplikm)
klonut     = int(    ilonut, jplikm)

END SUBROUTINE lfisup_mt

!INTF KREP            OUT 
!INTF KNUMER        IN    
!INTF CDNOMA        IN    
!INTF KLONUT          OUT