canopy_grid.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########################################
      SUBROUTINE canopy_grid(KI,KLVL,PZ,PZF,PDZ,PDZF)
!     #########################################
!
!!****  *CANOPY_GRID* - computation of vertical grid coordinatesa at 
!!                      half levels and grid depths at half and full
!!                      levels
!!                        
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!
!
!  --------------------------------- PZ(k+1)                     PDZ(k+1)
!                                                                           ^
!                                                                           |
!                                                                           |
!  - - - - - - - - - - - - - - - - - PZf(k+1)                               | PDZf(k+1)
!                                                              ^            |
!                                                              |            |
!  --------------------------------- PZ(k), XU, XT, XQ, XTKE   | PDZ(k)     V
!                                                              |            ^
!  - - - - - - - - - - - - - - - - - PZf(k)                    V            | PDZf(k)
!  --------------------------------- PZ(k-1)                     PDZ(k-1)   V
!  - - - - - - - - - - - - - - - - - PZf(k-1)
!

!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2006 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
INTEGER,                  INTENT(IN)    :: ki     ! number of horizontal points
INTEGER,                  INTENT(IN)    :: klvl   ! number of levels in canopy
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pz     ! heights of canopy levels              (m)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pzf    ! heights of surface between canopy lev.(m)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pdzf   ! depth between 2 full canopy levels    (m)
!                                                 ! PDZF is located at half levels
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pdz    ! depth between 2 half canopy levels    (m)
!                                                 ! PDZ is located at full levels
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER :: jlayer                 ! loop counter on layers
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
!*    1. Geometric computations
!        ----------------------
!
!
!*    1.1 layer depths (variable located at half levels below full levels)
!         ------------
!
IF (lhook) CALL dr_hook('CANOPY_GRID',0,zhook_handle)
pdzf(:,:) = -999.
pdzf(:,1) = 2.*pz(:,1)
DO jlayer=2,klvl
  pdzf(:,jlayer) = pz(:,jlayer) - pz(:,jlayer-1)
END DO
!
!*    1.2 Layer heights (variable located at half levels below full levels)
!         -------------
!
pzf(:,:) = -999.
pzf(:,1) = 0.
DO jlayer=2,klvl
  pzf(:,jlayer) = 2.*pz(:,jlayer-1) - pzf(:,jlayer-1)
END DO
!
!
!*    1.3 layer depths (variable located at full levels)
!         ------------
!
pdz(:,:) = -999.
DO jlayer=1,klvl-1
  pdz(:,jlayer) = pzf(:,jlayer+1) - pzf(:,jlayer)
END DO
pdz(:,klvl) = 2.*(pz(:,klvl)-pzf(:,klvl))
IF (lhook) CALL dr_hook('CANOPY_GRID',1,zhook_handle)
!
!-------------------------------------------------------------------------------
END SUBROUTINE canopy_grid