sfx_xios_check_field.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
SUBROUTINE sfx_xios_check_field(U, HREC, HCOMMENT, OWRITE, PFIELD1, PFIELD2, PFIELD3, HAXIS)
!!
!!
!!     PURPOSE
!!     --------
!!
!!     Ensure that a field is already declared to Xios.  
!!     If not, declare it using HREC, and declare it in a default 
!!        output file if this file is enabled ; 
!!     If 'units' or 'name' attribute is not defined using XIOS config 
!!        files , use HCOMMENT to declare it
!!
!!     IMPLICIT ARGUMENTS :
!!     -------------------- 
!!
!!     YXIOS_DOMAIN
!!
!!
!!     EXTERNAL
!!     --------
!!
!!     XIOS LIBRARY
!!
!!
!!     REFERENCE
!!     ---------
!!
!!     XIOS Reference guide - Yann Meurdesoif - 10/10/2014 - 
!!     svn co -r 515 http://forge.ipsl.jussieu.fr/ioserver/svn/XIOS/branchs/xios-1.0 <dir> 
!!       cd <dir>/doc ; ....
!!
!!     AUTHOR
!!     ------
!!
!!     S.Sénési, CNRM
!!
!!     MODIFICATION
!!     --------------
!!
!!     Original    08/2015
!!
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_xios,       ONLY     : yxios_domain, lxios_def_closed, coutput_default
USE modd_surf_par,   ONLY     : xundef
USE modd_surf_atm_n, ONLY     : surf_atm_t
USE yomhook    , ONLY         : lhook,   dr_hook
USE parkind1   , ONLY         : jprb
!
#ifdef WXIOS
USE xios, ONLY                : xios_field, xios_fieldgroup, xios_file, xios_get_handle,&
     xios_add_child, xios_set_attr, xios_is_defined_field_attr, xios_set_field_attr,    &
     xios_get_file_attr, xios_is_valid_file, xios_is_valid_field, xios_is_valid_axis,   &
     xios_is_defined_file_attr
#endif
!
USE modi_sfx_xios_check_field_2d
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!   Arguments
!
TYPE(surf_atm_t)  , INTENT(INOUT) :: U
 CHARACTER(LEN=*)      ,INTENT(IN) :: HREC     ! name of the field to check
 CHARACTER(LEN=100)    ,INTENT(IN) :: HCOMMENT ! Comment string
LOGICAL               ,INTENT(OUT):: OWRITE   ! TRUE if no issue re. Xios for this field
REAL,DIMENSION(:)     ,INTENT(IN) , OPTIONAL :: PFIELD1  ! value
REAL,DIMENSION(:,:)   ,INTENT(IN) , OPTIONAL :: PFIELD2  ! value
REAL,DIMENSION(:,:,:) ,INTENT(IN) , OPTIONAL :: PFIELD3  ! value
 CHARACTER(LEN=*)      ,INTENT(IN) , OPTIONAL :: HAXIS    ! name of the additional axis
!
!  Local variables
!
LOGICAL            :: LISDEF, LLWRITE
INTEGER            :: IPO,IPF  
INTEGER            :: KSIZE  
REAL(KIND=JPRB)    :: ZHOOK_HANDLE
!
#ifdef WXIOS
TYPE(xios_field) :: field_hdl, other_field_hdl
TYPE(xios_fieldgroup) :: fieldgroup_hdl
TYPE(xios_file) :: file_hdl
#endif
!
IF (lhook) CALL dr_hook('SFX_XIOS_CHECK_FIELD',0,zhook_handle)
!
#ifdef WXIOS
!
owrite=.true.
!
! ----------------------------------------------------------------------
! If field is 3D , just give up 
! ----------------------------------------------------------------------
!
IF (PRESENT(pfield3)) THEN 
   CALL abor1_sfx('THIS XIOS INTERFACE CANNOT YET HANDLE 2 AXES IN ADDITION TO HORIZONTAL SPACE AXES')
ENDIF
!
! ----------------------------------------------------------------------
!  Check consistency between field size and current domain size
! ----------------------------------------------------------------------
!
IF ((PRESENT(pfield1)) .OR. (PRESENT(pfield2)) .OR. (PRESENT(pfield3)) ) THEN 
   IF (PRESENT(pfield1)) ksize=SIZE(pfield1)
   IF (PRESENT(pfield2)) ksize=SIZE(pfield2,1)
   IF (PRESENT(pfield3)) ksize=SIZE(pfield3,1)
   IF ((yxios_domain=='FULL'  ) .AND. (ksize /= u%NSIZE_FULL  )) owrite=.false.
   IF ((yxios_domain=='NATURE') .AND. (ksize /= u%NSIZE_NATURE)) owrite=.false.
   IF ((yxios_domain=='SEA   ') .AND. (ksize /= u%NSIZE_SEA   )) owrite=.false.
   IF ((yxios_domain=='WATER ') .AND. (ksize /= u%NSIZE_WATER )) owrite=.false.
   IF ((yxios_domain=='TOWN  ') .AND. (ksize /= u%NSIZE_TOWN  )) owrite=.false.
   IF (.NOT. owrite) THEN 
      IF (.NOT. lxios_def_closed) THEN 
         CALL abor1_sfx('SFX_XIOS_CHECK_FIELD : Inconsistent size for field '//hrec//' on domain '//yxios_domain)
      ENDIF
      IF (lhook) CALL dr_hook('SFX_XIOS_CHECK_FIELD',1,zhook_handle)
      RETURN
   ENDIF
ENDIF
!
! ----------------------------------------------------------------------
!   If XIOS init phase is over, just check if field is known to XIOS 
!   and returns
! ----------------------------------------------------------------------
!
IF (lxios_def_closed) THEN
!$OMP SINGLE
   owrite=xios_is_valid_field(hrec)
!$OMP END SINGLE
   IF (lhook) CALL dr_hook('SFX_XIOS_CHECK_FIELD',1,zhook_handle)
   RETURN
ENDIF
!
!$OMP SINGLE
!
! ----------------------------------------------------------------------
!  We are still in the XIOS init phase =>  Define field if necessary 
! ----------------------------------------------------------------------
!
owrite=.false.
IF (.NOT. xios_is_valid_field(hrec))  THEN
   CALL xios_get_handle("field_definition",fieldgroup_hdl)
   CALL xios_add_child(fieldgroup_hdl,field_hdl,hrec)
   ! Inherit default values from 'default_field' 
   IF (.NOT. xios_is_valid_field("default_field")) &
        CALL abor1_sfx('sfx_xios_check_field:cannot output field '//hrec//' : no default_field is defined')
   ! With XIOS2, next call creates an issue
   ! CALL XIOS_SET_ATTR(field_hdl,field_ref="default_field",name=HREC)
   CALL xios_set_attr(field_hdl,name=hrec)
   !
ELSE 
   CALL xios_get_handle(hrec,field_hdl)
ENDIF
!
! ----------------------------------------------------------------------
! If field enabling is not defined, set it to TRUE
! ----------------------------------------------------------------------
!
 CALL xios_is_defined_field_attr(hrec,enabled=lisdef) 
IF ( .NOT. lisdef ) CALL xios_set_field_attr(hrec, enabled=.true.)
!
! ----------------------------------------------------------------------
! If field attribute 'domain' is not defined, set it
! ----------------------------------------------------------------------
!
 CALL xios_is_defined_field_attr(hrec,domain_ref=lisdef) 
IF ( .NOT. lisdef ) THEN 
   CALL xios_set_field_attr(hrec, domain_ref=yxios_domain)
ENDIF
!
! ----------------------------------------------------------------------
!  2d fields are a special case, and may lead to (implicit) recursion
! ----------------------------------------------------------------------
!
IF (PRESENT(pfield2)) THEN 
   IF (PRESENT(haxis)) THEN 
      CALL sfx_xios_check_field_2d(u, hrec, hcomment, owrite, pfield2, haxis)
   ELSE
      CALL sfx_xios_check_field_2d(u, hrec, hcomment, owrite, pfield2)
   ENDIF
ENDIF
!
! ----------------------------------------------------------------------
! If NetCDF variable name is not defined , set it
! ----------------------------------------------------------------------
!
 CALL xios_is_defined_field_attr(hrec,name=lisdef) 
IF ( .NOT. lisdef ) THEN 
   CALL xios_set_field_attr(hrec, name=hrec)
ENDIF
!
! ----------------------------------------------------------------------
! If field attribute 'long_name' is not defined or empty, set it 
! ----------------------------------------------------------------------
!
 CALL xios_is_defined_field_attr(hrec,long_name=lisdef) 
IF ( .NOT. lisdef .AND. (trim(hcomment) /= '') ) THEN 
   CALL xios_set_field_attr(hrec,long_name=trim(hcomment))
ENDIF
!
!
! ------------------------------------------------------------------------
! If field attribute 'units' is not defined or empty, try to guess a value 
! from HCOMMENT (using rightmost string between parenthesis)
! ------------------------------------------------------------------------
!
 CALL xios_is_defined_field_attr(hrec,unit=lisdef)  
IF ( .NOT. lisdef ) THEN 
   ipo=index(hcomment,"(",.true.)
   ipf=index(hcomment,")",.true.)
   IF ( (ipo > 0) .AND. (ipf>ipo+1) ) THEN
      CALL xios_set_field_attr(hrec,unit=hcomment(ipo+1:ipf-1))
   ENDIF
ENDIF
!

! ----------------------------------------------------------------------
! Set default value to Surfex's one
! ----------------------------------------------------------------------
!
 CALL xios_set_field_attr(hrec,default_value=xundef)
!
! ----------------------------------------------------------------------
! If file 'default_ouput is enabled, add field to it
! ----------------------------------------------------------------------
!
IF ( xios_is_valid_file(coutput_default)) THEN 
   CALL xios_get_handle(coutput_default,file_hdl)
   CALL xios_is_defined_file_attr(coutput_default,enabled=lisdef) 
   IF (lisdef ) CALL xios_get_file_attr(coutput_default,enabled=lisdef)
   IF (lisdef) THEN 
      CALL xios_add_child(file_hdl,field_hdl)
      CALL xios_set_attr(field_hdl,field_ref=hrec)
   ENDIF
ELSE
   CALL abor1_sfx('sfx_xios_check_field : cannot output field '//hrec//' : no default_output file is defined')
ENDIF
!
!
!$OMP END SINGLE
#else
owrite=.false.
#endif
!
IF (lhook) CALL dr_hook('SFX_XIOS_CHECK_FIELD',1,zhook_handle)
! ----------------------------------------------------------------------
!
END SUBROUTINE sfx_xios_check_field