diag_inline_watfluxn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE diag_inline_watflux_n (DGW, W, &
                                          ptstep, pta, pqa, ppa, pps, prhoa, pzona,  &
                                           pmera, pht, phw, pcd, pcdn, pch, pri, phu,  &
                                           pz0h, pqsat, psfth, psftq, psfzon, psfmer,      &
                                           pdir_sw, psca_sw, plw, pdir_alb, psca_alb,      &
                                           pemis, ptrad, prain, psnow, psfth_ice,   &
                                           psftq_ice                                       )  
!     ###############################################################################
!
!!****  *DIAG_INLINE_WATFLUX_n * - computes diagnostics during WATFLUX time-step
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      B. Decharme 08/2009 : Diag for Earth System Model Coupling
!!      S. Riette   06/2009 CLS_2M becomes CLS_TQ, CLS_TQ and CLS_WIND have one
!!                          more argument (height of diagnostic)
!       B. decharme 04/2013 : Add EVAP and SUBL diag
!!------------------------------------------------------------------
!

!
!
!
USE modd_diag_watflux_n, ONLY : diag_watflux_t
USE modd_watflux_n, ONLY : watflux_t
!
USE modd_csts,           ONLY : xtt
USE modd_surf_par,       ONLY : xundef
USE modd_sfx_oasis,      ONLY : lcpl_sea, lcpl_seaice
!
USE modi_param_cls
USE modi_cls_tq
USE modi_cls_wind
USE modi_diag_surf_budget_water
USE modi_diag_surf_budgetc_water
USE modi_diag_cpl_esm_water
! 
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(diag_watflux_t), INTENT(INOUT) :: dgw
TYPE(watflux_t), INTENT(INOUT) :: w
!
REAL,               INTENT(IN) :: ptstep ! atmospheric time-step                 (s)
REAL, DIMENSION(:), INTENT(IN) :: pta    ! atmospheric temperature
REAL, DIMENSION(:), INTENT(IN) :: pqa    ! atmospheric specific humidity
REAL, DIMENSION(:), INTENT(IN) :: ppa    ! atmospheric level pressure
REAL, DIMENSION(:), INTENT(IN) :: pps    ! surface pressure
REAL, DIMENSION(:), INTENT(IN) :: prhoa  ! air density
REAL, DIMENSION(:), INTENT(IN) :: pzona  ! zonal wind
REAL, DIMENSION(:), INTENT(IN) :: pmera  ! meridian wind
REAL, DIMENSION(:), INTENT(IN) :: pht    ! atmospheric level height
REAL, DIMENSION(:), INTENT(IN) :: phw    ! atmospheric level height for wind
REAL, DIMENSION(:), INTENT(IN) :: pcd    ! drag coefficient for momentum
REAL, DIMENSION(:), INTENT(IN) :: pcdn   ! neutral drag coefficient
REAL, DIMENSION(:), INTENT(IN) :: pch    ! drag coefficient for heat
REAL, DIMENSION(:), INTENT(IN) :: pri    ! Richardson number
REAL, DIMENSION(:), INTENT(IN) :: phu    ! near-surface humidity
REAL, DIMENSION(:), INTENT(IN) :: pz0h   ! roughness length for heat
REAL, DIMENSION(:), INTENT(IN) :: pqsat  ! humidity at saturation
REAL, DIMENSION(:), INTENT(IN) :: psfzon ! zonal friction
REAL, DIMENSION(:), INTENT(IN) :: psfmer ! meridian friction
REAL, DIMENSION(:), INTENT(IN) :: psfth  ! heat flux  (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: psftq  ! water flux (kg/m2/s)
REAL, DIMENSION(:,:),INTENT(IN):: pdir_sw   ! direct  solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:,:),INTENT(IN):: psca_sw   ! diffuse solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: plw       ! longwave radiation (on horizontal surf.)
REAL, DIMENSION(:), INTENT(IN) :: ptrad     ! radiative temperature                 (K)
REAL, DIMENSION(:,:),INTENT(IN):: pdir_alb  ! direct albedo for each spectral band  (-)
REAL, DIMENSION(:,:),INTENT(IN):: psca_alb  ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(:), INTENT(IN) :: pemis     ! emissivity                            (-)
!
REAL, DIMENSION(:), INTENT(IN) :: prain     ! Rainfall (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: psnow     ! Snowfall (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: psfth_ice ! heat flux  (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: psftq_ice ! water flux (kg/m2/s)
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PTA)) :: zh
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('DIAG_INLINE_WATFLUX_N',0,zhook_handle)
!
! * Mean surface temperature need to couple with AGCM
!
dgw%XDIAG_TS(:) = w%XTS(:)
!
IF (.NOT. w%LSBL) THEN
!
  IF (dgw%N2M==1) THEN
    CALL param_cls(pta, w%XTS, pqa, ppa, prhoa, pzona, pmera, pht, phw, &
                     psfth, psftq, psfzon, psfmer,                    &
                     dgw%XT2M, dgw%XQ2M, dgw%XHU2M, dgw%XZON10M, dgw%XMER10M              )  
  ELSE IF (dgw%N2M==2) THEN
    zh(:)=2.          
    CALL cls_tq(pta, pqa, ppa, pps, pht,         &
                  pcd, pch, pri,                   &
                  w%XTS, phu, pz0h, zh,              &
                  dgw%XT2M, dgw%XQ2M, dgw%XHU2M                )  
    zh(:)=10.                
    CALL cls_wind(pzona, pmera, phw,             &
                    pcd, pcdn, pri, zh,            &
                    dgw%XZON10M, dgw%XMER10M               )  
  END IF
!
  IF (dgw%N2M>=1) THEN
    !
    dgw%XT2M_MIN(:) = min(dgw%XT2M_MIN(:),dgw%XT2M(:))
    dgw%XT2M_MAX(:) = max(dgw%XT2M_MAX(:),dgw%XT2M(:))
    !
    dgw%XHU2M_MIN(:) = min(dgw%XHU2M_MIN(:),dgw%XHU2M(:))
    dgw%XHU2M_MAX(:) = max(dgw%XHU2M_MAX(:),dgw%XHU2M(:))
    !
    dgw%XWIND10M  (:) = sqrt(dgw%XZON10M(:)**2+dgw%XMER10M(:)**2)
    dgw%XWIND10M_MAX(:) = max(dgw%XWIND10M_MAX(:),dgw%XWIND10M(:))
    !
    !* Richardson number
    dgw%XRI = pri
    !
  ENDIF
!
ELSE
  IF (dgw%N2M>=1) THEN
    dgw%XT2M    = xundef
    dgw%XQ2M    = xundef
    dgw%XHU2M   = xundef
    dgw%XZON10M = xundef
    dgw%XMER10M = xundef
    dgw%XRI     = pri
  ENDIF
ENDIF
!
IF (dgw%LSURF_BUDGET.OR.dgw%LSURF_BUDGETC) THEN
  !
  CALL  diag_surf_budget_water(xtt, w%XTS, prhoa, psfth, psftq,          &
                                  pdir_sw, psca_sw, plw,                &
                                  pdir_alb, psca_alb, pemis, ptrad,     &
                                  psfzon, psfmer,                       &
                                  dgw%XRN, dgw%XH, dgw%XLE, dgw%XLEI, dgw%XGFLUX,           &
                                  dgw%XSWD, dgw%XSWU, dgw%XSWBD, dgw%XSWBU, dgw%XLWD, dgw%XLWU, &
                                  dgw%XFMU, dgw%XFMV, dgw%XEVAP, dgw%XSUBL )  
  !
END IF
!
IF(dgw%LSURF_BUDGETC)THEN
  CALL diag_surf_budgetc_water(dgw, &
                               ptstep, dgw%XRN, dgw%XH, dgw%XLE, dgw%XLEI, dgw%XGFLUX,  &
                                 dgw%XSWD, dgw%XSWU, dgw%XLWD, dgw%XLWU, dgw%XFMU, dgw%XFMV,&
                                 dgw%XEVAP, dgw%XSUBL                       )  
ENDIF
!
IF (dgw%LCOEF) THEN
  !
  !* Transfer coefficients
  !
  dgw%XCD = pcd
  dgw%XCH = pch
  dgw%XCE = pch
  !
  !* Roughness lengths
  !
  dgw%XZ0  = w%XZ0
  dgw%XZ0H = pz0h
  !
ENDIF
!
IF (dgw%LSURF_VARS) THEN
  !
  !* Humidity at saturation
  !
  dgw%XQS = pqsat
  !
ENDIF
!
! Diag for Earth System Model coupling
!
IF (lcpl_sea) THEN
!
  CALL diag_cpl_esm_water(w,                                                             &
                          lcpl_seaice,ptstep,dgw%XZON10M,dgw%XMER10M,dgw%XFMU,dgw%XFMV,  &
                          dgw%XSWD,dgw%XSWU,dgw%XGFLUX,psftq,prain,psnow,plw,w%XTICE,    &
                          psfth_ice,psftq_ice,pdir_sw,psca_sw                            )  
! 
ENDIF
IF (lhook) CALL dr_hook('DIAG_INLINE_WATFLUX_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_inline_watflux_n