read_teb_gardenn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_teb_garden_n (DTCO, DGU, U, GDM, &
                                    hprogram,hpatch)
!     ##################################
!
!!****  *READ_TEB_GARDEN_n* - routine to initialise ISBA variables
!!                         
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003
!!
!!      READ_SURF for general reading : 08/2003 (S.Malardel)
!!      B. Decharme  2008    : Floodplains
!!      B. Decharme  01/2009 : Optional Arpege deep soil temperature read
!!      B. Decharme  09/2012 : suppress NWG_LAYER (parallelization problems)
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_diag_surf_atm_n, ONLY : diag_surf_atm_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surfex_n, ONLY : teb_garden_model_t
!
USE modd_co2v_par,       ONLY : xanfminit, xcondctmin
!                                
USE modd_surf_par,       ONLY : xundef, nundef
USE modd_snow_par,       ONLY : xz0sn
!
USE modi_read_surf
!
USE modi_init_io_surf_n
USE modi_set_surfex_filein
USE modi_end_io_surf_n
USE modi_town_presence
USE modi_allocate_gr_snow
USE modi_read_gr_snow
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_get_type_dim_n
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(diag_surf_atm_t), INTENT(INOUT) :: dgu
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(teb_garden_model_t), INTENT(INOUT) :: gdm
!
 CHARACTER(LEN=6),  INTENT(IN)  :: hprogram ! calling program
 CHARACTER(LEN=3),  INTENT(IN)  :: hpatch   ! current TEB patch identificator
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
LOGICAL           :: gtown          ! town variables written in the file
INTEGER           :: iversion, ibugfix
INTEGER           :: ilu            ! 1D physical dimension
INTEGER           :: iresp          ! Error code after redding
 CHARACTER(LEN=12) :: yrecfm         ! Name of the article to be read
 CHARACTER(LEN=4)  :: ylvl
REAL, DIMENSION(:),ALLOCATABLE  :: zwork      ! 2D array to write data in file
!
INTEGER :: iwork   ! Work integer
!
INTEGER :: jlayer, jnbiomass  ! loop counter on layers
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
!
!* 1D physical dimension
!
IF (lhook) CALL dr_hook('READ_TEB_GARDEN_N',0,zhook_handle)
yrecfm='SIZE_TOWN'
 CALL get_type_dim_n(dtco, u, &
                     'TOWN  ',ilu)
!
yrecfm='VERSION'
 CALL read_surf(&
                hprogram,yrecfm,iversion,iresp)
!
yrecfm='BUG'
 CALL read_surf(&
                hprogram,yrecfm,ibugfix,iresp)
!
!*       2.     Prognostic fields:
!               -----------------
!
ALLOCATE(zwork(ilu))
!* soil temperatures
!
iwork=gdm%TGDO%NGROUND_LAYER
!
ALLOCATE(gdm%TGD%CUR%XTG(ilu,iwork))
DO jlayer=1,iwork
  WRITE(ylvl,'(I2)') jlayer
  IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
    yrecfm=hpatch//'GD_TG'//adjustl(ylvl(:len_trim(ylvl)))
  ELSE
    yrecfm='TWN_TG'//adjustl(ylvl(:len_trim(ylvl)))
  ENDIF
  yrecfm=adjustl(yrecfm)  
  CALL read_surf(&
                hprogram,yrecfm,zwork(:),iresp)
  gdm%TGD%CUR%XTG(:,jlayer)=zwork
END DO
!
!
!* soil liquid water content
!
ALLOCATE(gdm%TGD%CUR%XWG(ilu,iwork))
DO jlayer=1,gdm%TGDO%NGROUND_LAYER
  WRITE(ylvl,'(I2)') jlayer
  IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
    yrecfm=hpatch//'GD_WG'//adjustl(ylvl(:len_trim(ylvl)))
  ELSE
    yrecfm='TWN_WG'//adjustl(ylvl(:len_trim(ylvl)))
  ENDIF  
  yrecfm=adjustl(yrecfm)
  CALL read_surf(&
                hprogram,yrecfm,zwork(:),iresp)
  gdm%TGD%CUR%XWG(:,jlayer)=zwork
END DO
!
!* soil ice water content
!
ALLOCATE(gdm%TGD%CUR%XWGI(ilu,iwork))
DO jlayer=1,gdm%TGDO%NGROUND_LAYER
  WRITE(ylvl,'(I2)') jlayer
! ajouter ici un test pour lire les anciens fichiers
  IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
    yrecfm=hpatch//'GD_WGI'//adjustl(ylvl(:len_trim(ylvl)))
  ELSE
    yrecfm='TWN_WGI'//adjustl(ylvl(:len_trim(ylvl)))
  ENDIF  
  yrecfm=adjustl(yrecfm)  
  CALL read_surf(&
                hprogram,yrecfm,zwork(:),iresp)
  gdm%TGD%CUR%XWGI(:,jlayer)=zwork
END DO
!
!* water intercepted on leaves
!
ALLOCATE(gdm%TGD%CUR%XWR(ilu))
IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
  yrecfm=hpatch//'GD_WR'
ELSE
  yrecfm='TWN_WR'
ENDIF
yrecfm=adjustl(yrecfm)
 CALL read_surf(&
                hprogram,yrecfm,gdm%TGD%CUR%XWR(:),iresp)
!
!* Leaf Area Index (if prognostic)
!
IF (gdm%TVG%CPHOTO=='LAI' .OR. gdm%TVG%CPHOTO=='LST' .OR. &
                gdm%TVG%CPHOTO=='NIT' .OR. gdm%TVG%CPHOTO=='NCB') THEN
  IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
    yrecfm=hpatch//'GD_LAI'
  ELSE
    yrecfm='TWN_LAI'
  ENDIF        
  yrecfm=adjustl(yrecfm)
  CALL read_surf(&
                hprogram,yrecfm,gdm%TGDPE%CUR%XLAI(:),iresp)        
END IF
!
!* snow mantel
!
 CALL end_io_surf_n(hprogram)
 CALL set_surfex_filein(hprogram,'PGD ')
 CALL init_io_surf_n(dtco, dgu, u, &
                     hprogram,'TOWN  ','TEB   ','READ ')
!
 CALL town_presence(&
                    hprogram,gtown)
!
 CALL end_io_surf_n(hprogram)
 CALL set_surfex_filein(hprogram,'PREP')
 CALL init_io_surf_n(dtco, dgu, u, &
                     hprogram,'TOWN  ','TEB   ','READ ')
!
IF (.NOT. gtown) THEN
  gdm%TGD%CUR%TSNOW%SCHEME='1-L'
  CALL allocate_gr_snow(gdm%TGD%CUR%TSNOW,ilu,1)
ELSE
  IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
    CALL read_gr_snow(&
                      hprogram,'GD',hpatch,ilu,1,gdm%TGD%CUR%TSNOW  )
  ELSE
    CALL read_gr_snow(&
                      hprogram,'GARD',hpatch,ilu,1,gdm%TGD%CUR%TSNOW  )
  ENDIF
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       4.  Semi-prognostic variables
!            -------------------------
!
!* aerodynamical resistance
!
ALLOCATE(gdm%TGD%CUR%XRESA(ilu))
IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
  yrecfm=hpatch//'GD_RES'
ELSE
  yrecfm='TWN_RESA'
ENDIF
yrecfm=adjustl(yrecfm)
gdm%TGD%CUR%XRESA(:) = 100.
 CALL read_surf(&
                hprogram,yrecfm,gdm%TGD%CUR%XRESA(:),iresp)
!
ALLOCATE(gdm%TGD%CUR%XLE(ilu))
gdm%TGD%CUR%XLE(:) = xundef
!
!* ISBA-AGS variables
!
IF (gdm%TVG%CPHOTO/='NON') THEN
  ALLOCATE(gdm%TGD%CUR%XAN   (ilu)) 
  ALLOCATE(gdm%TGD%CUR%XANDAY(ilu)) 
  ALLOCATE(gdm%TGD%CUR%XANFM (ilu))
  ALLOCATE(gdm%TGDP%XANF  (ilu))
  gdm%TGD%CUR%XAN(:)    = 0.
  gdm%TGD%CUR%XANDAY(:) = 0.
  gdm%TGD%CUR%XANFM(:)  = xanfminit
  gdm%TGD%CUR%XLE(:)    = 0.
ELSE
  ALLOCATE(gdm%TGD%CUR%XAN   (0)) 
  ALLOCATE(gdm%TGD%CUR%XANDAY(0)) 
  ALLOCATE(gdm%TGD%CUR%XANFM (0))
  ALLOCATE(gdm%TGDP%XANF  (0))
ENDIF
!
IF(gdm%TVG%CPHOTO/='NON') THEN
  ALLOCATE(gdm%TGD%CUR%XBIOMASS         (ilu,gdm%TVG%NNBIOMASS))
  ALLOCATE(gdm%TGD%CUR%XRESP_BIOMASS    (ilu,gdm%TVG%NNBIOMASS))
ELSE
  ALLOCATE(gdm%TGD%CUR%XBIOMASS         (0,0))
  ALLOCATE(gdm%TGD%CUR%XRESP_BIOMASS    (0,0))
END IF
!
IF (gdm%TVG%CPHOTO=='AGS' .OR. gdm%TVG%CPHOTO=='AST') THEN
  !
  gdm%TGD%CUR%XBIOMASS(:,:) = 0.
  gdm%TGD%CUR%XRESP_BIOMASS(:,:) = 0.
ELSEIF (gdm%TVG%CPHOTO=='LAI' .OR. gdm%TVG%CPHOTO=='LST') THEN
  !
  gdm%TGD%CUR%XBIOMASS(:,1) = gdm%TGDP%XBSLAI(:) * gdm%TGDPE%CUR%XLAI(:)
  gdm%TGD%CUR%XRESP_BIOMASS(:,:) = 0.
ELSEIF (gdm%TVG%CPHOTO=='NIT' .OR. gdm%TVG%CPHOTO=='NCB') THEN
  !
  gdm%TGD%CUR%XBIOMASS(:,:) = 0.
  DO jnbiomass=1,gdm%TVG%NNBIOMASS
    WRITE(ylvl,'(I1)') jnbiomass
    IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
      yrecfm=hpatch//'GD_BIOMA'//adjustl(ylvl(:len_trim(ylvl)))
    ELSE
      yrecfm='TWN_BIOMASS'//adjustl(ylvl(:len_trim(ylvl)))
    ENDIF
    yrecfm=adjustl(yrecfm)
    CALL read_surf(&
                hprogram,yrecfm,gdm%TGD%CUR%XBIOMASS(:,jnbiomass),iresp)
  END DO

  gdm%TGD%CUR%XRESP_BIOMASS(:,:) = 0.
  DO jnbiomass=2,gdm%TVG%NNBIOMASS
    WRITE(ylvl,'(I1)') jnbiomass
    IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
      yrecfm=hpatch//'GD_RESPI'//adjustl(ylvl(:len_trim(ylvl)))
    ELSE
      yrecfm='TWN_RESP_BIOM'//adjustl(ylvl(:len_trim(ylvl)))
    ENDIF    
    yrecfm=adjustl(yrecfm)
    CALL read_surf(&
                hprogram,yrecfm,gdm%TGD%CUR%XRESP_BIOMASS(:,jnbiomass),iresp)
  END DO
  !
ENDIF
!
DEALLOCATE(zwork)
IF (lhook) CALL dr_hook('READ_TEB_GARDEN_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_teb_garden_n