diag_cpl_esm_water.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE diag_cpl_esm_water (W, &
                                      ocpl_seaice,ptstep,pzon10m,pmer10m,psfu,psfv,   &
                                      pswd,pswu,pgflux,psftq,prain,psnow,plw,ptice,   &
                                      psfth_ice,psftq_ice,pdir_sw,psca_sw             )  
!     #####################################################################
!
!!****  *DIAG_CPL_ESM_WATER * - Computes diagnostics over sea for 
!!                                Earth system model coupling
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     B. Decharme 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    08/2009
!!------------------------------------------------------------------
!
!
USE modd_watflux_n, ONLY : watflux_t
!
USE modd_csts,      ONLY : xstefan, xlstt
USE modd_water_par, ONLY : xemiswatice
!
! 
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(watflux_t), INTENT(INOUT) :: w
!
LOGICAL,            INTENT(IN) :: ocpl_seaice ! sea-ice / ocean key
REAL,               INTENT(IN) :: ptstep    ! atmospheric time-step
REAL, DIMENSION(:), INTENT(IN) :: pzon10m   ! zonal wind
REAL, DIMENSION(:), INTENT(IN) :: pmer10m   ! meridian wind
REAL, DIMENSION(:), INTENT(IN) :: psfu      ! zonal wind stress
REAL, DIMENSION(:), INTENT(IN) :: psfv      ! meridian wind stress
REAL, DIMENSION(:), INTENT(IN) :: pswd      ! total incoming short wave radiation
REAL, DIMENSION(:), INTENT(IN) :: pswu      ! total upward short wave radiation
REAL, DIMENSION(:), INTENT(IN) :: pgflux    ! storage flux
REAL, DIMENSION(:), INTENT(IN) :: psftq     ! water flux
REAL, DIMENSION(:), INTENT(IN) :: prain     ! Rainfall
REAL, DIMENSION(:), INTENT(IN) :: psnow     ! Snowfall
REAL, DIMENSION(:), INTENT(IN) :: plw       ! longwave radiation (on horizontal surf.)
REAL, DIMENSION(:), INTENT(IN) :: psfth_ice ! heat flux  (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: psftq_ice ! water flux (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: ptice     ! Ice Surface Temperature
REAL, DIMENSION(:,:),INTENT(IN):: pdir_sw   ! direct  solar radiation (on horizontal surf.)
REAL, DIMENSION(:,:),INTENT(IN):: psca_sw   ! diffuse solar radiation (on horizontal surf.)
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(W%XICE_ALB)) :: zswu, ztice4
!
INTEGER                      :: iswb ! number of SW bands
INTEGER                      :: jswb ! loop counter on number of SW bands
INTEGER                      :: ini  ! number of points
INTEGER                      :: ji   ! loop counter on number of points
!
REAL(KIND=JPRB) :: zhook_handle
!
IF (lhook) CALL dr_hook('DIAG_CPL_ESM_WATER',0,zhook_handle)
!
!-------------------------------------------------------------------------------------
! Total or free-ice water flux
!-------------------------------------------------------------------------------------
!
!* 10m wind speed (m)
!
w%XCPL_WATER_WIND(:) = w%XCPL_WATER_WIND(:) + ptstep * sqrt(pzon10m(:)**2+pmer10m(:)**2)
! 
!* wind stress (Pa.s)
!
w%XCPL_WATER_FWSU(:) = w%XCPL_WATER_FWSU(:) + ptstep * psfu(:)
w%XCPL_WATER_FWSV(:) = w%XCPL_WATER_FWSV(:) + ptstep * psfv(:)
w%XCPL_WATER_FWSM(:) = w%XCPL_WATER_FWSM(:) + ptstep * sqrt(psfu(:)**2+psfv(:)**2)
!
!* Solar net heat flux (J/m2)
!
w%XCPL_WATER_SNET(:) = w%XCPL_WATER_SNET(:) + ptstep * (pswd(:) - pswu(:))
!
!* Non solar heat flux (J/m2)
!
w%XCPL_WATER_HEAT(:) = w%XCPL_WATER_HEAT(:) + ptstep * (pgflux(:) + pswu(:) - pswd(:)) 
!
!* Evaporation (kg/m2)
!
w%XCPL_WATER_EVAP(:) = w%XCPL_WATER_EVAP(:) + ptstep * psftq(:)
!
!* Precip (kg/m2)
! 
w%XCPL_WATER_RAIN(:) = w%XCPL_WATER_RAIN(:) + ptstep * prain(:) 
w%XCPL_WATER_SNOW(:) = w%XCPL_WATER_SNOW(:) + ptstep * psnow(:)
!
!-------------------------------------------------------------------------------------
! Ice flux
!-------------------------------------------------------------------------------------
!
IF (ocpl_seaice) THEN
!
  ini  = SIZE(pdir_sw,1)
  iswb = SIZE(pdir_sw,2)
!
!* Solar net heat flux (J/m2)
!
  zswu(:)=0.0
  DO jswb=1,iswb
     DO ji=1,ini
      zswu(ji) = zswu(ji) + (pdir_sw(ji,jswb)+psca_sw(ji,jswb)) * w%XICE_ALB(ji)
     ENDDO
  ENDDO
!
  w%XCPL_WATERICE_SNET(:) = w%XCPL_WATERICE_SNET(:) + ptstep * (pswd(:) - zswu(:))
!
!* Non solar heat flux (J/m2)
!
  ztice4(:)=ptice(:)**4
!
  w%XCPL_WATERICE_HEAT(:) = w%XCPL_WATERICE_HEAT(:) + ptstep * ( xemiswatice*(plw(:)-xstefan*ztice4(:)) &
                                                             - psfth_ice(:) - xlstt*psftq_ice(:)  )  
!
!* Sublimation (kg/m2)
!
  w%XCPL_WATERICE_EVAP(:) = w%XCPL_WATERICE_EVAP(:) + ptstep * psftq_ice(:)
!
ENDIF
!
IF (lhook) CALL dr_hook('DIAG_CPL_ESM_WATER',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_cpl_esm_water