read_flake_sbln.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_flake_sbl_n (DTCO, U, F, FSB, &
                                   hprogram)
!     #########################################
!
!!****  *READ_FLAKE_SBL_n* - reads FLAKE fields
!!                        
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!!      E. Martin   01/2012 Add LSBL_COLD_START
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_flake_n, ONLY : flake_t
USE modd_flake_sbl_n, ONLY : flake_sbl_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_surf_par,      ONLY : xundef
!
USE modi_read_surf
USE modi_canopy_grid
USE modi_get_type_dim_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(flake_t), INTENT(INOUT) :: f
TYPE(flake_sbl_t), INTENT(INOUT) :: fsb
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
 CHARACTER(LEN=6),  INTENT(IN)  :: hprogram ! calling program
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
 CHARACTER(LEN=12) :: yrecfm         ! Name of the article to be read
 CHARACTER(LEN=3)  :: yread
INTEGER :: ilu     ! 1D physical dimension
INTEGER :: iresp   ! Error code after redding
INTEGER :: jlayer  ! loop counter on layers
INTEGER :: iversion, ibugfix
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
!* 1D physical dimension
!
IF (lhook) CALL dr_hook('READ_FLAKE_SBL_N',0,zhook_handle)
 CALL get_type_dim_n(dtco, u, &
                     'WATER ',ilu)
!
yrecfm='VERSION'
 CALL read_surf(&
                hprogram,yrecfm,iversion,iresp)
!
yrecfm='BUG'
 CALL read_surf(&
                hprogram,yrecfm,ibugfix,iresp)
!
!* flag to use or not SBL levels
!
yrecfm='WAT_SBL'
 CALL read_surf(&
                hprogram,yrecfm,f%LSBL,iresp)
!
IF (.NOT.f%LSBL) THEN
  ALLOCATE(fsb%XZ  (0,0))
  ALLOCATE(fsb%XU  (0,0))
  ALLOCATE(fsb%XT  (0,0))
  ALLOCATE(fsb%XQ  (0,0))
  ALLOCATE(fsb%XTKE(0,0))
  ALLOCATE(fsb%XLMO(0)  )
  ALLOCATE(fsb%XP  (0,0))
  ALLOCATE(fsb%XDZ (0,0))
  ALLOCATE(fsb%XZF (0,0))
  ALLOCATE(fsb%XDZF(0,0))
  IF (lhook) CALL dr_hook('READ_SEAFLUX_SBL_N',1,zhook_handle)
  RETURN
ENDIF
!
!* number of vertical levels
!
yrecfm='WAT_SBL_LVL'
 CALL read_surf(&
                hprogram,yrecfm,fsb%NLVL,iresp)
!
!*       2.     Prognostic fields:
!               -----------------
!
!* altitudes
!
ALLOCATE(fsb%XZ(ilu,fsb%NLVL))
!
DO jlayer=1,fsb%NLVL
  WRITE(yrecfm,'(A9,I2.2,A1)') 'WAT_SBL_Z',jlayer,' '
  CALL read_surf(&
                hprogram,yrecfm,fsb%XZ(:,jlayer),iresp)
END DO
!
ALLOCATE(fsb%XU  (ilu,fsb%NLVL))
ALLOCATE(fsb%XT  (ilu,fsb%NLVL))
ALLOCATE(fsb%XQ  (ilu,fsb%NLVL))
ALLOCATE(fsb%XTKE(ilu,fsb%NLVL))
ALLOCATE(fsb%XLMO(ilu)     )
ALLOCATE(fsb%XP  (ilu,fsb%NLVL))
!
IF (iversion>7 .OR. iversion==7 .AND.ibugfix>=2) THEN
  yrecfm='STORAGETYPE'
  CALL read_surf(&
                hprogram,yrecfm,yread,iresp)
ELSE
  yread = 'ALL'
ENDIF
!
IF(yread=='ALL') THEN
  !
  !* wind in SBL
  DO jlayer=1,fsb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'WAT_SBL_U',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,fsb%XU(:,jlayer),iresp)
  END DO
  !
  !* theta in SBL
  DO jlayer=1,fsb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'WAT_SBL_T',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,fsb%XT(:,jlayer),iresp)
  END DO
  !
  !* humidity in SBL
  DO jlayer=1,fsb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'WAT_SBL_Q',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,fsb%XQ(:,jlayer),iresp)
  END DO
  !
  !* Tke in SBL
  DO jlayer=1,fsb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'WAT_SBL_E',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,fsb%XTKE(:,jlayer),iresp)
  END DO
  !
  !* Monin-Obhukov length
  yrecfm='WAT_SBL_LMO     '
  CALL read_surf(&
                hprogram,yrecfm,fsb%XLMO(:),iresp)
  !
  !* Pressure
  DO jlayer=1,fsb%NLVL
    WRITE(yrecfm,'(A9,I2.2,A1)') 'WAT_SBL_P',jlayer,' '
    CALL read_surf(&
                hprogram,yrecfm,fsb%XP(:,jlayer),iresp)
  END DO
  !
ELSE
  fsb%XU  (:,:) = xundef
  fsb%XT  (:,:) = xundef
  fsb%XQ  (:,:) = xundef
  fsb%XTKE(:,:) = xundef
  fsb%XLMO(:)   = xundef
  fsb%XP  (:,:) = xundef
ENDIF
!
!
!* Grid characteristics
!
!
!  --------------------------------- XZ(k+1)                     XDZ(k+1)
!                                                                           ^
!                                                                           |
!                                                                           |
!  - - - - - - - - - - - - - - - - - XZf(k+1)                               | XDZf(k+1)
!                                                              ^            |
!                                                              |            |
!  --------------------------------- XZ(k), XU, XT, XQ, XTKE   | XDZ(k)     V
!                                                              |            ^
!  - - - - - - - - - - - - - - - - - XZf(k)                    V            | XDZf(k)
!  --------------------------------- XZ(k-1)                     XDZ(k-1)   V
!  - - - - - - - - - - - - - - - - - XZf(k-1)
!
ALLOCATE(fsb%XDZ (ilu,fsb%NLVL))
ALLOCATE(fsb%XZF (ilu,fsb%NLVL))
ALLOCATE(fsb%XDZF(ilu,fsb%NLVL))
 CALL canopy_grid(ilu,fsb%NLVL,fsb%XZ,fsb%XZF,fsb%XDZ,fsb%XDZF)
!
IF (lhook) CALL dr_hook('READ_FLAKE_SBL_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_flake_sbl_n