read_teb_canopyn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_teb_canopy_n (DTCO, U, TCP, TOP, &
                                    hprogram)
!     #########################################
!
!!****  *READ_TEB_CANOPY_n* - reads TEB fields
!!                        
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!!      E. Martin   01/2012 Add LSBL_COLD_START
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_teb_canopy_n, ONLY : teb_canopy_t
USE modd_teb_option_n, ONLY : teb_options_t
!
USE modd_surf_par,       ONLY : xundef
!
USE modi_read_surf
USE modi_canopy_grid
USE modi_get_type_dim_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(teb_canopy_t), INTENT(INOUT) :: tcp
TYPE(teb_options_t), INTENT(INOUT) :: top
!
 CHARACTER(LEN=6),  INTENT(IN)  :: hprogram ! calling program
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
!
 CHARACTER(LEN=12) :: yrecfm         ! Name of the article to be read
 CHARACTER(LEN=3)  :: yread
INTEGER :: jlayer  ! loop counter on layers
INTEGER :: ilu     ! 1D physical dimension
INTEGER :: iresp   ! Error code after redding
INTEGER           :: iversion, ibugfix   ! surface version
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!
!* 1D physical dimension
!
IF (lhook) CALL dr_hook('READ_TEB_CANOPY_N',0,zhook_handle)
yrecfm='SIZE_TOWN'
 CALL get_type_dim_n(dtco, u, &
                     'TOWN  ',ilu)
!
!* flag to use or not canopy levels
!
yrecfm='VERSION'
 CALL read_surf(&
                hprogram,yrecfm,iversion,iresp)
!
yrecfm='BUG'
 CALL read_surf(&
                hprogram,yrecfm,ibugfix,iresp)
!
IF (iversion<3) THEN
  top%LCANOPY = .false.
ELSE
  yrecfm='TEB_CANOPY'
  CALL read_surf(&
                hprogram,yrecfm,top%LCANOPY,iresp)
END IF
!
IF (.NOT.top%LCANOPY) THEN
  ALLOCATE(tcp%XZ  (0,0))
  ALLOCATE(tcp%XU  (0,0))
  ALLOCATE(tcp%XT  (0,0))
  ALLOCATE(tcp%XQ  (0,0))
  ALLOCATE(tcp%XTKE(0,0))
  ALLOCATE(tcp%XLMO(0,0))
  ALLOCATE(tcp%XP  (0,0))
  ALLOCATE(tcp%XLM (0,0))
  ALLOCATE(tcp%XLEPS(0,0))  
  ALLOCATE(tcp%XDZ (0,0))
  ALLOCATE(tcp%XZF (0,0))
  ALLOCATE(tcp%XDZF(0,0))
  IF (lhook) CALL dr_hook('READ_TEB_CANOPY_N',1,zhook_handle)
  RETURN
ENDIF
!
!* number of vertical levels
!
yrecfm='TEB_CAN_LVL'
 CALL read_surf(&
                hprogram,yrecfm,tcp%NLVL,iresp)
!
!*       2.     Prognostic fields:
!               -----------------
!
!* altitudes
!
ALLOCATE(tcp%XZ(ilu,tcp%NLVL))
!
DO jlayer=1,tcp%NLVL
  WRITE(yrecfm,'(A9,I2.2,A1)') 'TEB_CAN_Z',jlayer,' '
  CALL read_surf(&
                hprogram,yrecfm,tcp%XZ(:,jlayer),iresp)
END DO
!
ALLOCATE(tcp%XU  (ilu,tcp%NLVL))
ALLOCATE(tcp%XT  (ilu,tcp%NLVL))
ALLOCATE(tcp%XQ  (ilu,tcp%NLVL))
ALLOCATE(tcp%XTKE(ilu,tcp%NLVL))
ALLOCATE(tcp%XLMO(ilu,tcp%NLVL))
ALLOCATE(tcp%XP  (ilu,tcp%NLVL))
!
IF (iversion>7 .OR. iversion==7 .AND.ibugfix>=2) THEN
  yrecfm='STORAGETYPE'
  CALL read_surf(&
                hprogram,yrecfm,yread,iresp)
ELSE
  yread = 'ALL'
ENDIF
!
IF(yread=='ALL') THEN
  !
  !* wind in SBL
  DO jlayer=1,tcp%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'TEB_CAN_U',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,tcp%XU(:,jlayer),iresp)
  END DO
  !
  !* theta in SBL
  DO jlayer=1,tcp%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'TEB_CAN_T',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,tcp%XT(:,jlayer),iresp)
  END DO
  !
  !* humidity in SBL
  DO jlayer=1,tcp%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'TEB_CAN_Q',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,tcp%XQ(:,jlayer),iresp)
  END DO
  !
  !* Tke in SBL
  DO jlayer=1,tcp%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'TEB_CAN_E',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,tcp%XTKE(:,jlayer),iresp)
  END DO
  !
  !* Monin-Obhukov length
  IF (iversion<7) THEN
    yrecfm='TEB_CAN_LMO ' 
    CALL read_surf(&
                hprogram,yrecfm,tcp%XLMO(:,1),iresp) 
    DO jlayer = 2,tcp%NLVL
      tcp%XLMO(:,jlayer) = tcp%XLMO(:,1)
    ENDDO    
  ELSE
    DO jlayer=1,tcp%NLVL
      WRITE(yrecfm,'(A10,I2.2)') 'TEB_CAN_MO',jlayer
      CALL read_surf(&
                hprogram,yrecfm,tcp%XLMO(:,jlayer),iresp)
    ENDDO
  ENDIF    
  !
  !* Pressure
  DO jlayer=1,tcp%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'TEB_CAN_P',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,tcp%XP(:,jlayer),iresp)
  END DO
  !
ELSE
  tcp%XU  (:,:) = xundef
  tcp%XT  (:,:) = xundef
  tcp%XQ  (:,:) = xundef
  tcp%XTKE(:,:) = xundef
  tcp%XLMO(:,:) = xundef
  tcp%XP  (:,:) = xundef
ENDIF
!
!* mixing length
!
ALLOCATE(tcp%XLM(ilu,tcp%NLVL))
!
!* dissipative length
!
ALLOCATE(tcp%XLEPS(ilu,tcp%NLVL))
!
!
!* Grid characteristics
!
!
!  --------------------------------- XZ(k+1)                     XDZ(k+1)
!                                                                           ^
!                                                                           |
!                                                                           |
!  - - - - - - - - - - - - - - - - - XZf(k+1)                               | XDZf(k+1)
!                                                              ^            |
!                                                              |            |
!  --------------------------------- XZ(k), XU, XT, XQ, XTKE   | XDZ(k)     V
!                                                              |            ^
!  - - - - - - - - - - - - - - - - - XZf(k)                    V            | XDZf(k)
!  --------------------------------- XZ(k-1)                     XDZ(k-1)   V
!  - - - - - - - - - - - - - - - - - XZf(k-1)
!
ALLOCATE(tcp%XDZ (ilu,tcp%NLVL))
ALLOCATE(tcp%XZF (ilu,tcp%NLVL))
ALLOCATE(tcp%XDZF(ilu,tcp%NLVL))
 CALL canopy_grid(ilu,tcp%NLVL,tcp%XZ,tcp%XZF,tcp%XDZ,tcp%XDZF)
!
IF (lhook) CALL dr_hook('READ_TEB_CANOPY_N',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_teb_canopy_n