pgd_teb.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE pgd_teb (DTCO, UG, U, USS, TOP, BOP, TG, BDD, DTT, DTB, &
                          GDO, GDK, DTGD, GDIR, GRO, GRS, GRK, DTGR, HPROGRAM)
!     ##############################################################
!
!!**** *PGD_TEB* monitor for averaging and interpolations of TEB physiographic fields
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    10/12/97
!!    A. Lemonsu      05/2009         Key for garden option
!!    G. Pigeon     /09/12: WALL, ROOF, FLOOR, MASS LAYER default to 5
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_surfex_mpi, ONLY : nrank, npio
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_sso_n, ONLY : sso_t
!
USE modd_teb_option_n, ONLY : teb_options_t
USE modd_bem_option_n, ONLY : bem_options_t
USE modd_sfx_grid_n, ONLY : grid_t
USE modd_bld_description_n, ONLY : bld_desc_t
USE modd_data_teb_n, ONLY : data_teb_t
USE modd_data_bem_n, ONLY : data_bem_t
!
USE modd_isba_options_n, ONLY : isba_options_t
USE modd_isba_n, ONLY : isba_s_t, isba_k_t
USE modd_data_isba_n, ONLY : data_isba_t
USE modd_teb_irrig_n, ONLY : teb_irrig_t
!
USE modd_data_cover_par, ONLY : jpcover
!
USE modi_get_surf_size_n
USE modi_pack_pgd
USE modi_pgd_teb_par
USE modi_pgd_teb_veg
USE modi_get_luout
USE modi_read_nam_pgd_teb
USE modi_test_nam_var_surf
USE modi_pgd_bem_par
USE modi_abor1_sfx
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_write_cover_tex_teb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(sso_t), INTENT(INOUT) :: USS
TYPE(teb_options_t), INTENT(INOUT) :: TOP
TYPE(bem_options_t), INTENT(INOUT) :: BOP
TYPE(grid_t), INTENT(INOUT) :: TG
TYPE(bld_desc_t), INTENT(INOUT) :: BDD
TYPE(data_teb_t), INTENT(INOUT) :: DTT
TYPE(data_bem_t), INTENT(INOUT) :: DTB
!
TYPE(isba_options_t), INTENT(INOUT) :: GDO
TYPE(isba_k_t), INTENT(INOUT) :: GDK
TYPE(data_isba_t), INTENT(INOUT) :: DTGD
TYPE(teb_irrig_t), INTENT(INOUT) :: GDIR
TYPE(isba_options_t), INTENT(INOUT) :: GRO
TYPE(isba_s_t), INTENT(INOUT) :: GRS
TYPE(isba_k_t), INTENT(INOUT) :: GRK
TYPE(data_isba_t), INTENT(INOUT) :: DTGR
!
 CHARACTER(LEN=6), INTENT(IN)  :: HPROGRAM   ! Type of program
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER         :: ILUOUT    ! output listing logical unit
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
!*    1.      Initializations of defaults
!             ---------------------------
!
IF (lhook) CALL dr_hook('PGD_TEB',0,zhook_handle)
 CALL get_luout(hprogram,iluout)

top%NROOF_LAYER  = 5
top%NROAD_LAYER  = 5
top%NWALL_LAYER  = 5
bop%NFLOOR_LAYER = 5
!
!-------------------------------------------------------------------------------
!
!*    2.      Reading of namelist
!             -------------------
!
 CALL read_nam_pgd_teb(hprogram,top%NTEB_PATCH,top%CBEM,bop%CCOOL_COIL,  &
                       bop%CHEAT_COIL,bop%LAUTOSIZE,top%NROAD_LAYER,     &
                       top%NROOF_LAYER,top%NWALL_LAYER,bop%NFLOOR_LAYER, &
                       top%LGREENROOF,top%LHYDRO,top%LSOLAR_PANEL     )
!
!-------------------------------------------------------------------------------
!
!*    3.      Coherence of options
!             --------------------
!
 CALL test_nam_var_surf(iluout,'CBLD',top%CBEM,'DEF','BEM ')
 CALL test_nam_var_surf(iluout,'CCOOL_COIL',bop%CCOOL_COIL,'IDEAL ','DXCOIL')
 CALL test_nam_var_surf(iluout,'CHEAT_COIL',bop%CHEAT_COIL,'IDEAL ','FINCAP')
!
IF (.NOT. u%LGARDEN) THEN
  IF (top%LGREENROOF) CALL abor1_sfx('ERROR: You cannot activate LGREENROOF if LGARDEN is FALSE')
  IF (top%LHYDRO    ) CALL abor1_sfx('ERROR: You cannot activate LHYDRO     if LGARDEN is FALSE')
ENDIF
!
!-------------------------------------------------------------------------------
!
!*    4.      Number of points and packing
!             ----------------------------
!
 CALL get_surf_size_n(dtco, u, 'TOWN  ',tg%NDIM)
!
ALLOCATE(top%LCOVER     (jpcover))
ALLOCATE(top%XZS        (tg%NDIM))
ALLOCATE(tg%XLAT       (tg%NDIM))
ALLOCATE(tg%XLON       (tg%NDIM))
ALLOCATE(tg%XMESH_SIZE (tg%NDIM))
!
 CALL pack_pgd(dtco, u, hprogram, 'TOWN  ', tg, top%LCOVER, top%XCOVER, top%XZS  )  
!
!-------------------------------------------------------------------------------
!
!*    5.      TEB specific fields
!             -------------------
!
top%LECOCLIMAP = u%LECOCLIMAP
 CALL pgd_teb_par(dtco, ug, u, uss, bdd, dtt, tg%NDIM, &
                  hprogram,u%LGARDEN,top%LGREENROOF,top%CBLD_ATYPE)
!
!-------------------------------------------------------------------------------
!
!*    6.      Prints of cover parameters in a tex file
!             ----------------------------------------
!
IF (u%LECOCLIMAP .AND. nrank==npio) CALL write_cover_tex_teb
!
!
!-------------------------------------------------------------------------------
!
!*    7.      Case of urban green areas (and hydrology)
!             -----------------------------------------
!
top%LGARDEN       = u%LGARDEN
!
IF (top%LGARDEN) CALL pgd_teb_veg(dtco, ug, u, uss, gdo, gdk, dtgd, gdir, &
                              gro, grs, grk, dtgr, top, tg%NDIM, hprogram)
!
!-------------------------------------------------------------------------------
!
!*    8.      Case of Building Energy Model
!             -----------------------------
!
IF (top%CBEM .EQ. 'BEM') CALL pgd_bem_par(dtco, ug, u, uss, dtb, tg%NDIM, &
                                          hprogram,bop%LAUTOSIZE)
!
IF (lhook) CALL dr_hook('PGD_TEB',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE pgd_teb