diag_inline_seafluxn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE diag_inline_seaflux_n (DGO, D, DC, DI, DIC, DGMSI, S,              &
                                  PTSTEP, PTA, PQA, PPA, PPS, PRHOA, PZONA,           &
                                  PMERA, PHT, PHW, PCD, PCDN, PCH, PCE, PRI, PHU,     &
                                  PZ0H, PQSAT, PSFTH, PSFTQ, PSFZON, PSFMER,          &
                                  PDIR_SW, PSCA_SW, PLW, PDIR_ALB, PSCA_ALB,          &
                                  PEMIS, PTRAD, PRAIN, PSNOW,                         & 
                                  PCD_ICE, PCDN_ICE, PCH_ICE, PCE_ICE, PRI_ICE,       &
                                  PZ0_ICE, PZ0H_ICE, PQSAT_ICE, PSFTH_ICE, PSFTQ_ICE, &
                                   PSFZON_ICE, PSFMER_ICE )
                                          
!     #####################################################################################
!
!!****  *DIAG_INLINE_SEAFLUX_n * - computes diagnostics during SEAFLUX time-step
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      Modified    01/2006 : sea flux parameterization.
!!      B. Decharme 08/2009 : Diag for Earth System Model Coupling
!!      S. Riette   06/2009 CLS_2M becomes CLS_TQ, CLS_TQ and CLS_WIND have one
!!                          more argument (height of diagnostic)
!!      B. Decharme 04/2013 : Add EVAP and SUBL diag
!!      S. Senesi   01/2014 ! introduce fractional seaice and sea-ice model 
!!------------------------------------------------------------------
!
USE modd_diag_n, ONLY : diag_t, diag_options_t
USE modd_diag_misc_seaice_n, ONLY : diag_misc_seaice_t
USE modd_seaflux_n, ONLY : seaflux_t
!
USE modd_csts,           ONLY : xtts
USE modd_surf_par,       ONLY : xundef
USE modd_sfx_oasis,      ONLY : lcpl_sea
!
USE modd_types_glt,     ONLY : t_glt
USE modd_glt_param ,    ONLY : gelato_dim=>nx
USE mode_glt_stats ,    ONLY : glt_avhicem, glt_avhsnwm
USE modi_cls_tq
USE modi_cls_wind
USE modi_diag_surf_budget_sea
USE modi_diag_surf_budgetc
USE modi_diag_cpl_esm_sea
!
USE modi_seaflux_albedo
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(diag_options_t), INTENT(INOUT) :: DGO
TYPE(diag_t), INTENT(INOUT) :: D
TYPE(diag_t), INTENT(INOUT) :: DC
TYPE(diag_t), INTENT(INOUT) :: DI
TYPE(diag_t), INTENT(INOUT) :: DIC
TYPE(diag_misc_seaice_t), INTENT(INOUT) :: DGMSI
TYPE(seaflux_t), INTENT(INOUT) :: S
!
REAL,               INTENT(IN) :: PTSTEP ! atmospheric time-step                 (s)
REAL, DIMENSION(:), INTENT(IN) :: PTA    ! atmospheric temperature
REAL, DIMENSION(:), INTENT(IN) :: PQA    ! atmospheric specific humidity
REAL, DIMENSION(:), INTENT(IN) :: PPA    ! atmospheric level pressure
REAL, DIMENSION(:), INTENT(IN) :: PPS    ! surface pressure
REAL, DIMENSION(:), INTENT(IN) :: PRHOA  ! air density
REAL, DIMENSION(:), INTENT(IN) :: PZONA  ! zonal wind
REAL, DIMENSION(:), INTENT(IN) :: PMERA  ! meridian wind
REAL, DIMENSION(:), INTENT(IN) :: PHT    ! atmospheric level height
REAL, DIMENSION(:), INTENT(IN) :: PHW    ! atmospheric level height for wind
REAL, DIMENSION(:), INTENT(IN) :: PCD    ! drag coefficient for momentum
REAL, DIMENSION(:), INTENT(IN) :: PCDN   ! neutral drag coefficient
REAL, DIMENSION(:), INTENT(IN) :: PCH    ! drag coefficient for heat
REAL, DIMENSION(:), INTENT(IN) :: PCE    ! drag coefficient for vapor
REAL, DIMENSION(:), INTENT(IN) :: PRI    ! Richardson number
REAL, DIMENSION(:), INTENT(IN) :: PHU    ! near-surface humidity
REAL, DIMENSION(:), INTENT(IN) :: PZ0H   ! roughness length for heat
REAL, DIMENSION(:), INTENT(IN) :: PQSAT  ! humidity at saturation
REAL, DIMENSION(:), INTENT(IN) :: PSFZON ! zonal friction
REAL, DIMENSION(:), INTENT(IN) :: PSFMER ! meridian friction
REAL, DIMENSION(:), INTENT(IN) :: PSFTH  ! heat flux  (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: PSFTQ  ! water flux (kg/m2/s)
REAL, DIMENSION(:,:),INTENT(IN):: PDIR_SW   ! direct  solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:,:),INTENT(IN):: PSCA_SW   ! diffuse solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: PLW       ! longwave radiation (on horizontal surf.)
REAL, DIMENSION(:), INTENT(IN) :: PTRAD     ! radiative temperature                 (K)
REAL, DIMENSION(:,:),INTENT(IN):: PDIR_ALB  ! direct albedo for each spectral band  (-)
REAL, DIMENSION(:,:),INTENT(IN):: PSCA_ALB  ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(:), INTENT(IN) :: PEMIS     ! emissivity                            (-)
!
REAL, DIMENSION(:), INTENT(IN) :: PRAIN     ! Rainfall (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: PSNOW     ! Snowfall (kg/m2/s)
!
REAL, DIMENSION(:), INTENT(IN)    :: PCD_ICE    ! drag coefficient for momentum
REAL, DIMENSION(:), INTENT(IN)    :: PCDN_ICE   ! neutral drag coefficient
REAL, DIMENSION(:), INTENT(IN)    :: PCH_ICE    ! drag coefficient for heat
REAL, DIMENSION(:), INTENT(IN)    :: PCE_ICE    ! drag coefficient for vapor
REAL, DIMENSION(:), INTENT(IN)    :: PRI_ICE    ! Richardson number
REAL, DIMENSION(:), INTENT(IN)    :: PZ0_ICE    ! roughness length for momentum
REAL, DIMENSION(:), INTENT(IN)    :: PZ0H_ICE   ! roughness length for heat
REAL, DIMENSION(:), INTENT(IN)    :: PQSAT_ICE  ! humidity at saturation
REAL, DIMENSION(:), INTENT(IN)    :: PSFTH_ICE  ! heat flux  (W/m2)
REAL, DIMENSION(:), INTENT(IN)    :: PSFTQ_ICE  ! water flux (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN)    :: PSFZON_ICE ! zonal friction
REAL, DIMENSION(:), INTENT(IN)    :: PSFMER_ICE ! meridian friction
!
!*      0.2    declarations of local variables
!
LOGICAL                         :: GSIC
REAL, DIMENSION(SIZE(PTA))      :: ZZ0W
REAL, DIMENSION(SIZE(PTA))      :: ZH
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('DIAG_INLINE_SEAFLUX_N',0,zhook_handle)
!
! * Mean surface temperature need to couple with AGCM
!
IF (s%LHANDLE_SIC) THEN
   d%XTS   (:) = (1 - s%XSIC(:)) * s%XSST(:) + s%XSIC(:) * s%XTICE(:)
   d%XTSRAD(:) = ptrad(:)
ELSE
   d%XTS   (:) = s%XSST (:)
   d%XTSRAD(:) = ptrad(:)
ENDIF
!
IF (.NOT. s%LSBL) THEN
!
  IF (dgo%N2M==2) THEN
    zh(:)=2.          
    CALL cls_tq(pta, pqa, ppa, pps, pht, pcd, pch, pri, &
                s%XSST, phu, pz0h, zh,d%XT2M, d%XQ2M, d%XHU2M)
    zh(:)=10.                
    CALL cls_wind(pzona, pmera, phw,pcd, pcdn, pri, zh,  &
                  d%XZON10M, d%XMER10M)  
    IF (s%LHANDLE_SIC) THEN
       zh(:)=2.          
       CALL cls_tq(pta, pqa, ppa, pps, pht, pcd_ice, pch_ice, pri_ice,       &
            s%XTICE, phu, pz0h_ice, zh, di%XT2M, di%XQ2M, di%XHU2M)  
       zh(:)=10.                
       CALL cls_wind(pzona, pmera, phw, pcd_ice, pcdn_ice, pri_ice, zh,  &
            di%XZON10M, di%XMER10M  )  
    ENDIF 
  END IF
!
  IF (dgo%N2M>=1) THEN
     IF (s%LHANDLE_SIC) THEN
        !
        d%XT2M    = d%XT2M    * (1 - s%XSIC) + di%XT2M    * s%XSIC
        d%XQ2M    = d%XQ2M    * (1 - s%XSIC) + di%XQ2M    * s%XSIC
        d%XHU2M   = d%XHU2M   * (1 - s%XSIC) + di%XHU2M   * s%XSIC
        !
        d%XZON10M(:) = d%XZON10M(:) * (1 - s%XSIC(:)) + di%XZON10M(:) * s%XSIC(:)
        d%XMER10M(:) = d%XMER10M(:) * (1 - s%XSIC(:)) + di%XMER10M(:) * s%XSIC(:)
        di%XWIND10M(:) = sqrt(di%XZON10M(:)**2+di%XMER10M(:)**2)
        !
        d%XRI    = pri     * (1 - s%XSIC) + pri_ice     * s%XSIC
        di%XRI   =pri_ice
     ELSE
        d%XRI    =pri
     ENDIF
    !
    d%XT2M_MIN(:) = min(d%XT2M_MIN(:),d%XT2M(:))
    d%XT2M_MAX(:) = max(d%XT2M_MAX(:),d%XT2M(:))
    !
    d%XHU2M_MIN(:) = min(d%XHU2M_MIN(:),d%XHU2M(:))
    d%XHU2M_MAX(:) = max(d%XHU2M_MAX(:),d%XHU2M(:))
    !
    d%XWIND10M(:) = sqrt(d%XZON10M(:)**2+d%XMER10M(:)**2)
    d%XWIND10M_MAX(:) = max(d%XWIND10M_MAX(:),d%XWIND10M(:))
    !
  ENDIF
!
ELSE
  IF (dgo%N2M>=1) THEN
    d%XT2M    = xundef
    d%XQ2M    = xundef
    d%XHU2M   = xundef
    d%XZON10M = xundef
    d%XMER10M = xundef
    d%XRI     = pri
  ENDIF
ENDIF
!
IF (dgo%LSURF_BUDGET.OR.dgo%LSURF_BUDGETC) THEN
!
  CALL seaflux_albedo(pdir_sw,psca_sw,pdir_alb,psca_alb,d%XALBT)
!
  CALL diag_surf_budget_sea   (d, di, s, xtts, prhoa, psfth, psfth_ice, &
                               psftq, psftq_ice, pdir_sw, psca_sw, plw,   &
                               pdir_alb, psca_alb, pemis, ptrad,          &
                               psfzon, psfzon_ice, psfmer, psfmer_ice   ) 
  IF (s%LHANDLE_SIC) di%XLE = d%XLEI
!
END IF
!
IF(dgo%LSURF_BUDGETC)THEN
  !
  CALL diag_surf_budgetc(d, dc, ptstep, .true.)
  !
  IF (s%LHANDLE_SIC) THEN
     CALL diag_surf_budgetc(di, dic, ptstep, .false.)
     dic%XLE = dc%XLEI
  ENDIF
  !
ENDIF
!
IF (dgo%LCOEF) THEN
   IF (s%LHANDLE_SIC) THEN 
      !
      !* Transfer coefficients
      !
      d%XCD = (1 - s%XSIC) * pcd + s%XSIC * pcd_ice
      d%XCH = (1 - s%XSIC) * pch + s%XSIC * pch_ice
      d%XCE = (1 - s%XSIC) * pce + s%XSIC * pce_ice
      !
      !* Roughness lengths
      !
      zz0w = ( 1 - s%XSIC ) * 1.0/(log(phw/s%XZ0)    **2)  +  s%XSIC   * 1.0/(log(phw/pz0_ice)**2)  
      d%XZ0  = phw  * exp( - sqrt( 1./  zz0w ))
      zz0w = ( 1 - s%XSIC ) * 1.0/(log(phw/pz0h)    **2)  +  s%XSIC   * 1.0/(log(phw/pz0h_ice)**2)  
      d%XZ0H = phw  * exp( - sqrt( 1./  zz0w ))

      di%XCD  = pcd_ice
      di%XCH  = pch_ice
      di%XZ0  = pz0_ice
      di%XZ0H = pz0h_ice
      !
   ELSE
      !
      !* Transfer coefficients
      !
      d%XCD = pcd
      d%XCH = pch
      d%XCE = pce
      !
      !* Roughness lengths
      !
      d%XZ0  = s%XZ0
      d%XZ0H = pz0h
   ENDIF
   !
ENDIF
!
IF (dgo%LSURF_VARS) THEN
  !
  !* Humidity at saturation
  !
   IF (s%LHANDLE_SIC) THEN 
      d%XQS     = (1 - s%XSIC) * pqsat + s%XSIC * pqsat_ice
      di%XQS = pqsat_ice
   ELSE 
      d%XQS = pqsat
   ENDIF
ENDIF
!
! Diags from embedded Seaice model
! CALL DIAG_INLINE_SEAICE() : simply  : 
!
IF (dgmsi%LDIAG_MISC_SEAICE) THEN
   IF (trim(s%CSEAICE_SCHEME) == 'GELATO') THEN 
      gelato_dim=SIZE(pta)
      dgmsi%XSIT  = reshape(glt_avhicem(s%TGLT%dom,s%TGLT%sit),(/gelato_dim/))
      dgmsi%XSND  = reshape(glt_avhsnwm(s%TGLT%dom,s%TGLT%sit),(/gelato_dim/))
      dgmsi%XMLT  = s%TGLT%oce_all(:,1)%tml
   ELSE
      ! Placeholder for an alternate seaice scheme
   ENDIF
ENDIF
!
! Diags for Earth System Model coupling or for embedded Seaice model
! (we are actually using XCPL_.. variables for feeding the seaice model)
!
gsic=(s%LHANDLE_SIC.AND.(s%CSEAICE_SCHEME /= 'NONE  '))
!
IF (lcpl_sea.OR.gsic) THEN
!
  CALL diag_cpl_esm_sea(s, d, di, ptstep, psftq, prain, psnow, &
                        plw, psfth_ice, psftq_ice, pdir_sw, psca_sw, gsic )
! 
ENDIF
IF (lhook) CALL dr_hook('DIAG_INLINE_SEAFLUX_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_inline_seaflux_n