treat_bathyfield.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE treat_bathyfield (UG, U, USS, &
                                   HPROGRAM,HSCHEME,HFILETYPE,    &
                              HSUBROUTINE,HFILENAME,HNCVARNAME,   &
                              HFIELD, PPGDARRAY,HSFTYPE               )  
!     ##############################################################
!
!!**** *TREAT_BATHYFIELD* chooses which treatment subroutine to use to read 
!!                        the bathymetry
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    C. Lebeaupin Brossier        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!    
!!    Original    01/2008
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
!
!
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_sso_n, ONLY : sso_t
!
USE modd_surf_par, ONLY : xundef
USE modd_pgdwork, ONLY : nsize, nsize_all, xall, xsumval
!
USE modd_surfex_mpi, ONLY : nrank, npio, nproc, ncomm, nreq, nindex, idx_r, &
                                nsize_task,nreq, nsize_max=>nsize
!
USE modi_ini_ssowork
USE modi_get_luout
USE modi_read_direct
USE modi_read_binllv
USE modi_read_binllvfast
USE modi_read_ascllv
USE modi_read_netcdf
USE modi_average2_mesh
USE modi_read_and_send_mpi
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
USE modi_average2_cover
!
USE modi_average2_orography
!
USE modi_read_direct_gauss
IMPLICIT NONE
!
#ifdef SFX_MPI
include "mpif.h"
#endif
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(sso_t), INTENT(INOUT) :: USS
!
 CHARACTER(LEN=6),  INTENT(IN) :: HPROGRAM      ! Type of program
 CHARACTER(LEN=6),  INTENT(IN) :: HSCHEME       ! Scheme treated
 CHARACTER(LEN=6),  INTENT(IN) :: HFILETYPE     ! Type of the data file
 CHARACTER(LEN=6),  INTENT(IN) :: HSUBROUTINE   ! Name of the subroutine to call
 CHARACTER(LEN=28), INTENT(IN) :: HFILENAME     ! Name of the field file.
 CHARACTER(LEN=28), INTENT(IN) :: HNCVARNAME    ! Name of the variable in netcdf file
 CHARACTER(LEN=20), INTENT(IN) :: HFIELD        ! Name of the field.
REAL, DIMENSION(:), INTENT(INOUT), OPTIONAL :: PPGDARRAY ! field on MESONH grid
 CHARACTER(LEN=3),   INTENT(IN),    OPTIONAL :: HSFTYPE
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
REAL, DIMENSION(:,:), ALLOCATABLE :: ZPGDARRAY
INTEGER, DIMENSION(:), ALLOCATABLE :: IMASK
REAL, DIMENSION(:,:), ALLOCATABLE :: ZVAL
INTEGER, DIMENSION(:), ALLOCATABLE :: ISIZE
!
#ifdef SFX_MPI
INTEGER, DIMENSION(MPI_STATUS_SIZE) :: ISTATUS
INTEGER, DIMENSION(MPI_STATUS_SIZE,NPROC-1) :: ISTATUS2
#endif
INTEGER :: ILUOUT, INFOMPI, JP, ICPT, JI, JL, IREQ, IDX,&
                        IDX_SAVE
REAL(KIND=JPRB) :: ZHOOK_HANDLE, ZHOOK_HANDLE_OMP
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TREAT_BATHYFIELD',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
!*    1.     Selection of type of reading (and point by point treatment)
!            -----------------------------------------------------------
!
SELECT CASE (hfiletype)

   CASE ('DIRECT')
         IF(ug%G%CGRID=="GAUSS     ")THEN
            CALL read_direct_gauss(ug, u, uss, &
                                   hprogram,hscheme,hsubroutine,hfilename,hfield)
         ELSE
            CALL read_direct(ug, u, uss, &
                             hprogram,hscheme,hsubroutine,hfilename,hfield)
         ENDIF
   CASE ('BINLLV')
       CALL ini_ssowork
    IF (nrank==npio) CALL read_binllv(ug, u, uss, &
                        hprogram,hsubroutine,hfilename)

   CASE ('BINLLF')
       CALL ini_ssowork
    IF (nrank==npio) CALL read_binllvfast(ug, u, uss, &
                            hprogram,hsubroutine,hfilename)

   CASE ('ASCLLV')
       CALL ini_ssowork
    IF (nrank==npio) CALL read_ascllv(ug, u, uss, &
                        hprogram,hsubroutine,hfilename)

   CASE ('NETCDF')
       CALL ini_ssowork
    IF (nrank==npio) CALL read_netcdf(ug, u, uss, &
                        hprogram,hsubroutine,hfilename,hncvarname)

END SELECT
!
!-------------------------------------------------------------------------------
!
!nsize contains the number of points found for each of the domain, for each task
ALLOCATE(nsize(u%NSIZE_FULL,1))
!
IF (nproc>1) THEN
  !
  ALLOCATE(isize(nsize_max))
  !
  idx_save = idx_r
  idx = idx_save + nrank
  !each task sends to each other task the part of NSIZE_ALL it got, stored in
  !isize
  CALL read_and_send_mpi(nsize_all(:,1),isize(1:nsize_task(nrank)),kpio=nrank,kdx=idx)
  !
  nsize(:,1) = 0
  !for each task
  DO jp=0,nproc-1
   !
    IF (jp/=nrank) THEN
      !
#ifdef SFX_MPI
      !each task receives each ISIZE from each task
      CALL mpi_recv(isize,nsize_max*kind(isize)/4,mpi_integer,&
                jp,idx_save+1+jp,ncomm,istatus,infompi)
#endif
      !
    ELSE
      !
      icpt = 0
      DO ji = 1,SIZE(nindex)
        IF (nindex(ji)==jp) THEN
          icpt = icpt + 1
          isize(icpt) = nsize_all(ji,1)
        ENDIF
      ENDDO
      !
    ENDIF
    !
    !nsize is the sum of all parts isize
    nsize(:,1) = nsize(:,1) + isize(1:nsize_task(nrank))
    !
  ENDDO
  DEALLOCATE(isize)
#ifdef SFX_MPI  
  CALL mpi_waitall(nproc-1,nreq(1:nproc-1),istatus2,infompi)
#endif  
ELSE
  nsize(:,1) = nsize_all(:,1)
ENDIF
!
!
DEALLOCATE(nsize_all)
!
!
SELECT CASE (hsubroutine)

  CASE ('A_MESH')
    !most simple case
    ALLOCATE(xsumval(u%NSIZE_FULL,1))
    IF (nproc>1) THEN
      xsumval(:,:) = 0.
      ALLOCATE(zval(u%NSIZE_FULL,1))
      DO jp = 0,nproc-1
        CALL read_and_send_mpi(xall(:,:,1),zval,kpio=jp)
        xsumval(:,:) = xsumval(:,:) + zval(:,:)
      ENDDO
      DEALLOCATE(zval)
    ELSE
      xsumval(:,:) = xall(:,:,1)
    ENDIF
    DEALLOCATE(xall)
    !
END SELECT
!
!*    2.     Call to the adequate subroutine (global treatment)
!            --------------------------------------------------
!
SELECT CASE (hsubroutine)

  CASE ('A_MESH')
    IF (.NOT. PRESENT(ppgdarray)) THEN
      WRITE(iluout,*) 'You asked to average a PGD field with A_MESH option,'
      WRITE(iluout,*) 'but you did not give the array to store this field'
      CALL abor1_sfx('TREAT_BATHYFIELD: PGD ARRAY IS MISSING')
    END IF
    ALLOCATE(zpgdarray(SIZE(ppgdarray),1))    
    CALL average2_mesh(zpgdarray)
    ppgdarray = zpgdarray(:,1)
    DEALLOCATE(zpgdarray)

END SELECT
IF (lhook) CALL dr_hook('TREAT_BATHYFIELD',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE treat_bathyfield