diag_surf_budget_water.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE diag_surf_budget_water (PTT, PTS, PRHOA, PSFTH, PSFTQ,         &
                                           pdir_sw, psca_sw, plw,                &
                                           pdir_alb, psca_alb, pemis, ptrad,     &
                                           psfzon, psfmer,                       &
                                           prn, ph, ple, plei, pgflux,           &
                                           pswd, pswu, pswbd, pswbu, plwd, plwu, &
                                           pfmu, pfmv, pevap, psubl              )  
!     ###############################################################################
!
!!****  *DIAG_SURF_BUDGET_WATER * - Computes diagnostics over water
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!       B. decharme 04/2013 : Add EVAP and SUBL diag
!                             Ts instead of Tsrad
!!------------------------------------------------------------------
!

!
!
USE modd_csts,           ONLY : xstefan, xlstt, xlvtt, xcpd
!
! 
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL,               INTENT(IN) :: ptt       ! freezing temperature of water surface
REAL, DIMENSION(:), INTENT(IN) :: pts       ! surface temperature (K)
REAL, DIMENSION(:), INTENT(IN) :: prhoa     ! air density
REAL, DIMENSION(:), INTENT(IN) :: psfth     ! heat flux
REAL, DIMENSION(:), INTENT(IN) :: psftq     ! water flux
REAL, DIMENSION(:,:),INTENT(IN):: pdir_sw   ! direct  solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:,:),INTENT(IN):: psca_sw   ! diffuse solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: plw       ! longwave radiation (on horizontal surf.)
REAL, DIMENSION(:), INTENT(IN) :: ptrad     ! radiative temperature                 (K)
REAL, DIMENSION(:,:),INTENT(IN):: pdir_alb  ! direct albedo for each spectral band  (-)
REAL, DIMENSION(:,:),INTENT(IN):: psca_alb  ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(:), INTENT(IN) :: pemis     ! emissivity                            (-)
REAL, DIMENSION(:), INTENT(IN) :: psfzon    ! zonal friction
REAL, DIMENSION(:), INTENT(IN) :: psfmer    ! meridional friction
!
REAL, DIMENSION(:), INTENT(OUT):: prn       ! net radiation                         (W/m2)
REAL, DIMENSION(:), INTENT(OUT):: ph        ! sensible heat flux                    (W/m2)
REAL, DIMENSION(:), INTENT(OUT):: ple       ! total latent heat flux                (W/m2)
REAL, DIMENSION(:), INTENT(OUT):: plei      ! sublimation latent heat flux          (W/m2)
REAL, DIMENSION(:), INTENT(OUT):: pgflux    ! storage flux                          (W/m2)
REAL, DIMENSION(:), INTENT(OUT):: pevap     ! total evaporation                     (kg/m2/s)
REAL, DIMENSION(:), INTENT(OUT):: psubl     ! sublimation                           (kg/m2/s)
!
REAL, DIMENSION(:,:), INTENT(OUT):: pswbd  ! incoming short wave radiation by spectral band (W/m2)
REAL, DIMENSION(:,:), INTENT(OUT):: pswbu  ! upward  short wave radiation by spectral band (W/m2)
REAL, DIMENSION(:), INTENT(OUT):: pswd     ! total incoming short wave radiation (W/m2)
REAL, DIMENSION(:), INTENT(OUT):: pswu     ! total upward short wave radiation (W/m2)
REAL, DIMENSION(:), INTENT(OUT):: plwd     ! Downward long wave radiation (W/m2)
REAL, DIMENSION(:), INTENT(OUT):: plwu     ! upward long wave radiation (W/m2)  
!
REAL, DIMENSION(:), INTENT(OUT):: pfmu     ! zonal friction
REAL, DIMENSION(:), INTENT(OUT):: pfmv     ! meridional friction
!
!*      0.2    declarations of local variables
!
INTEGER                      :: iswb ! number of SW bands
INTEGER                      :: jswb ! loop counter on number of SW bands
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
!
IF (lhook) CALL dr_hook('DIAG_SURF_BUDGET_WATER',0,zhook_handle)
iswb = SIZE(pdir_sw,2)
! 
!* total incoming and outgoing SW
!
DO jswb=1,iswb
  pswbd(:,jswb) = pdir_sw(:,jswb)                    + psca_sw(:,jswb)
  pswbu(:,jswb) = pdir_sw(:,jswb) * pdir_alb(:,jswb) + psca_sw(:,jswb) * psca_alb(:,jswb) 
ENDDO
!
pswd(:) = 0.
pswu(:) = 0.
DO jswb=1,iswb
   pswd(:)=pswd(:)+pswbd(:,jswb)
   pswu(:)=pswu(:)+pswbu(:,jswb)
ENDDO
!
!*incoming outgoing LW
!
plwd(:)=plw(:)
plwu(:)=pemis(:)*xstefan*ptrad(:)**4 + (1.-pemis(:))*plw(:)
!
!* net radiation
!
prn    =   pswd(:) - pswu(:) + plwd(:) - plwu(:)
!
!* sensible heat flux
!
ph     = psfth(:)
!
!* latent heat flux
!
WHERE (pts<ptt  )
  ple    = psftq * xlstt
  plei   = psftq * xlstt
  pevap  = psftq
  psubl  = psftq
ELSEWHERE
  ple    = psftq * xlvtt
  plei   = 0.0
  pevap  = psftq
  psubl  = 0.0
END WHERE
!
!* storage flux
!
pgflux = prn - ph - ple
!
!* wind stress
!
pfmu = psfzon
!
pfmv = psfmer
IF (lhook) CALL dr_hook('DIAG_SURF_BUDGET_WATER',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_surf_budget_water