diag_cpl_esm_sea.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE diag_cpl_esm_sea (S, D, DI, PTSTEP, PSFTQ, PRAIN, PSNOW, &
                                    PLW, PSFTH_ICE, PSFTQ_ICE, PDIR_SW, PSCA_SW, OSIC)  
!     ###################################################################
!
!!****  *DIAG_CPL_ESM_SEA * - Computes diagnostics over sea for 
!!                Earth system model coupling or embedded seaice scheme
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     B. Decharme 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    08/2009
!!      S.Senesi    01/2014  Adapt to embedded seaice scheme (SWU and LWU 
!!                           for seaice are provided as inputs)
!!      A.Voldoire  04/2015  Add LCPL_SEAICE test
!!------------------------------------------------------------------
!
USE modd_diag_n, ONLY : diag_t
USE modd_seaflux_n, ONLY : seaflux_t
!
USE modd_csts,      ONLY : xstefan, xlstt
USE modd_water_par, ONLY : xemiswatice
!
USE modd_sfx_oasis, ONLY : lcpl_seaice
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(seaflux_t), INTENT(INOUT) :: S
TYPE(diag_t), INTENT(INOUT) :: D
TYPE(diag_t), INTENT(INOUT) :: DI
!
REAL,               INTENT(IN) :: PTSTEP    ! atmospheric time-step
REAL, DIMENSION(:), INTENT(IN) :: PSFTQ     ! water flux
REAL, DIMENSION(:), INTENT(IN) :: PRAIN     ! Rainfall
REAL, DIMENSION(:), INTENT(IN) :: PSNOW     ! Snowfall
REAL, DIMENSION(:), INTENT(IN) :: PLW       ! longwave radiation (on horizontal surf.)
REAL, DIMENSION(:), INTENT(IN) :: PSFTH_ICE ! heat flux  (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: PSFTQ_ICE ! water flux (kg/m2/s)
REAL, DIMENSION(:,:),INTENT(IN):: PDIR_SW   ! direct  solar radiation (on horizontal surf.)
REAL, DIMENSION(:,:),INTENT(IN):: PSCA_SW   ! diffuse solar radiation (on horizontal surf.)
LOGICAL,            INTENT(IN) :: OSIC
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(S%XICE_ALB)) :: ZSWU, ZTICE4
!
INTEGER                      :: ISWB ! number of SW bands
INTEGER                      :: JSWB ! loop counter on number of SW bands
INTEGER                      :: INI  ! number of points
INTEGER                      :: JI   ! loop counter on number of points
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('DIAG_CPL_ESM_SEA',0,zhook_handle)
!
!-------------------------------------------------------------------------------------
! Total or free-ice sea flux
!-------------------------------------------------------------------------------------
!
!* 10m wind speed (m)
!
s%XCPL_SEA_WIND(:) = s%XCPL_SEA_WIND(:) + ptstep * sqrt(d%XZON10M(:)**2+d%XMER10M(:)**2)
! 
!* wind stress (Pa.s)
!
s%XCPL_SEA_FWSU(:) = s%XCPL_SEA_FWSU(:) + ptstep * d%XFMU(:)
s%XCPL_SEA_FWSV(:) = s%XCPL_SEA_FWSV(:) + ptstep * d%XFMV(:)
s%XCPL_SEA_FWSM(:) = s%XCPL_SEA_FWSM(:) + ptstep * sqrt(d%XFMU(:)**2+d%XFMV(:)**2)
!
!* Solar net heat flux (J/m2)
!
s%XCPL_SEA_SNET(:) = s%XCPL_SEA_SNET(:) + ptstep * (d%XSWD(:) - d%XSWU(:))
!
!* Non solar heat flux (J/m2)
!
s%XCPL_SEA_HEAT(:) = s%XCPL_SEA_HEAT(:) + ptstep * (d%XGFLUX(:) + d%XSWU(:) - d%XSWD(:)) 
!
!* Evaporation (kg/m2)
!
s%XCPL_SEA_EVAP(:) = s%XCPL_SEA_EVAP(:) + ptstep * psftq(:)
!
!* Precip (kg/m2)
! 
s%XCPL_SEA_RAIN(:) = s%XCPL_SEA_RAIN(:) + ptstep * prain(:)
s%XCPL_SEA_SNOW(:) = s%XCPL_SEA_SNOW(:) + ptstep * psnow(:)
!
!-------------------------------------------------------------------------------------
! Ice flux
!-------------------------------------------------------------------------------------
IF (lcpl_seaice.OR.osic) THEN
!
  ini  = SIZE(pdir_sw,1)
  iswb = SIZE(pdir_sw,2)
!
!* Solar net heat flux (J/m2)
!
  IF (osic) THEN
    zswu(:)=di%XSWU(:)
  ELSE
    zswu(:)=0.0
    DO jswb=1,iswb
      DO ji=1,ini
         zswu(ji) = zswu(ji) + (pdir_sw(ji,jswb)+psca_sw(ji,jswb)) * s%XICE_ALB(ji)
      ENDDO
    ENDDO
  ENDIF
!
  s%XCPL_SEAICE_SNET(:) = s%XCPL_SEAICE_SNET(:) + ptstep * (d%XSWD(:) - zswu(:))
!
!* Non solar heat flux (J/m2)
!
  IF (osic) THEN
    s%XCPL_SEAICE_HEAT(:) = s%XCPL_SEAICE_HEAT(:) + ptstep * &
              ( plw(:) - di%XLWU(:) - psfth_ice(:) - xlstt*psftq_ice(:) )
  ELSE
    ztice4(:)=s%XTICE(:)**4
    s%XCPL_SEAICE_HEAT(:) = s%XCPL_SEAICE_HEAT(:) + ptstep * ( xemiswatice*(plw(:)-xstefan*ztice4(:)) &
                                                         - psfth_ice(:) - xlstt*psftq_ice(:)      ) 
  ENDIF 
!
!* Sublimation (kg/m2)
!
  s%XCPL_SEAICE_EVAP(:) = s%XCPL_SEAICE_EVAP(:) + ptstep * psftq_ice(:)
!
ENDIF
!
IF (lhook) CALL dr_hook('DIAG_CPL_ESM_SEA',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_cpl_esm_sea