cls_wind.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE cls_wind( PZONA, PMERA, PHW, PCD, PCDN, PRI, PHV, PZON10M, PMER10M  )  
!     ###############################################################
!
!!****  *PARAMCLS*  
!!
!!    PURPOSE
!!    -------
!
!         
!     
!!**  METHOD
!!    ------
!
!!    EXTERNAL
!!    --------
!!
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!    USE MODD_CST
!!    USE MODD_GROUND_PAR
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!
!!    MODIFICATIONS
!!    -------------
!!
!!      Original    26/10/98
!!      S. Riette   06/2009  height of diagnostic becomes an argument
!!      S. Riette   01/2010 XUNDEF is sent where forcing level is below heigt of
!!                          diagnostic (no extrapolation, only interpolation)
!!      P. LeMoigne 02/2015 Suppress XUNDEF
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_csts,     ONLY : xkarman
USE modd_surf_par, ONLY : xundef
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
REAL, DIMENSION(:), INTENT(IN)       :: PZONA  ! zonal wind component
REAL, DIMENSION(:), INTENT(IN)       :: PMERA  ! meridian wind component
REAL, DIMENSION(:), INTENT(IN)       :: PHW    ! atmospheric level height (wind)
REAL, DIMENSION(:), INTENT(IN)       :: PCD    ! drag coefficient for momentum
REAL, DIMENSION(:), INTENT(IN)       :: PCDN   ! neutral drag coefficient
REAL, DIMENSION(:), INTENT(IN)       :: PRI    ! Richardson number
REAL, DIMENSION(:), INTENT(IN)       :: PHV    ! height of diagnostic (m)
!
REAL, DIMENSION(:), INTENT(OUT)      :: PZON10M! zonal wind at 10 meters
REAL, DIMENSION(:), INTENT(OUT)      :: PMER10M! meridian wind at 10 meters
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PHW)) :: ZBN,ZBD,ZRU
REAL, DIMENSION(SIZE(PHW)) :: ZLOGU,ZCORU,ZIV
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('CLS_WIND',0,zhook_handle)
pzon10m(:) = xundef
pmer10m(:) = xundef
!
zbn(:) = 0.
zbd(:) = 0.
zru(:) = 0.
zlogu(:) = 0.
zcoru(:) = 0.
ziv(:) = 0.
!
!*      1.     preparatory calculations
!              ------------------------
!
zbn(:)=xkarman/sqrt(pcdn(:))
!
zbd(:)=xkarman/sqrt(pcd(:))
!
WHERE(phv(:)<=phw(:))
   zru(:)=min(phv(:)/phw(:),1.)
ELSEWHERE
   zru(:)=min(phw(:)/phv(:),1.)
END WHERE
!
zlogu(:)=log(1.+zru(:)*(exp(zbn(:)) -1.))
!
!*      2.     Stability effects
!              -----------------
!
WHERE (pri(:)>=0.)
  zcoru(:)=zru(:)*(zbn(:)-zbd(:))
END WHERE
!
WHERE (pri(:)< 0.)
  zcoru(:)=log(1.+zru(:)*(exp(max(0.,zbn(:)-zbd(:)))-1.))
END WHERE
!
!*      3.     Interpolation of dynamical variables
!              ------------------------------------
!
!
ziv(:)=max(0.,min(1.,(zlogu(:)-zcoru(:))/zbd(:)))
!
WHERE(phv(:)<=phw(:))
  pzon10m(:)=pzona(:)*ziv(:)
  pmer10m(:)=pmera(:)*ziv(:)
ELSEWHERE
  pzon10m(:)=pzona(:)/max(1.,ziv(:))
  pmer10m(:)=pmera(:)/max(1.,ziv(:))  
END WHERE
IF (lhook) CALL dr_hook('CLS_WIND',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE cls_wind