read_isba_canopyn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_isba_canopy_n (DTCO, ICP, I, U, &
                                     hprogram)
!     #########################################
!
!!****  *READ_ISBA_CANOPY_n* - reads ISBA fields
!!                        
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!!      E. Martin   01/2012 Add LSBL_COLD_START
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_isba_canopy_n, ONLY : isba_canopy_t
USE modd_isba_n, ONLY : isba_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_surf_par,        ONLY : xundef
!
!
USE modi_read_surf
USE modi_canopy_grid
USE modi_get_type_dim_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(isba_canopy_t), INTENT(INOUT) :: icp
TYPE(isba_t), INTENT(INOUT) :: i
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
 CHARACTER(LEN=6),  INTENT(IN)  :: hprogram ! calling program
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
!
 CHARACTER(LEN=12) :: yrecfm         ! Name of the article to be read
 CHARACTER(LEN=3)  :: yread
INTEGER :: jlayer  ! loop counter on layers
INTEGER :: ilu     ! 1D physical dimension
INTEGER :: iresp   ! Error code after redding
INTEGER :: iversion, ibugfix  ! surface version
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!
!* 1D physical dimension
!
IF (lhook) CALL dr_hook('READ_ISBA_CANOPY_N',0,zhook_handle)
yrecfm='SIZE_NATURE'
 CALL get_type_dim_n(dtco, u, &
                     'NATURE',ilu)
!
!
!* flag to use or not canopy levels
!
yrecfm='VERSION'
 CALL read_surf(&
                hprogram,yrecfm,iversion,iresp)
!
yrecfm='BUG'
 CALL read_surf(&
                hprogram,yrecfm,ibugfix,iresp)
!
IF (iversion<3) THEN
  i%LCANOPY = .false.
ELSE
  yrecfm='ISBA_CANOPY'
  CALL read_surf(&
                hprogram,yrecfm,i%LCANOPY,iresp)
END IF
!
IF (.NOT.i%LCANOPY) THEN
  ALLOCATE(icp%XZ  (0,0))
  ALLOCATE(icp%XU  (0,0))
  ALLOCATE(icp%XT  (0,0))
  ALLOCATE(icp%XQ  (0,0))
  ALLOCATE(icp%XTKE(0,0))
  ALLOCATE(icp%XLMO(0)  )
  ALLOCATE(icp%XP  (0,0))
  ALLOCATE(icp%XDZ (0,0))
  ALLOCATE(icp%XZF (0,0))
  ALLOCATE(icp%XDZF(0,0))
  IF (lhook) CALL dr_hook('READ_ISBA_CANOPY_N',1,zhook_handle)
  RETURN
ENDIF
!
!* number of vertical levels
!
yrecfm='ISBA_CAN_LVL'
 CALL read_surf(&
                hprogram,yrecfm,icp%NLVL,iresp)
!
!*       2.     Prognostic fields:
!               -----------------
!
!* altitudes
!
ALLOCATE(icp%XZ(ilu,icp%NLVL))
!
DO jlayer=1,icp%NLVL
  WRITE(yrecfm,'(A10,I2.2)') 'ISBA_CAN_Z',jlayer
  CALL read_surf(&
                hprogram,yrecfm,icp%XZ(:,jlayer),iresp)
END DO
!
ALLOCATE(icp%XU  (ilu,icp%NLVL))
ALLOCATE(icp%XT  (ilu,icp%NLVL))
ALLOCATE(icp%XQ  (ilu,icp%NLVL))
ALLOCATE(icp%XTKE(ilu,icp%NLVL))
ALLOCATE(icp%XLMO(ilu)     )
ALLOCATE(icp%XP  (ilu,icp%NLVL))
!
IF (iversion>7 .OR. iversion==7 .AND.ibugfix>=2) THEN
  yrecfm='STORAGETYPE'
  CALL read_surf(&
                hprogram,yrecfm,yread,iresp)
ELSE
  yread = 'ALL'
ENDIF
!
IF(yread=='ALL') THEN
  !
  !* wind in SBL
  DO jlayer=1,icp%NLVL
    WRITE(yrecfm,'(A10,I2.2)') 'ISBA_CAN_U',jlayer
    CALL read_surf(&
                hprogram,yrecfm,icp%XU(:,jlayer),iresp)
  END DO
  !
  !* theta in SBL
  DO jlayer=1,icp%NLVL
    WRITE(yrecfm,'(A10,I2.2)') 'ISBA_CAN_T',jlayer
    CALL read_surf(&
                hprogram,yrecfm,icp%XT(:,jlayer),iresp)
  END DO
  !
  !* humidity in SBL
  DO jlayer=1,icp%NLVL
    WRITE(yrecfm,'(A10,I2.2)') 'ISBA_CAN_Q',jlayer
    CALL read_surf(&
                hprogram,yrecfm,icp%XQ(:,jlayer),iresp)
  END DO
  !
  !* Tke in SBL
  DO jlayer=1,icp%NLVL
    WRITE(yrecfm,'(A10,I2.2)') 'ISBA_CAN_E',jlayer
    CALL read_surf(&
                hprogram,yrecfm,icp%XTKE(:,jlayer),iresp)
  END DO
  !
  !* Monin-Obhukov length
  yrecfm='ISBA_CAN_LMO     '
  CALL read_surf(&
                hprogram,yrecfm,icp%XLMO(:),iresp)
  !
  !* Pressure
  DO jlayer=1,icp%NLVL
    WRITE(yrecfm,'(A10,I2.2)') 'ISBA_CAN_P',jlayer
    CALL read_surf(&
                hprogram,yrecfm,icp%XP(:,jlayer),iresp)
  END DO
  !
ELSE
  icp%XU  (:,:) = xundef
  icp%XT  (:,:) = xundef
  icp%XQ  (:,:) = xundef
  icp%XTKE(:,:) = xundef
  icp%XLMO(:)   = xundef
  icp%XP  (:,:) = xundef
ENDIF
!
!
!* Grid characteristics
!
!
!  --------------------------------- XZ(k+1)                     XDZ(k+1)
!                                                                           ^
!                                                                           |
!                                                                           |
!  - - - - - - - - - - - - - - - - - XZf(k+1)                               | XDZf(k+1)
!                                                              ^            |
!                                                              |            |
!  --------------------------------- XZ(k), XU, XT, XQ, XTKE   | XDZ(k)     V
!                                                              |            ^
!  - - - - - - - - - - - - - - - - - XZf(k)                    V            | XDZf(k)
!  --------------------------------- XZ(k-1)                     XDZ(k-1)   V
!  - - - - - - - - - - - - - - - - - XZf(k-1)
!
ALLOCATE(icp%XDZ (ilu,icp%NLVL))
ALLOCATE(icp%XZF (ilu,icp%NLVL))
ALLOCATE(icp%XDZF(ilu,icp%NLVL))
 CALL canopy_grid(ilu,icp%NLVL,icp%XZ,icp%XZF,icp%XDZ,icp%XDZF)
!
IF (lhook) CALL dr_hook('READ_ISBA_CANOPY_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_isba_canopy_n