allocate_gr_snow.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE allocate_gr_snow(TPSNOW,KLU,KPATCH)
!     ##############################################
!
!!****  *ALLOCATE_GR_SNOW* - 
!!
!!    PURPOSE
!!    -------
!!
!!
!!**  METHOD
!!    ------
!!
!!       TPSNOW%SCHEME must yet be initialized
!!    
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!      Book 2
!!
!!    AUTHOR
!!    ------
!!      
!!      V.Masson  Meteo-France
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    20/01/99
!
!!     F.Solmon     06/00 Adapt for patch cases 
!!     V. Masson    01/2004 Externalization
!!     A. Bogatchev 09/2005 EBA snow option
!!     P. Samuelsson 07/2014 Added snow albedos
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_type_snow
USE modd_surf_par,    ONLY : xundef
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declaration of arguments
!              ------------------------
!
TYPE(surf_snow), INTENT(INOUT)             :: tpsnow
INTEGER, INTENT(IN)                        :: klu
INTEGER, INTENT(IN)                        :: kpatch
REAL(KIND=JPRB) :: zhook_handle
!
!*       0.2   Declaration of local variables
!              ------------------------------
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('ALLOCATE_GR_SNOW',0,zhook_handle)
!
IF (tpsnow%SCHEME=='3-L' .OR. tpsnow%SCHEME=='CRO' .OR. tpsnow%SCHEME=='1-L' .OR.  &
    tpsnow%SCHEME=='D95' .OR. tpsnow%SCHEME=='EBA') THEN
  !
  ALLOCATE(tpsnow%WSNOW  (klu,tpsnow%NLAYER,kpatch))
  ALLOCATE(tpsnow%RHO    (klu,tpsnow%NLAYER,kpatch))
  ALLOCATE(tpsnow%ALB    (klu,kpatch))  
  ALLOCATE(tpsnow%ALBVIS (klu,kpatch))  
  ALLOCATE(tpsnow%ALBNIR (klu,kpatch))  
  ALLOCATE(tpsnow%ALBFIR (klu,kpatch))  
  tpsnow%WSNOW   = 0.
  tpsnow%RHO     = xundef  
  tpsnow%ALB     = xundef
  tpsnow%ALBVIS  = xundef
  tpsnow%ALBNIR  = xundef
  tpsnow%ALBFIR  = xundef
  !
  IF (tpsnow%SCHEME/='D95' .AND. tpsnow%SCHEME/='EBA') THEN
    !
    ALLOCATE(tpsnow%EMIS(klu,kpatch))
    ALLOCATE(tpsnow%TS  (klu,kpatch))
    tpsnow%EMIS = xundef
    tpsnow%TS   = xundef
    !
    IF (tpsnow%SCHEME/='1-L') THEN
      !
      ALLOCATE(tpsnow%TEMP(klu,tpsnow%NLAYER,kpatch))
      ALLOCATE(tpsnow%HEAT(klu,tpsnow%NLAYER,kpatch))
      ALLOCATE(tpsnow%AGE (klu,tpsnow%NLAYER,kpatch)) 
      tpsnow%TEMP = xundef
      tpsnow%HEAT = xundef
      tpsnow%AGE  = xundef
      !
      IF(tpsnow%SCHEME=='CRO') THEN
        !
        ALLOCATE(tpsnow%GRAN1(klu,tpsnow%NLAYER,kpatch))
        ALLOCATE(tpsnow%GRAN2(klu,tpsnow%NLAYER,kpatch))  
        ALLOCATE(tpsnow%HIST (klu,tpsnow%NLAYER,kpatch))  
        tpsnow%GRAN1 = xundef
        tpsnow%GRAN2 = xundef  
        tpsnow%HIST  = xundef  
        !
      END IF
      !
    ELSE
      !
      ALLOCATE(tpsnow%T(klu,tpsnow%NLAYER,kpatch))
      tpsnow%T = xundef
      !
    END IF
  ENDIF
ENDIF
!
!
IF (tpsnow%SCHEME/='CRO') THEN
  !
  ALLOCATE(tpsnow%GRAN1(0,0,0))
  ALLOCATE(tpsnow%GRAN2(0,0,0))  
  ALLOCATE(tpsnow%HIST (0,0,0))  
  !
  IF (tpsnow%SCHEME/='3-L') THEN
    !
    ALLOCATE(tpsnow%TEMP(0,0,0))    
    ALLOCATE(tpsnow%HEAT(0,0,0))
    ALLOCATE(tpsnow%AGE (0,0,0))
    !
    IF (tpsnow%SCHEME/='1-L') THEN
      !
      ALLOCATE(tpsnow%EMIS (0,0))
      ALLOCATE(tpsnow%TS   (0,0))
      !
      IF (tpsnow%SCHEME/='D95' .AND. tpsnow%SCHEME/='EBA') THEN
        !
        ALLOCATE(tpsnow%WSNOW  (0,0,0))
        ALLOCATE(tpsnow%RHO    (0,0,0))
        ALLOCATE(tpsnow%ALB    (0,0))
        ALLOCATE(tpsnow%ALBVIS (0,0))
        ALLOCATE(tpsnow%ALBNIR (0,0))
        ALLOCATE(tpsnow%ALBFIR (0,0))
        !
      ENDIF
      !
    ENDIF
    !
  ENDIF
  ! 
END IF
!
IF (tpsnow%SCHEME/='1-L') THEN
  !
  ALLOCATE(tpsnow%T(0,0,0))
  !
ENDIF
!
IF (lhook) CALL dr_hook('ALLOCATE_GR_SNOW',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE allocate_gr_snow