zoom_pgd_isba.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###########################################################
      SUBROUTINE zoom_pgd_isba (CHI, DTCO, DTI, IG, I, UG, U, USS, &
                                hprogram,hinifile,hinifiletype,hfile,hfiletype,oecoclimap)
!     ###########################################################

!!
!!    PURPOSE
!!    -------
!!   This program prepares the physiographic data fields.
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson                   Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original     13/10/03
!!    B. Decharme      2008  XWDRAIN
!!    M.Tomasini    17/04/12  Add interpolation for ISBA variables (MODD_DATA_ISBA_n)
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
!
!
!
!
USE modd_ch_isba_n, ONLY : ch_isba_t
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_data_isba_n, ONLY : data_isba_t
USE modd_isba_grid_n, ONLY : isba_grid_t
USE modd_isba_n, ONLY : isba_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
!
USE modd_surf_par, ONLY : xundef
USE modd_data_cover_par, ONLY : jpcover
USE modd_isba_par,    ONLY : xoptimgrid
USE modd_prep,           ONLY : cingrid_type, cinterp_type
!
USE modi_get_luout
USE modi_open_aux_io_surf
USE modi_read_surf
USE modi_close_aux_io_surf
USE modi_get_surf_size_n
USE modi_pack_pgd
USE modi_zoom_pgd_isba_full
USE modi_get_aos_n
USE modi_get_sso_n
USE modi_pack_pgd_isba
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of dummy arguments
!            ------------------------------
!
!
TYPE(ch_isba_t), INTENT(INOUT) :: chi
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(data_isba_t), INTENT(INOUT) :: dti
TYPE(isba_grid_t), INTENT(INOUT) :: ig
TYPE(isba_t), INTENT(INOUT) :: i
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
!
 CHARACTER(LEN=6),     INTENT(IN)  :: hprogram    ! program calling
 CHARACTER(LEN=28),    INTENT(IN)  :: hinifile    ! input atmospheric file name
 CHARACTER(LEN=6),     INTENT(IN)  :: hinifiletype! input atmospheric file type
 CHARACTER(LEN=28),    INTENT(IN)  :: hfile       ! output file name
 CHARACTER(LEN=6),     INTENT(IN)  :: hfiletype   ! output file type
LOGICAL,              INTENT(IN)  :: oecoclimap  ! flag to use ecoclimap
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER :: iversion, ibugfix
INTEGER :: iresp
INTEGER :: iluout
INTEGER :: il      ! total 1D dimension (output grid, total surface)
INTEGER :: ilu     ! total 1D dimension (output grid, ISBA points only)
REAL, DIMENSION(:), ALLOCATABLE   :: zaosip    ! A/S i+ on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: zaosim    ! A/S i- on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: zaosjp    ! A/S j+ on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: zaosjm    ! A/S j- on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: zho2ip    ! h/2 i+ on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: zho2im    ! h/2 i- on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: zho2jp    ! h/2 j+ on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: zho2jm    ! h/2 j- on all surface points
REAL, DIMENSION(:), ALLOCATABLE   :: zsso_slope! subgrid slope on all surface points
REAL(KIND=JPRB)                   :: zhook_handle
INTEGER                           :: isize_lmeb_patch
!------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('ZOOM_PGD_ISBA',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
!*      1.     Preparation of IO for reading in the file
!              -----------------------------------------
!
!* Note that all points are read, even those without physical meaning.
!  These points will not be used during the horizontal interpolation step.
!  Their value must be defined as XUNDEF.
!
 CALL open_aux_io_surf(&
                       hinifile,hinifiletype,'FULL  ')
!
 CALL read_surf(&
                hinifiletype,'VERSION',iversion,iresp)
 CALL read_surf(&
                hinifiletype,'BUG',ibugfix,iresp) 
 CALL read_surf(&
                hinifiletype,'PATCH_NUMBER',i%NPATCH,iresp)
!
ALLOCATE(i%LMEB_PATCH(i%NPATCH))
!
IF (iversion>=8) THEN
!
   CALL read_surf(hinifiletype,'MEB_PATCH',i%LMEB_PATCH(:),iresp,hdir='-')!
   isize_lmeb_patch = count(i%LMEB_PATCH(:))
!
   IF (isize_lmeb_patch>0)THEN
      CALL read_surf(hinifiletype,'FORC_MEASURE',i%LFORC_MEASURE,iresp)
      CALL read_surf(hinifiletype,'MEB_LITTER',i%LMEB_LITTER,iresp)
   ELSE      
      i%LFORC_MEASURE=.false.
      i%LMEB_LITTER  =.false.           
   ENDIF
!
ELSE
   i%LMEB_PATCH(:)=.false.
   i%LFORC_MEASURE=.false.
   i%LMEB_LITTER  =.false.
ENDIF


 CALL read_surf(&
                hinifiletype,'GROUND_LAYER',i%NGROUND_LAYER,iresp)
 CALL read_surf(&
                hinifiletype,'ISBA',i%CISBA,iresp)
IF (iversion >= 7) THEN
  CALL read_surf(&
                hinifiletype,'PEDOTF',i%CPEDOTF,iresp)
ELSE
  i%CPEDOTF = 'CH78'
ENDIF
 CALL read_surf(&
                hinifiletype,'PHOTO',i%CPHOTO,iresp)
!
IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=2) THEN
  !
  CALL read_surf(&
                hinifiletype,'TR_ML',i%LTR_ML,iresp)
  !
ELSE 
  i%LTR_ML = .false.
ENDIF
!
IF(i%CISBA=='DIF') THEN
  ALLOCATE(i%XSOILGRID(i%NGROUND_LAYER))
  i%XSOILGRID=xundef
  IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=2) THEN
    CALL read_surf(&
                hinifiletype,'SOILGRID',i%XSOILGRID,iresp,hdir='-')
  ELSE
    i%XSOILGRID(1:i%NGROUND_LAYER)=xoptimgrid(1:i%NGROUND_LAYER)
  ENDIF
ELSE
  ALLOCATE(i%XSOILGRID(0))
ENDIF
!
!* number of biomass pools
!
IF (iversion>=6) THEN
  CALL read_surf(&
                hprogram,'NBIOMASS',i%NNBIOMASS,iresp)
ELSE
  SELECT CASE (i%CPHOTO)
    CASE ('AGS','LAI','AST','LST')
      i%NNBIOMASS = 1
    CASE ('NIT')
      i%NNBIOMASS = 3
    CASE ('NCB')
      i%NNBIOMASS = 6
  END SELECT
ENDIF
!
 CALL close_aux_io_surf(hinifile,hinifiletype)
!
!------------------------------------------------------------------------------
i%LECOCLIMAP = oecoclimap
!
!-------------------------------------------------------------------------------
!
!*    7.      Number of points and packing of general fields
!             ----------------------------------------------
!
!
 CALL get_surf_size_n(dtco, u, &
                      'NATURE',ilu)
!
ALLOCATE(i%LCOVER     (jpcover))
ALLOCATE(i%XZS        (ilu))
ALLOCATE(ig%XLAT       (ilu))
ALLOCATE(ig%XLON       (ilu))
ALLOCATE(ig%XMESH_SIZE (ilu))
ALLOCATE(i%XZ0EFFJPDIR(ilu))
!
 CALL pack_pgd(dtco, u, &
               hprogram, 'NATURE',                    &
                ig%CGRID,  ig%XGRID_PAR,                     &
                i%LCOVER, i%XCOVER, i%XZS,                   &
                ig%XLAT, ig%XLON, ig%XMESH_SIZE, i%XZ0EFFJPDIR    )  
!
!------------------------------------------------------------------------------
!
!*      3.     Reading of sand, clay, runoffb, wdrain and interpolations
!              --------------------------------------------------
!
ALLOCATE(i%XSAND(ilu,i%NGROUND_LAYER))
ALLOCATE(i%XCLAY(ilu,i%NGROUND_LAYER))
ALLOCATE(i%XRUNOFFB(ilu))
ALLOCATE(i%XWDRAIN (ilu))
 CALL zoom_pgd_isba_full(chi, dtco, dti, ig, i, ug, u, &
                         hprogram,hinifile,hinifiletype)
!
!-------------------------------------------------------------------------------
!
!*    8.      Packing of ISBA specific fields
!             -------------------------------
!
 CALL get_surf_size_n(dtco, u, &
                      'FULL  ',il)
!
ALLOCATE(zaosip(il))
ALLOCATE(zaosim(il))
ALLOCATE(zaosjp(il))
ALLOCATE(zaosjm(il))
ALLOCATE(zho2ip(il))
ALLOCATE(zho2im(il))
ALLOCATE(zho2jp(il))
ALLOCATE(zho2jm(il))
ALLOCATE(zsso_slope(il))

 CALL get_aos_n(uss, &
                hprogram,il,zaosip,zaosim,zaosjp,zaosjm,zho2ip,zho2im,zho2jp,zho2jm)
 CALL get_sso_n(uss, &
                hprogram,il,zsso_slope)

 CALL pack_pgd_isba(dtco, ig, i, u, &
                    hprogram,                                    &
                     zaosip, zaosim, zaosjp, zaosjm,              &
                     zho2ip, zho2im, zho2jp, zho2jm,              &
                     zsso_slope                                   )  
!
DEALLOCATE(zaosip)
DEALLOCATE(zaosim)
DEALLOCATE(zaosjp)
DEALLOCATE(zaosjm)
DEALLOCATE(zho2ip)
DEALLOCATE(zho2im)
DEALLOCATE(zho2jp)
DEALLOCATE(zho2jm)
DEALLOCATE(zsso_slope)
IF (lhook) CALL dr_hook('ZOOM_PGD_ISBA',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE zoom_pgd_isba