diag_surf_budget_sea.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE  diag_surf_budget_sea(D, DI, S, PTT, PRHOA, PSFTH, PSFTH_ICE, &
                                 PSFTQ, PSFTQ_ICE, PDIR_SW, PSCA_SW, PLW,    &
                                 PDIR_ALB, PSCA_ALB, PEMIS, PTRAD,           &
                                 PSFZON, PSFZON_ICE, PSFMER, PSFMER_ICE   ) 


!     ###############################################################################
!
!!****  *DIAG_SURF_BUDGET_WATER * - Computes diagnostics over water
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!       B. decharme 04/2013 : Add EVAP and SUBL diag
!       S.Senesi    01/2014 : Handle fluxes on seaice
!!------------------------------------------------------------------
!
USE modd_seaflux_n, ONLY : seaflux_t
USE modd_diag_n, ONLY : diag_t
!
USE modd_csts,           ONLY : xstefan, xlstt, xlvtt
USE modd_water_par,      ONLY : xemiswatice, xalbseaice
! 
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(diag_t), INTENT(INOUT) :: D
TYPE(diag_t), INTENT(INOUT) :: DI
TYPE(seaflux_t), INTENT(INOUT) :: S
!
REAL,               INTENT(IN) :: PTT       ! freezing temperature of water surface
REAL, DIMENSION(:), INTENT(IN) :: PRHOA     ! air density
REAL, DIMENSION(:), INTENT(IN) :: PSFTH     ! heat flux
REAL, DIMENSION(:), INTENT(IN) :: PSFTH_ICE ! heat flux on seaice
!
REAL, DIMENSION(:), INTENT(IN) :: PSFTQ     ! water flux
REAL, DIMENSION(:), INTENT(IN) :: PSFTQ_ICE ! water flux on seaice
!
REAL, DIMENSION(:,:),INTENT(IN):: PDIR_SW   ! direct  solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:,:),INTENT(IN):: PSCA_SW   ! diffuse solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: PLW       ! longwave radiation (on horizontal surf.)
!
REAL, DIMENSION(:,:),INTENT(IN):: PDIR_ALB  ! direct albedo for each spectral band  (-)
REAL, DIMENSION(:,:),INTENT(IN):: PSCA_ALB  ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(:), INTENT(IN) :: PEMIS     ! emissivity                            (-)
REAL, DIMENSION(:), INTENT(IN) :: PTRAD     ! radiative temperature                 (K)
!
REAL, DIMENSION(:), INTENT(IN) :: PSFZON    ! zonal friction
REAL, DIMENSION(:), INTENT(IN) :: PSFZON_ICE! zonal friction
REAL, DIMENSION(:), INTENT(IN) :: PSFMER    ! meridional friction
REAL, DIMENSION(:), INTENT(IN) :: PSFMER_ICE! meridional friction
!
!*      0.2    declarations of local variables
!
INTEGER                      :: I
INTEGER                      :: ISWB ! number of SW bands
INTEGER                      :: JSWB ! loop counter on number of SW bands
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('DIAG_SURF_BUDGET_SEA',0,zhook_handle)
!
iswb = SIZE(pdir_sw,2)
! 
!* total incoming and outgoing SW
!
DO jswb=1,iswb
  d%XSWBD(:,jswb) = pdir_sw(:,jswb)                    + psca_sw(:,jswb)
  d%XSWBU(:,jswb) = pdir_sw(:,jswb) * pdir_alb(:,jswb) + psca_sw(:,jswb) * psca_alb(:,jswb) 
ENDDO
!
d%XSWD(:) = 0.
d%XSWU(:) = 0.
DO jswb=1,iswb
   d%XSWD(:) = d%XSWD(:) + d%XSWBD(:,jswb)
   d%XSWU(:) = d%XSWU(:) + d%XSWBU(:,jswb)
ENDDO
!
!*incoming outgoing LW
!
d%XLWD(:)=plw(:)
d%XLWU(:)=pemis(:)*xstefan*ptrad(:)**4 + (1.-pemis(:))*plw(:)
!
!* net radiation
!
d%XRN(:)    =   d%XSWD(:) - d%XSWU(:)     + d%XLWD(:) - d%XLWU    (:)
!
IF (.NOT.s%LHANDLE_SIC) THEN
  !
  !* sensible heat flux
  !
  d%XH     = psfth
  !
  !* latent heat flux
  !
  WHERE (s%XSST<ptt  )
     d%XLE    = psftq * xlstt
     d%XLEI   = psftq * xlstt
     d%XEVAP  = psftq
     d%XSUBL  = psftq
  ELSEWHERE
     d%XLE    = psftq * xlvtt
     d%XLEI   = 0.0
     d%XEVAP  = psftq
     d%XSUBL  = 0.0
  END WHERE
  !
  !* wind stress
  !
  d%XFMU = psfzon
  d%XFMV = psfmer
  !
ELSE
  !
  !---------------------------------------------------------------------------- 
  ! Sea ice or mixed diag
  !---------------------------------------------------------------------------- 
  !
  !
  !* total incoming and outgoing SW
  !
  DO jswb=1,iswb
    di%XSWBU(:,jswb) = (pdir_sw(:,jswb) + psca_sw(:,jswb)) * s%XICE_ALB(:) 
  ENDDO
  !
  di%XSWU(:) = 0.
  DO jswb=1,iswb
     di%XSWU(:) = di%XSWU(:) + di%XSWBU(:,jswb)
  ENDDO
  !
  !*incoming outgoing LW
  !
  di%XLWU(:)=xemiswatice*xstefan*s%XTICE(:)**4 + (1.-xemiswatice)*plw(:)
  !
  !* net radiation
  !
  di%XRN(:) =   d%XSWD(:) - di%XSWU(:) + d%XLWD(:) - di%XLWU(:)
  !
  !* sensible heat flux
  !
  d%XH     = (1 - s%XSIC) * psfth + s%XSIC * psfth_ice 
  di%XH    =                                 psfth_ice
  !
  !* latent heat flux
  !
  d%XLE     = (1 - s%XSIC) * psftq * xlvtt + s%XSIC * psftq_ice * xlstt
  d%XLEI    =                                         psftq_ice * xlstt
  d%XEVAP   = (1 - s%XSIC) * psftq         + s%XSIC * psftq_ice 
  d%XSUBL   =                                s%XSIC * psftq_ice 
  !
  !* ice storage flux
  !
  di%XGFLUX = di%XRN - di%XH - d%XLEI
  !
  !* wind stress
  !
  d%XFMU  = (1 - s%XSIC) * psfzon + s%XSIC * psfzon_ice
  di%XFMU =                                  psfzon_ice
  d%XFMV  = (1 - s%XSIC) * psfmer + s%XSIC * psfmer_ice
  di%XFMV =                                  psfmer_ice
!  
ENDIF
!
!* total storage flux
!
d%XGFLUX = d%XRN - d%XH - d%XLE
!
!
IF (lhook) CALL dr_hook('DIAG_SURF_BUDGET_SEA',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_surf_budget_sea