pack_pgd.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE pack_pgd (DTCO, U, &
                           hprogram, hsurf,                 &
                            hgrid,  pgrid_par,               &
                            ocover, pcover, pzs,             &
                            plat, plon, pmesh_size, pdir     )  
!     ##############################################################
!
!!**** *PACK_PGD* packs ISBA physiographic fields from all surface points to ISBA points
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    03/2004
!!    Escobar J.  08/02/2005 : bug declare ILU local variable
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_pgd_grid,       ONLY : nl, cgrid, xgrid_par
!
USE modd_data_cover_par, ONLY : jpcover
!
USE modi_get_cover_n
USE modi_get_lcover_n
USE modi_get_zs_n
USE modi_pack_same_rank
USE modi_pack_grid
USE modi_latlon_grid
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_get_surf_mask_n
!
USE modi_get_type_dim_n
!
USE modi_get_luout
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
 CHARACTER(LEN=6),        INTENT(IN) :: hprogram  ! Type of program
 CHARACTER(LEN=6),        INTENT(IN) :: hsurf     ! surface type
!
 CHARACTER(LEN=10),       INTENT(OUT):: hgrid     ! grid used
REAL,    DIMENSION(:),   POINTER    :: pgrid_par ! grid definition
LOGICAL, DIMENSION(:),   INTENT(OUT):: ocover    ! list of present cover
REAL,    DIMENSION(:,:), POINTER :: pcover    ! cover fraction
REAL,    DIMENSION(:),   INTENT(OUT):: pzs       ! zs
REAL,    DIMENSION(:),   INTENT(OUT):: plat      ! latitude
REAL,    DIMENSION(:),   INTENT(OUT):: plon      ! longitude
REAL,    DIMENSION(:),   INTENT(OUT):: pmesh_size! mesh size
REAL,    DIMENSION(:),   INTENT(OUT), OPTIONAL :: pdir ! angle of grid axis with N.
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER                        :: iluout ! output listing logical unit
INTEGER                        :: il     ! number of points
INTEGER                        :: ilu    ! expected physical size of full surface array
INTEGER                        :: jcover
INTEGER, DIMENSION(:), POINTER :: imask  ! mask for packing from complete field to nature field
REAL,    DIMENSION(SIZE(PLAT)) :: zdir
!
REAL, DIMENSION(NL)    :: zcover ! cover  on all surface points
LOGICAL, DIMENSION(JPCOVER)    :: gcover ! list of existing cover
REAL, DIMENSION(NL)            :: zzs    ! zs     on all surface points
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('PACK_PGD',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
!*    1.      Number of points and packing
!             ----------------------------
!
 CALL get_type_dim_n(dtco, u, &
                     hsurf,il)
ALLOCATE(imask(il))
ilu=0
 CALL get_surf_mask_n(dtco, u, &
                      hsurf,il,imask,ilu,iluout)
!
!-------------------------------------------------------------------------------
!
!*    2.      Packing of grid
!             ---------------
!
 CALL pack_grid(imask,cgrid,hgrid,xgrid_par,pgrid_par)
!
!-------------------------------------------------------------------------------
!
!*    3.      Computes geographical quantities
!             --------------------------------
!
 CALL latlon_grid(hgrid,SIZE(pgrid_par),il,iluout,pgrid_par,plat,plon,pmesh_size,zdir)
!
IF (present(pdir)) pdir = zdir
!
!-------------------------------------------------------------------------------
!
!*    4.      Packing of fields
!             -----------------
!
 CALL get_lcover_n(u, &
                   hprogram,jpcover,gcover)
!
ALLOCATE(pcover(SIZE(plat),count(gcover)))
!
DO jcover=1,count(gcover)
  CALL get_cover_n(u, &
                   hprogram,jcover,zcover)
  CALL pack_same_rank(imask,zcover(:),pcover(:,jcover))
ENDDO

 CALL get_zs_n(u, &
               hprogram,nl,zzs)
!
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
ocover=gcover
!
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
 CALL pack_same_rank(imask,zzs(:),pzs(:))
!
!-------------------------------------------------------------------------------
!
DEALLOCATE(imask)
IF (lhook) CALL dr_hook('PACK_PGD',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE pack_pgd