diag_surf_budget_flake.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE diag_surf_budget_flake (D, PRHOA, PSFTH, PDIR_SW, PSCA_SW, PLW,  &
                                          PDIR_ALB, PSCA_ALB, PLWUP, PSFZON, PSFMER  )  
!     ###############################################################################
!
!!****  *DIAG_SURF_BUDGET_FLAKE * - Computes diagnostics over lake
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     B. Decharme 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    04/2013
!!------------------------------------------------------------------
!
USE modd_diag_n, ONLY : diag_t
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(diag_t), INTENT(INOUT) :: D
!
REAL, DIMENSION(:), INTENT(IN) :: PRHOA     ! air density
REAL, DIMENSION(:), INTENT(IN) :: PSFTH     ! heat flux
REAL, DIMENSION(:,:),INTENT(IN):: PDIR_SW   ! direct  solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:,:),INTENT(IN):: PSCA_SW   ! diffuse solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: PLW       ! longwave radiation (on horizontal surf.)
REAL, DIMENSION(:), INTENT(IN) :: PLWUP     ! upward longwave radiation             (W/m2)
REAL, DIMENSION(:,:),INTENT(IN):: PDIR_ALB  ! direct albedo for each spectral band  (-)
REAL, DIMENSION(:,:),INTENT(IN):: PSCA_ALB  ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(:), INTENT(IN) :: PSFZON    ! zonal friction
REAL, DIMENSION(:), INTENT(IN) :: PSFMER    ! meridional friction
!
!*      0.2    declarations of local variables
!
INTEGER                      :: ISWB ! number of SW bands
INTEGER                      :: JSWB ! loop counter on number of SW bands
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------------
!
!
IF (lhook) CALL dr_hook('DIAG_SURF_BUDGET_FLAKE',0,zhook_handle)
iswb = SIZE(pdir_sw,2)
! 
!* total incoming and outgoing SW
!
DO jswb=1,iswb
  d%XSWBD(:,jswb) = pdir_sw(:,jswb)                    + psca_sw(:,jswb)
  d%XSWBU(:,jswb) = pdir_sw(:,jswb) * pdir_alb(:,jswb) + psca_sw(:,jswb) * psca_alb(:,jswb) 
ENDDO
!
d%XSWD(:) = 0.
d%XSWU(:) = 0.
DO jswb=1,iswb
   d%XSWD(:)=d%XSWD(:)+d%XSWBD(:,jswb)
   d%XSWU(:)=d%XSWU(:)+d%XSWBU(:,jswb)
ENDDO
!
!*incoming outgoing LW
!
d%XLWD(:)=plw(:)
d%XLWU(:)=plwup(:)
!
!* net radiation
!
d%XRN    =   d%XSWD(:) - d%XSWU(:) + d%XLWD(:) - d%XLWU(:)
!
!* sensible heat flux
!
d%XH     = psfth(:)
!
!* storage flux
!
d%XGFLUX = d%XRN - d%XH - d%XLE
!
!* wind stress
!
d%XFMU = psfzon
!
d%XFMV = psfmer
IF (lhook) CALL dr_hook('DIAG_SURF_BUDGET_FLAKE',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_surf_budget_flake