read_watflux_sbln.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_watflux_sbl_n (DTCO, U, W, WSB, &
                                     hprogram)
!     #########################################
!
!!****  *READ_WATFLUX_SBL_n* - reads WATFLUX fields
!!                        
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!!      E. Martin   01/2012 Add LSBL_COLD_START
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_watflux_n, ONLY : watflux_t
USE modd_watflux_sbl_n, ONLY : watflux_sbl_t
!
USE modd_surf_par,        ONLY : xundef
!
USE modi_read_surf
USE modi_canopy_grid
USE modi_get_type_dim_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(watflux_t), INTENT(INOUT) :: w
TYPE(watflux_sbl_t), INTENT(INOUT) :: wsb
!
 CHARACTER(LEN=6),  INTENT(IN)  :: hprogram ! calling program
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
 CHARACTER(LEN=12) :: yrecfm         ! Name of the article to be read
 CHARACTER(LEN=3)  :: yread
INTEGER :: jlayer  ! loop counter on layers
INTEGER :: ilu     ! 1D physical dimension
INTEGER :: iresp   ! Error code after redding
INTEGER :: iversion, ibugfix   ! surface version
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!
!* 1D physical dimension
!
IF (lhook) CALL dr_hook('READ_WATFLUX_SBL_N',0,zhook_handle)
 CALL get_type_dim_n(dtco, u, &
                     'WATER ',ilu)
!
!* flag to use or not SBL levels
!
yrecfm='VERSION'
 CALL read_surf(&
                hprogram,yrecfm,iversion,iresp)
!
yrecfm='BUG'
 CALL read_surf(&
                hprogram,yrecfm,ibugfix,iresp)
!
yrecfm='WAT_SBL'
 CALL read_surf(&
                hprogram,yrecfm,w%LSBL,iresp)
!
IF (.NOT.w%LSBL) THEN
  ALLOCATE(wsb%XZ  (0,0))
  ALLOCATE(wsb%XU  (0,0))
  ALLOCATE(wsb%XT  (0,0))
  ALLOCATE(wsb%XQ  (0,0))
  ALLOCATE(wsb%XTKE(0,0))
  ALLOCATE(wsb%XLMO(0)  )
  ALLOCATE(wsb%XP  (0,0))
  ALLOCATE(wsb%XDZ (0,0))
  ALLOCATE(wsb%XZF (0,0))
  ALLOCATE(wsb%XDZF(0,0))
  IF (lhook) CALL dr_hook('READ_WATFLUX_SBL_N',1,zhook_handle)
  RETURN
ENDIF
!
!* number of vertical levels
!
yrecfm='WAT_SBL_LVL'
 CALL read_surf(&
                hprogram,yrecfm,wsb%NLVL,iresp)
!
!*       2.     Prognostic fields:
!               -----------------
!
!* altitudes
!
ALLOCATE(wsb%XZ(ilu,wsb%NLVL))
!
DO jlayer=1,wsb%NLVL
  WRITE(yrecfm,'(A9,I2.2,A1)') 'WAT_SBL_Z',jlayer,' '
  CALL read_surf(&
                hprogram,yrecfm,wsb%XZ(:,jlayer),iresp)
END DO
!
ALLOCATE(wsb%XU  (ilu,wsb%NLVL))
ALLOCATE(wsb%XT  (ilu,wsb%NLVL))
ALLOCATE(wsb%XQ  (ilu,wsb%NLVL))
ALLOCATE(wsb%XTKE(ilu,wsb%NLVL))
ALLOCATE(wsb%XLMO(ilu)     )
ALLOCATE(wsb%XP  (ilu,wsb%NLVL))
!
IF (iversion>7 .OR. iversion==7 .AND.ibugfix>=2) THEN
  yrecfm='STORAGETYPE'
  CALL read_surf(&
                hprogram,yrecfm,yread,iresp)
ELSE
  yread = 'ALL'
ENDIF
!
IF(yread=='ALL') THEN
  !
  !* wind in SBL
  DO jlayer=1,wsb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'WAT_SBL_U',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,wsb%XU(:,jlayer),iresp)
  END DO
  !
  !* theta in SBL
  DO jlayer=1,wsb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'WAT_SBL_T',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,wsb%XT(:,jlayer),iresp)
  END DO
  !
  !* humidity in SBL
  DO jlayer=1,wsb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'WAT_SBL_Q',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,wsb%XQ(:,jlayer),iresp)
  END DO
  !
  !* Tke in SBL
  DO jlayer=1,wsb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'WAT_SBL_E',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,wsb%XTKE(:,jlayer),iresp)
  END DO
  !
  !* Monin-Obhukov length
  yrecfm='WAT_SBL_LMO '
  CALL read_surf(&
                hprogram,yrecfm,wsb%XLMO(:),iresp)
  !
  !* Pressure
  DO jlayer=1,wsb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'WAT_SBL_P',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,wsb%XP(:,jlayer),iresp)
  END DO
  !
ELSE
  wsb%XU  (:,:) = xundef
  wsb%XT  (:,:) = xundef
  wsb%XQ  (:,:) = xundef
  wsb%XTKE(:,:) = xundef
  wsb%XLMO(:)   = xundef
  wsb%XP  (:,:) = xundef
ENDIF
!
!
!* Grid characteristics
!
!
!  --------------------------------- XZ(k+1)                     XDZ(k+1)
!                                                                           ^
!                                                                           |
!                                                                           |
!  - - - - - - - - - - - - - - - - - XZf(k+1)                               | XDZf(k+1)
!                                                              ^            |
!                                                              |            |
!  --------------------------------- XZ(k), XU, XT, XQ, XTKE   | XDZ(k)     V
!                                                              |            ^
!  - - - - - - - - - - - - - - - - - XZf(k)                    V            | XDZf(k)
!  --------------------------------- XZ(k-1)                     XDZ(k-1)   V
!  - - - - - - - - - - - - - - - - - XZf(k-1)
!
ALLOCATE(wsb%XDZ (ilu,wsb%NLVL))
ALLOCATE(wsb%XZF (ilu,wsb%NLVL))
ALLOCATE(wsb%XDZF(ilu,wsb%NLVL))
 CALL canopy_grid(ilu,wsb%NLVL,wsb%XZ,wsb%XZF,wsb%XDZ,wsb%XDZF)
!
IF (lhook) CALL dr_hook('READ_WATFLUX_SBL_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_watflux_sbl_n