read_netcdf.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_netcdf (UG, U, USS, &
                              HPROGRAM,HSUBROUTINE,HFILENAME,HNCVARNAME)
!     ##############################################################
!
!!**** *READ_NETCDF* reads a netcdf file and copy lat/lon/val then call treatment 
!!                   subroutine
!!
!!    PURPOSE
!!    -------
!!
!!    AUTHOR
!!    ------
!!
!!    C. Lebeaupin Brossier Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    01/2008
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_sso_n, ONLY : sso_t
!
USE modd_pgd_grid,   ONLY : llatlonmask
!
USE modi_pt_by_pt_treatment
USE mode_read_cdf
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_get_luout
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(sso_t), INTENT(INOUT) :: USS
!
 CHARACTER(LEN=6),  INTENT(IN) :: HPROGRAM      ! Type of program
 CHARACTER(LEN=6),  INTENT(IN) :: HSUBROUTINE   ! Name of the subroutine to call
 CHARACTER(LEN=28), INTENT(IN) :: HFILENAME     ! Name of the field file.
 CHARACTER(LEN=28), INTENT(IN) :: HNCVARNAME    ! Name of the variable in netcdf file
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER      :: JLAT, JLON                 ! indexes of OLATLONMASK array
REAL         :: ZVALUE                     ! values of a data point
REAL         :: ZLAT                       ! latitude of data point
REAL         :: ZLON                       ! longitude of data point
!
REAL, DIMENSION(:),ALLOCATABLE :: ZVALU    ! array of values extract from netcdf file
REAL, DIMENSION(:),ALLOCATABLE :: ZLONG    ! array of values extract from netcdf file
REAL, DIMENSION(:),ALLOCATABLE :: ZLATI    ! array of values extract from netcdf file
!
INTEGER      :: ILUOUT                     ! output listing
INTEGER      :: JLOOP                      ! loop indice
INTEGER      :: JDIMENSION                 ! dimensions of ZVALU,ZLAT, 
REAL(KIND=JPRB) :: ZHOOK_HANDLE
                                           ! and ZLON arrays
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('READ_NETCDF',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
!
!*    1.      Read the netcdf file and lat/lon/val arrays dimensions
!             ------------------------------------------------------
 CALL read_dim_cdf(hfilename,hncvarname,jdimension)
ALLOCATE(zvalu(jdimension))
ALLOCATE(zlati(jdimension))
ALLOCATE(zlong(jdimension))

!*    1.      Read the netcdf file and extract lat/lon/val
!             --------------------------------------------
 CALL read_latlonval_cdf(hfilename,hncvarname,zlong(:),zlati(:),zvalu(:))
!
!----------------------------------------------------------------------------
!
!*    4.     Test if point is in the domain
!            ------------------------------
!
DO jloop=1,SIZE(zvalu)
! 
  zlon  = zlong(jloop)
  zlat  = zlati(jloop)
  zvalue= zvalu(jloop)
! 
  zlon=zlon+nint((180.-zlon)/360.)*360.
  !
  jlat = 1 + int( ( zlat + 90. ) * 2. )
  jlat = min(jlat,360)
  jlon = 1 + int( ( zlon       ) * 2. )
  jlon = min(jlon,720)
  !
  IF (.NOT. llatlonmask(jlon,jlat)) cycle
!
!-------------------------------------------------------------------------------
!
!*    5.     Call to the adequate subroutine (point by point treatment)
!            ----------------------------------------------------------
! 
  CALL pt_by_pt_treatment(ug, u, uss, &
                          iluout,  (/ zlat /) , (/ zlon /) , (/ zvalue /) , &
                            hsubroutine                                       )  
!
!-------------------------------------------------------------------------------
ENDDO
IF (ALLOCATED(zvalu       ))  DEALLOCATE(zvalu  )
IF (ALLOCATED(zlong       ))  DEALLOCATE(zlong  )
IF (ALLOCATED(zlati       ))  DEALLOCATE(zlati  )
IF (lhook) CALL dr_hook('READ_NETCDF',1,zhook_handle)
!
!----------------------------------------------------------------------------
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_netcdf