diag_inline_flaken.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE diag_inline_flake_n (DGO, D, DC, F, &
                                       PTSTEP, PTA, PQA, PPA, PPS, PRHOA, PZONA,  &
                                       PMERA, PHT, PHW, PRAIN, PSNOW,             &
                                       PCD, PCDN, PCH, PRI, PHU,                  &
                                       PZ0H, PQSAT, PSFTH, PSFTQ, PSFZON, PSFMER, &
                                       PDIR_SW, PSCA_SW, PLW, PDIR_ALB, PSCA_ALB, &
                                       PLE, PLEI, PSUBL, PLWUP, PALB, PSWE        )  
!     ###############################################################################
!
!!****  *DIAG_INLINE_FLAKE_n * - computes diagnostics during FLAKE time-step
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      S. Riette    06/2009 CLS_2M becomes CLS_TQ, CLS_TQ and CLS_WIND have one
!!                           more argument (height of diagnostic)
!!      P. Le Moigne 04/2013 : Accumulated diagnostics
!!                             Coupling for ESM
!!------------------------------------------------------------------
!

!
!
!
USE modd_diag_n, ONLY : diag_t, diag_options_t
USE modd_flake_n, ONLY : flake_t
!
USE modd_csts,         ONLY : xtt
USE modd_surf_par,     ONLY : xundef
USE modd_sfx_oasis,    ONLY : lcpl_lake
!
USE modi_cls_tq
USE modi_cls_wind
USE modi_diag_surf_budget_flake
USE modi_diag_surf_budgetc
USE modi_diag_cpl_esm_flake
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(diag_options_t), INTENT(IN) :: DGO
TYPE(diag_t), INTENT(INOUT) :: D
TYPE(diag_t), INTENT(INOUT) :: DC
TYPE(flake_t), INTENT(INOUT) :: F
!
REAL              , INTENT(IN) :: PTSTEP ! atmospheric time-step (s)
REAL, DIMENSION(:), INTENT(IN) :: PTA    ! atmospheric temperature
REAL, DIMENSION(:), INTENT(IN) :: PQA    ! atmospheric specific humidity
REAL, DIMENSION(:), INTENT(IN) :: PPA    ! atmospheric level pressure
REAL, DIMENSION(:), INTENT(IN) :: PPS    ! surface pressure
REAL, DIMENSION(:), INTENT(IN) :: PRHOA  ! air density
REAL, DIMENSION(:), INTENT(IN) :: PZONA  ! zonal wind
REAL, DIMENSION(:), INTENT(IN) :: PMERA  ! meridian wind
REAL, DIMENSION(:), INTENT(IN) :: PHT    ! atmospheric level height
REAL, DIMENSION(:), INTENT(IN) :: PHW    ! atmospheric level height for wind
REAL, DIMENSION(:), INTENT(IN) :: PRAIN  ! Rainfall (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: PSNOW  ! Snowfall (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: PCD    ! drag coefficient for momentum
REAL, DIMENSION(:), INTENT(IN) :: PCDN   ! neutral drag coefficient
REAL, DIMENSION(:), INTENT(IN) :: PCH    ! drag coefficient for heat
REAL, DIMENSION(:), INTENT(IN) :: PRI    ! Richardson number
REAL, DIMENSION(:), INTENT(IN) :: PHU    ! near-surface humidity
REAL, DIMENSION(:), INTENT(IN) :: PZ0H   ! roughness length for heat
REAL, DIMENSION(:), INTENT(IN) :: PQSAT  ! humidity at saturation
REAL, DIMENSION(:), INTENT(IN) :: PSFZON ! zonal friction
REAL, DIMENSION(:), INTENT(IN) :: PSFMER ! meridian friction
REAL, DIMENSION(:), INTENT(IN) :: PSFTH  ! heat flux  (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: PSFTQ  ! water flux (kg/m2/s)
REAL, DIMENSION(:,:),INTENT(IN):: PDIR_SW   ! direct  solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:,:),INTENT(IN):: PSCA_SW   ! diffuse solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: PLW       ! longwave radiation (on horizontal surf.) (W/m2)
REAL, DIMENSION(:,:),INTENT(IN):: PDIR_ALB  ! direct albedo for each spectral band  (-)
REAL, DIMENSION(:,:),INTENT(IN):: PSCA_ALB  ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(:), INTENT(IN) :: PLE       ! total latent heat flux (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: PLEI      ! sublimation heat flux (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: PSUBL     ! sublimation (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: PLWUP     ! upward longwave radiation (W/m2)
!
REAL, DIMENSION(:), INTENT(IN) :: PALB      ! Flake total albedo
REAL, DIMENSION(:), INTENT(IN) :: PSWE      ! Flake snow water equivalent (kg.m-2)
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PTA)) :: ZH
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('DIAG_INLINE_FLAKE_N',0,zhook_handle)
!
d%XTS(:) = f%XTS(:)
!
IF (.NOT. f%LSBL) THEN
!
  IF (dgo%N2M==2) THEN
    zh(:)=2.          
    CALL cls_tq(pta, pqa, ppa, pps, pht, pcd, pch, pri, &
                  f%XTS, phu, pz0h, zh, d%XT2M, d%XQ2M, d%XHU2M )  
    zh(:)=10.                
    CALL cls_wind(pzona, pmera, phw, pcd, pcdn, pri, zh, d%XZON10M, d%XMER10M )  
  END IF
!
  IF (dgo%N2M>=1) THEN
    !
    d%XT2M_MIN(:) = min(d%XT2M_MIN(:),d%XT2M(:))
    d%XT2M_MAX(:) = max(d%XT2M_MAX(:),d%XT2M(:))
    !
    d%XHU2M_MIN(:) = min(d%XHU2M_MIN(:),d%XHU2M(:))
    d%XHU2M_MAX(:) = max(d%XHU2M_MAX(:),d%XHU2M(:))
    !
    d%XWIND10M(:) = sqrt(d%XZON10M(:)**2+d%XMER10M(:)**2)
    d%XWIND10M_MAX(:) = max(d%XWIND10M_MAX(:),d%XWIND10M(:))
    !
    !* Richardson number
    d%XRI = pri
    !
  ENDIF
!
ELSE
  !
  IF (dgo%N2M>=1) THEN
    d%XT2M    = xundef
    d%XQ2M    = xundef
    d%XHU2M   = xundef
    d%XZON10M = xundef
    d%XMER10M = xundef
    d%XRI     = pri
  ENDIF
ENDIF
!
IF (dgo%LSURF_BUDGET.OR.dgo%LSURF_BUDGETC) THEN
  !
  d%XLE  (:) = ple(:)
  d%XLEI (:) = plei(:)
  d%XEVAP(:) = psftq(:)
  d%XSUBL(:) = psubl(:)
  d%XALBT(:) = palb(:)
  d%XSWE (:) = pswe(:)
  !
  CALL  diag_surf_budget_flake (d, prhoa, psfth, pdir_sw, psca_sw, plw, &
                                pdir_alb, psca_alb, plwup, psfzon, psfmer )  
  !
END IF
!
IF(dgo%LSURF_BUDGETC)THEN
  CALL diag_surf_budgetc(d, dc, ptstep, .true.)  
ENDIF
!
IF (dgo%LCOEF) THEN
  !
  !* Transfer coefficients
  !
  d%XCD = pcd
  d%XCH = pch
  d%XCE = pch
  !
  !* Roughness lengths
  !
  d%XZ0  = f%XZ0
  d%XZ0H = pz0h
  !
END IF
!
IF (dgo%LSURF_VARS) THEN
  !
  !* Humidity at saturation
  !
  d%XQS = pqsat
  !
END IF
!
! Diag for Earth System Model coupling
!
IF (lcpl_lake) THEN
!
  CALL diag_cpl_esm_flake(f,ptstep,prain,psnow,psftq)
! 
ENDIF
!
IF (lhook) CALL dr_hook('DIAG_INLINE_FLAKE_N',1,zhook_handle)
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_inline_flake_n