set_axis.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
SUBROUTINE set_axis(HNAME, PVALUE ,CDPOSITIVE, KSIZE, CDUNITS, PBOUNDS)
!!
!!
!!     PURPOSE
!!     --------
!!
!!     Declare a Surfex axis to XIOS 
!!
!!
!!     IMPLICIT ARGUMENTS :
!!     -------------------- 
!!
!!
!!     EXTERNAL
!!     --------
!!
!!     XIOS LIBRARY
!!
!!
!!     REFERENCE
!!     ---------
!!
!!     XIOS Reference guide - Yann Meurdesoif - 10/10/2014 - 
!!     svn co -r 515 http://forge.ipsl.jussieu.fr/ioserver/svn/XIOS/branchs/xios-1.0 <dir> ; cd <dir>/doc ; ....
!!
!!     AUTHOR
!!     ------
!!
!!     S.Sénési, CNRM
!!
!!     MODIFICATION
!!     --------------
!!
!!     Original    08/2015
!!
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
USE modi_abor1_sfx
!
USE modd_xios, ONLY : lxios
#ifdef WXIOS
USE xios,      ONLY : xios_get_handle, xios_add_child, xios_set_axis_attr, xios_axisgroup, xios_axis
#endif
!
!
IMPLICIT NONE
!
!   Arguments
!
 CHARACTER(LEN=*), INTENT(IN)  :: HNAME    ! axis name
REAL,DIMENSION(:),INTENT(IN), OPTIONAL  :: PVALUE   ! axis coordinate values array
 CHARACTER(LEN=*), INTENT(IN), OPTIONAL  :: CDPOSITIVE  ! 'up' or 'down', if axis is vertical
INTEGER         , INTENT(IN), OPTIONAL  :: KSIZE       ! size of the axis (when values are not provided)
 CHARACTER(LEN=*), INTENT(IN), OPTIONAL  :: CDUNITS     ! Units for the values
REAL,DIMENSION(:,:),INTENT(IN),OPTIONAL :: PBOUNDS  ! coordinate bounds array (should be (2,:))
!
!  Local variables
!
#ifdef WXIOS
TYPE(xios_axisgroup) :: axisgroup_hdl
TYPE(xios_axis)      :: axis_hdl
#endif
!
INTEGER              :: I
REAL(KIND=JPRB), DIMENSION(:),ALLOCATABLE :: ZAXIS
REAL(KIND=JPRB)      :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('SET_AXIS',0,zhook_handle)
!
IF (lxios) THEN 
#ifdef WXIOS
!
!$OMP SINGLE
   
   CALL xios_get_handle("axis_definition",axisgroup_hdl)
   CALL xios_add_child(axisgroup_hdl,axis_hdl,hname)
   IF (PRESENT(pvalue)) THEN
      CALL xios_set_axis_attr(hname, VALUE=pvalue, n_glo=SIZE(pvalue))
      IF (PRESENT(pbounds)) THEN
         CALL xios_set_axis_attr(hname, bounds=pbounds)
      ENDIF
      IF (PRESENT(cdunits)) THEN
         CALL xios_set_axis_attr(hname, unit=cdunits)
      ENDIF
   ELSE
      IF (PRESENT(ksize)) THEN 
         ALLOCATE(zaxis(ksize))
         zaxis=(/(i, i=1,ksize)/)
         CALL xios_set_axis_attr(hname, VALUE=zaxis, n_glo=ksize)
         DEALLOCATE(zaxis)
      ELSE
         CALL abor1_sfx('SET_AXIS : MUST PROVIDE PVALUE OR KSIZE FOR'//trim(hname))
      ENDIF
   ENDIF
   IF (PRESENT(cdpositive)) THEN    
      CALL xios_set_axis_attr(hname, positive=cdpositive)
   ENDIF

!$OMP END SINGLE
!
#endif
ENDIF
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('SET_AXIS',1,zhook_handle)
!
END SUBROUTINE set_axis