average2_mesh.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE average2_mesh(PPGDARRAY)
!     #########################################
!
!!**** *AVERAGE2_MESH* computes a PGD field
!!
!!    PURPOSE
!!    -------
!!
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    12/09/95
!!     V. Masson  03/2004  externalization
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_surfex_mpi, ONLY : nrank
USE modd_surf_par, ONLY : xundef
USE modd_pgdwork,        ONLY : nsize, xsumval, catype, xprec
USE modd_data_cover_par, ONLY : xcdref
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
REAL,    DIMENSION(:,:), INTENT(INOUT) :: PPGDARRAY ! Mesonh field
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL :: ZINT
INTEGER :: JI, JJ
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('AVERAGE2_MESH',0,zhook_handle)
SELECT CASE (catype)

  CASE ('ARI')
  WHERE (nsize(:,:)/=0)
    ppgdarray(:,:) = xsumval(:,:)/nsize(:,:)
  ENDWHERE

  CASE ('INV')
  WHERE (nsize(:,:)/=0)
    ppgdarray(:,:) = nsize(:,:)/xsumval(:,:)
  ENDWHERE

  CASE ('CDN')
  WHERE (nsize(:,:)/=0)
    ppgdarray(:,:) = xcdref/exp(sqrt(nsize(:,:)/xsumval(:,:)))
  ENDWHERE

  CASE ('MAJ')
  WHERE (nsize(:,:)/=0)
    ppgdarray(:,:) = xsumval(:,:)
  ENDWHERE
          
END SELECT
!
!
DO jj=1,SIZE(ppgdarray,2)
  DO ji = 1,SIZE(ppgdarray,1)

    IF (ppgdarray(ji,jj)/=xundef) THEN
      zint = aint(ppgdarray(ji,jj),8)
      IF (ppgdarray(ji,jj)/=zint) THEN
        ppgdarray(ji,jj) = zint + anint((ppgdarray(ji,jj)-zint)*xprec)/xprec
      ENDIF
    ENDIF

  ENDDO
ENDDO
!
IF (lhook) CALL dr_hook('AVERAGE2_MESH',1,zhook_handle)

!-------------------------------------------------------------------------------
!
END SUBROUTINE average2_mesh