read_seaflux_sbln.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_seaflux_sbl_n (DTCO, S, SSB, U, &
                                     hprogram)
!     #########################################
!
!!****  *READ_SEAFLUX_SBL_n* - reads SEAFLUX fields
!!                        
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!!      E. Martin   01/2012 Add LSBL_COLD_START
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_seaflux_n, ONLY : seaflux_t
USE modd_seaflux_sbl_n, ONLY : seaflux_sbl_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_surf_par,        ONLY : xundef
!
USE modi_read_surf
USE modi_canopy_grid
USE modi_get_type_dim_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(seaflux_t), INTENT(INOUT) :: s
TYPE(seaflux_sbl_t), INTENT(INOUT) :: ssb
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
 CHARACTER(LEN=6),  INTENT(IN)  :: hprogram ! calling program
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
!
 CHARACTER(LEN=12) :: yrecfm         ! Name of the article to be read
 CHARACTER(LEN=3)  :: yread
INTEGER :: ilu     ! 1D physical dimension
INTEGER :: iresp   ! Error code after redding
INTEGER :: jlayer  ! loop counter on layers
INTEGER :: iversion, ibugfix
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
!* 1D physical dimension
!
IF (lhook) CALL dr_hook('READ_SEAFLUX_SBL_N',0,zhook_handle)
 CALL get_type_dim_n(dtco, u, &
                     'SEA   ',ilu)
!
yrecfm='VERSION'
 CALL read_surf(&
                hprogram,yrecfm,iversion,iresp)
!
yrecfm='BUG'
 CALL read_surf(&
                hprogram,yrecfm,ibugfix,iresp)
!
!* flag to use or not SBL levels
!
yrecfm='SEA_SBL'
 CALL read_surf(&
                hprogram,yrecfm,s%LSBL,iresp)
!
IF (.NOT.s%LSBL) THEN
  ALLOCATE(ssb%XZ  (0,0))
  ALLOCATE(ssb%XU  (0,0))
  ALLOCATE(ssb%XT  (0,0))
  ALLOCATE(ssb%XQ  (0,0))
  ALLOCATE(ssb%XTKE(0,0))
  ALLOCATE(ssb%XLMO(0)  )
  ALLOCATE(ssb%XP  (0,0))
  ALLOCATE(ssb%XDZ (0,0))
  ALLOCATE(ssb%XZF (0,0))
  ALLOCATE(ssb%XDZF(0,0))
  IF (lhook) CALL dr_hook('READ_SEAFLUX_SBL_N',1,zhook_handle)
  RETURN
ENDIF
!
!* number of vertical levels
!
yrecfm='SEA_SBL_LVL'
 CALL read_surf(&
                hprogram,yrecfm,ssb%NLVL,iresp)
!
!*       2.     Prognostic fields:
!               -----------------
!
!* altitudes
!
ALLOCATE(ssb%XZ(ilu,ssb%NLVL))
!
DO jlayer=1,ssb%NLVL
  WRITE(yrecfm,'(A9,I2.2,A1)') 'SEA_SBL_Z',jlayer,' '
  CALL read_surf(&
                hprogram,yrecfm,ssb%XZ(:,jlayer),iresp)
END DO
!
ALLOCATE(ssb%XU  (ilu,ssb%NLVL))
ALLOCATE(ssb%XT  (ilu,ssb%NLVL))
ALLOCATE(ssb%XQ  (ilu,ssb%NLVL))
ALLOCATE(ssb%XTKE(ilu,ssb%NLVL))
ALLOCATE(ssb%XLMO(ilu)     )
ALLOCATE(ssb%XP  (ilu,ssb%NLVL))
!
IF (iversion>7 .OR. iversion==7 .AND.ibugfix>=2) THEN
  yrecfm='STORAGETYPE'
  CALL read_surf(&
                hprogram,yrecfm,yread,iresp)
ELSE
  yread = 'ALL'
ENDIF
!
IF(yread=='ALL') THEN
  !
  !* wind in SBL
  DO jlayer=1,ssb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'SEA_SBL_U',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,ssb%XU(:,jlayer),iresp)
  END DO
  !
  !* theta in SBL
  DO jlayer=1,ssb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'SEA_SBL_T',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,ssb%XT(:,jlayer),iresp)
  END DO
  !
  !* humidity in SBL
  DO jlayer=1,ssb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'SEA_SBL_Q',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,ssb%XQ(:,jlayer),iresp)
  END DO
  !
  !* Tke in SBL
  DO jlayer=1,ssb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'SEA_SBL_E',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,ssb%XTKE(:,jlayer),iresp)
  END DO
  !
  !* Monin-Obhukov length
  yrecfm='SEA_SBL_LMO '
  CALL read_surf(&
                hprogram,yrecfm,ssb%XLMO(:),iresp)
  !
  !* Pressure
  DO jlayer=1,ssb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'SEA_SBL_P',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,ssb%XP(:,jlayer),iresp)
  END DO
  !
ELSE
  ssb%XU  (:,:) = xundef
  ssb%XT  (:,:) = xundef
  ssb%XQ  (:,:) = xundef
  ssb%XTKE(:,:) = xundef
  ssb%XLMO(:)   = xundef
  ssb%XP  (:,:) = xundef
ENDIF
!
!
!* Grid characteristics
!
!
!  --------------------------------- XZ(k+1)                     XDZ(k+1)
!                                                                           ^
!                                                                           |
!                                                                           |
!  - - - - - - - - - - - - - - - - - XZf(k+1)                               | XDZf(k+1)
!                                                              ^            |
!                                                              |            |
!  --------------------------------- XZ(k), XU, XT, XQ, XTKE   | XDZ(k)     V
!                                                              |            ^
!  - - - - - - - - - - - - - - - - - XZf(k)                    V            | XDZf(k)
!  --------------------------------- XZ(k-1)                     XDZ(k-1)   V
!  - - - - - - - - - - - - - - - - - XZf(k-1)
!
ALLOCATE(ssb%XDZ (ilu,ssb%NLVL))
ALLOCATE(ssb%XZF (ilu,ssb%NLVL))
ALLOCATE(ssb%XDZF(ilu,ssb%NLVL))
 CALL canopy_grid(ilu,ssb%NLVL,ssb%XZ,ssb%XZF,ssb%XDZ,ssb%XDZF)
!
IF (lhook) CALL dr_hook('READ_SEAFLUX_SBL_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_seaflux_sbl_n