sfx_xios_check_field_2d.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
 SUBROUTINE sfx_xios_check_field_2d(U, HREC, HCOMMENT, OWRITE, PFIELD2, HAXIS)
!!
!!
!!     PURPOSE
!!     --------
!!
!!     Ensure that a 2-dim field is already declared to Xios.  
!!
!!
!!     IMPLICIT ARGUMENTS :
!!     -------------------- 
!!
!!     YXIOS_DOMAIN
!!
!!
!!     EXTERNAL
!!     --------
!!
!!     XIOS LIBRARY
!!
!!
!!     REFERENCE
!!     ---------
!!
!!     XIOS Reference guide - Yann Meurdesoif - 10/10/2014 - 
!!     svn co -r 515 http://forge.ipsl.jussieu.fr/ioserver/svn/XIOS/branchs/xios-1.0 <dir> 
!!       cd <dir>/doc ; ....
!!
!!     AUTHOR
!!     ------
!!
!!     S.Sénési, CNRM
!!
!!     MODIFICATION
!!     --------------
!!
!!     Original    08/2015
!!
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE yomhook    , ONLY         : lhook,   dr_hook
USE parkind1   , ONLY         : jprb
!
USE modd_surf_atm_n, ONLY     : surf_atm_t
!
#ifdef WXIOS
USE xios, ONLY                :  xios_set_field_attr, xios_is_defined_field_attr, &
                                 xios_is_valid_axis, xios_get_axis_attr, xios_is_defined_axis_attr
USE modd_xios , ONLY          :  ypatch_dim_name
#endif
!
USE modi_set_axis
USE modi_sfx_xios_check_field
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!   Arguments
!
TYPE(surf_atm_t)      ,INTENT(INOUT):: U
 CHARACTER(LEN=*)      ,INTENT(IN)   :: HREC     ! name of the field to check
 CHARACTER(LEN=100)    ,INTENT(IN)   :: HCOMMENT ! Comment string
LOGICAL               ,INTENT(INOUT):: OWRITE   ! set to .FALSE. if any issue re. Xios for this field
REAL,DIMENSION(:,:)   ,INTENT(IN)   :: PFIELD2  ! 2D field value
 CHARACTER(LEN=*)      ,INTENT(IN) , OPTIONAL :: HAXIS    ! name of the additional axis
!
!  Local variables
!
LOGICAL            :: LISDEF, LLWRITE, LDEFUNITS
LOGICAL            :: LVALID_AXIS, LVERTICAL_AXIS
 CHARACTER(LEN=100) :: YAXIS
 CHARACTER(LEN=100) :: YUNITS
REAL(KIND=JPRB), DIMENSION(:),ALLOCATABLE :: ZAXIS
INTEGER            :: IDIM        ! for additonal dim
 CHARACTER(LEN=3)   :: YIDIM       ! for additonal dim  
REAL(KIND=JPRB)    :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('SFX_XIOS_CHECK_FIELD_2D',0,zhook_handle)
!
#ifdef WXIOS
!$OMP SINGLE
!
! Assume that every axis attribute is well defined as soon as the axis is defined
 CALL xios_is_defined_field_attr(hrec,axis_ref=lisdef) 
!
IF ( .NOT. lisdef ) THEN 
   IF (.NOT. PRESENT(haxis) .OR. (trim(haxis)=='')) THEN
      yaxis='you_should_define_a_dim_for_'//hrec//'_in_xml_file_or_call_set_axis_in_code'
   ELSE
      yaxis=trim(haxis)
   ENDIF
   lvalid_axis=xios_is_valid_axis(yaxis)
   !
   IF (trim(haxis)/=trim(ypatch_dim_name)) THEN
      IF (.NOT. lvalid_axis) THEN 
         ALLOCATE(zaxis(SIZE(pfield2,2)))
         zaxis=(/(idim, idim=1,SIZE(pfield2,2))/)
         CALL set_axis(yaxis,zaxis)
         DEALLOCATE(zaxis)
      ELSE 
         ! xxx il faut encore vérifier si le set_axis_attr des valeurs a été fait pour ce champ !!
      ENDIF
      CALL xios_set_field_attr(hrec, axis_ref=yaxis)
   ELSE 
      ! Account for loop on pacthes
      DO idim=1,SIZE(pfield2,2)
         IF (idim < 10) THEN 
            WRITE(yidim,'(I1)') idim
         ELSE
            WRITE(yidim,'(I2)') idim
         ENDIF
         CALL sfx_xios_check_field(u, trim(hrec)//'_'//trim(yidim), hcomment, llwrite, pfield1=pfield2(:,idim))
         owrite= owrite .AND. llwrite
      END DO
      ! Disable the writing as a mutli-dim array
      CALL xios_set_field_attr(hrec, enabled=.false.)
   ENDIF
ENDIF
!
!$OMP END SINGLE
#endif
IF (lhook) CALL dr_hook('SFX_XIOS_CHECK_FIELD_2D',1,zhook_handle)
! ----------------------------------------------------------------------
!
END SUBROUTINE sfx_xios_check_field_2d