writesurf_tebn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE writesurf_teb_n (DGU, U, TM, GDM, GRM, &
                                  hprogram,kpatch,hwrite)
!     ####################################
!
!!****  *WRITE_TEB_n* - writes TEB fields
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
!
!
!
!
!
USE modd_diag_surf_atm_n, ONLY : diag_surf_atm_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surfex_n, ONLY : teb_model_t
USE modd_surfex_n, ONLY : teb_garden_model_t
USE modd_surfex_n, ONLY : teb_greenroof_model_t
!
USE modi_write_surf
USE modi_writesurf_gr_snow
USE modi_writesurf_teb_garden_n
USE modi_writesurf_teb_greenroof_n
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!RJ #ifdef SFX_MPI
!RJ INCLUDE "mpif.h"
!RJ #endif
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
!
TYPE(diag_surf_atm_t), INTENT(INOUT) :: dgu
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(teb_model_t), INTENT(INOUT) :: tm
TYPE(teb_garden_model_t), INTENT(INOUT) :: gdm
TYPE(teb_greenroof_model_t), INTENT(INOUT) :: grm
!
 CHARACTER(LEN=6),  INTENT(IN)  :: hprogram ! program calling
INTEGER,           INTENT(IN)  :: kpatch   ! current TEB patch
 CHARACTER(LEN=3),    INTENT(IN)  :: hwrite    ! 'PREP' : does not write SBL XUNDEF fields
!                                             ! 'ALL' : all fields are written
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER           :: iresp           ! IRESP  : return-code if a problem appears
 CHARACTER(LEN=12) :: yrecfm         ! Name of the article to be read
 CHARACTER(LEN=100):: ycomment       ! Comment string
 CHARACTER(LEN=3)  :: ypatch         ! Patch identificator
 CHARACTER(LEN=7)  :: ydir           ! Direction identificator
 CHARACTER(LEN=100):: ystring        ! Comment string
!
INTEGER :: jlayer ! loop on surface layers
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('WRITESURF_TEB_N',0,zhook_handle)
!
ypatch='   '
IF (tm%TOP%NTEB_PATCH>1) WRITE(ypatch,fmt='(A,I1,A)') 'T',kpatch,'_'
!
!
!*       2.     Option for road orientation:
!               ---------------------------
!
ycomment='Option for Road orientation in TEB scheme'
 CALL write_surf(dgu, u, &
                 hprogram,'ROAD_DIR',tm%TOP%CROAD_DIR,iresp,ycomment)
ycomment='Option for Wall representation in TEB scheme'
 CALL write_surf(dgu, u, &
                 hprogram,'WALL_OPT',tm%TOP%CWALL_OPT,iresp,ycomment)
!
!*       3.     Prognostic fields:
!               -----------------
!
!* roof temperatures
!

DO jlayer=1,tm%TOP%NROOF_LAYER
  WRITE(yrecfm,'(A3,A5,I1.1,A1)') ypatch,'TROOF',jlayer,' '
  WRITE(ycomment,'(A9,I1.1,A4)') 'X_Y_TROOF',jlayer,' (K)'
  yrecfm=adjustl(yrecfm)
 CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%T%CUR%XT_ROOF(:,jlayer),iresp,hcomment=ycomment)
END DO

!
!* roof water content
!

yrecfm=ypatch//'WS_ROOF'
yrecfm=adjustl(yrecfm)
ycomment='WS_ROOF (kg/m2)'
 CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%T%CUR%XWS_ROOF(:),iresp,hcomment=ycomment)
!
!* road temperatures
!

DO jlayer=1,tm%TOP%NROAD_LAYER
  WRITE(yrecfm,'(A3,A5,I1.1,A1)') ypatch,'TROAD',jlayer,' '
  yrecfm=adjustl(yrecfm)
  IF (tm%TOP%CROAD_DIR=='UNIF' .OR. tm%DTT%LDATA_ROAD_DIR) THEN
    ystring = 'X_Y_TROAD'
  ELSEIF (SIZE(tm%T%CUR%XROAD_DIR)>0) THEN
    !* road direction is uniform spatially, one can then indicate it in the comment
    CALL road_dir(tm%T%CUR%XROAD_DIR(1),ydir)
    ystring=trim(ydir)//' ROAD TEMP. LAYER '
  ELSE
    ystring='? ROAD TEMP. LAYER '
  ENDIF
  WRITE(ycomment,'(A,I1.1,A4)') trim(ystring), jlayer,' (K)'
  CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%T%CUR%XT_ROAD(:,jlayer),iresp,hcomment=ycomment)
END DO
!
!* road water content
!

yrecfm=ypatch//'WS_ROAD'
yrecfm=adjustl(yrecfm)
ycomment='WS_ROAD (kg/m2)'
 CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%T%CUR%XWS_ROAD(:),iresp,hcomment=ycomment)
!
!* wall temperatures
!

DO jlayer=1,tm%TOP%NWALL_LAYER
 IF (tm%TOP%CWALL_OPT=='UNIF') THEN
  WRITE(yrecfm,'(A3,A5,I1.1,A1)') ypatch,'TWALL',jlayer,' '
  yrecfm=adjustl(yrecfm)
  WRITE(ycomment,'(A9,I1.1,A4)') 'X_Y_TWALL',jlayer,' (K)'
  CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%T%CUR%XT_WALL_A(:,jlayer),iresp,hcomment=ycomment)
 ELSE
  !* Wall A
  WRITE(yrecfm,'(A3,A6,I1.1)') ypatch,'TWALLA',jlayer
  yrecfm=adjustl(yrecfm)
  IF (tm%DTT%LDATA_ROAD_DIR) THEN
    ystring = 'X_Y_TWALL_A'
  ELSEIF (SIZE(tm%T%CUR%XROAD_DIR)>0) THEN
    !* wall direction is uniform spatially, one can then indicate it in the comment
    CALL walla_dir(tm%T%CUR%XROAD_DIR(1),ydir)
    ystring=trim(ydir)//'-FACING WALL TEMP. LAYER '
  ELSE
    ystring='?-FACING WALL TEMP. LAYER '
  ENDIF
  WRITE(ycomment,'(A,I1.1,A4)') trim(ystring), jlayer,' (K)'
  CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%T%CUR%XT_WALL_A(:,jlayer),iresp,hcomment=ycomment)
  !
  !* Wall B
  WRITE(yrecfm,'(A3,A6,I1.1)') ypatch,'TWALLB',jlayer
  yrecfm=adjustl(yrecfm)
  IF (tm%DTT%LDATA_ROAD_DIR) THEN
    ystring = 'X_Y_TWALL_B'
  ELSEIF (SIZE(tm%T%CUR%XROAD_DIR)>0) THEN
    !* wall direction is uniform spatially, one can then indicate it in the comment
    CALL wallb_dir(tm%T%CUR%XROAD_DIR(1),ydir)
    ystring=trim(ydir)//'-FACING WALL TEMP. LAYER '
  ELSE
    ystring='?-FACING WALL TEMP. LAYER '
  ENDIF
  WRITE(ycomment,'(A,I1.1,A4)') trim(ystring), jlayer,' (K)'
  CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%T%CUR%XT_WALL_B(:,jlayer),iresp,hcomment=ycomment)
 END IF
END DO
!
!* internal building temperature
!
yrecfm=ypatch//'TI_BLD'
yrecfm=adjustl(yrecfm)
ycomment='TI_BLD (K)'
 CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%B%CUR%XTI_BLD(:),iresp,hcomment=ycomment)
!
!
!* outdoor window temperature
!
yrecfm=ypatch//'T_WIN1'
yrecfm=adjustl(yrecfm)
ycomment='T_WIN1 (K)'
 CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%B%CUR%XT_WIN1(:),iresp,hcomment=ycomment)
!
IF (tm%TOP%CBEM=='BEM') THEN
!* internal building specific humidity
!
yrecfm=ypatch//'QI_BLD'
yrecfm=adjustl(yrecfm)
ycomment='QI_BLD (kg/kg)'
 CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%B%CUR%XQI_BLD(:),iresp,hcomment=ycomment)
!
  !
  !* indoor window temperature
  !
  yrecfm=ypatch//'T_WIN2'
  yrecfm=adjustl(yrecfm)
  ycomment='T_WIN2 (K)'
  CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%B%CUR%XT_WIN2(:),iresp,hcomment=ycomment)
  !
  !* floor temperatures
  !
  DO jlayer=1,tm%BOP%NFLOOR_LAYER
    WRITE(yrecfm,'(A3,A5,I1.1,A1)') ypatch,'TFLOO',jlayer,' '
    WRITE(ycomment,'(A9,I1.1,A4)') 'X_Y_TFLOO',jlayer,' (K)'
    yrecfm=adjustl(yrecfm)
    CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%B%CUR%XT_FLOOR(:,jlayer),iresp,hcomment=ycomment)
  END DO
  !
  !* internal th. mass temperature
  !
  DO jlayer=1,tm%BOP%NFLOOR_LAYER
    WRITE(yrecfm,'(A3,A5,I1.1,A1)') ypatch,'TMASS',jlayer,' '
    WRITE(ycomment,'(A9,I1.1,A4)') 'X_Y_TMASS',jlayer,' (K)'
    yrecfm=adjustl(yrecfm)
    CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%B%CUR%XT_MASS(:,jlayer),iresp,hcomment=ycomment)
  END DO        
  !
ENDIF
!
!* deep road temperature
!
yrecfm=ypatch//'TI_ROAD'
yrecfm=adjustl(yrecfm)
ycomment='TI_ROAD (K)'
 CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%T%CUR%XTI_ROAD(:),iresp,hcomment=ycomment)
!
!* snow mantel
!
yrecfm='RF'
 CALL writesurf_gr_snow(dgu, u, &
                        hprogram,yrecfm,ypatch,tm%T%CUR%TSNOW_ROOF  )
!
yrecfm='RD'
 CALL writesurf_gr_snow(dgu, u, &
                        hprogram,yrecfm,ypatch,tm%T%CUR%TSNOW_ROAD  )
!
!-------------------------------------------------------------------------------
!
!*       4.     Semi-prognostic fields:
!               ----------------------
!
!* temperature of canyon air
!
yrecfm=ypatch//'TCANYON'
yrecfm=adjustl(yrecfm)
ycomment='T_CANYON (K)'
 CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%T%CUR%XT_CANYON(:),iresp,hcomment=ycomment)
!
!* humidity of canyon air
!
yrecfm=ypatch//'QCANYON'
yrecfm=adjustl(yrecfm)
ycomment='Q_CANYON (kg/kg)'
 CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%T%CUR%XQ_CANYON(:),iresp,hcomment=ycomment)
!
!
!* Thermal solar panels present day production
!
IF (tm%TOP%LSOLAR_PANEL) THEN
  yrecfm=ypatch//'THER_PDAY'
  yrecfm=adjustl(yrecfm)
  ycomment='Thermal Solar Panels present day production (J/m2)'
  IF (.NOT. ASSOCIATED(tm%TPN%XTHER_PRODC_DAY)) THEN
    ! for PREP cases
    ALLOCATE(tm%TPN%XTHER_PRODC_DAY(SIZE(tm%B%CUR%XTI_BLD)))
    tm%TPN%XTHER_PRODC_DAY=0.
  END IF
  CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%TPN%XTHER_PRODC_DAY(:),iresp,hcomment=ycomment)
END IF
!-------------------------------------------------------------------------------
!
!*       5.  Time
!            ----
!
IF (kpatch==1) THEN
  yrecfm='DTCUR'
  ycomment='s'
  CALL write_surf(dgu, u, &
                 hprogram,yrecfm,tm%TOP%TTIME,iresp,hcomment=ycomment)
END IF
!
!
!-------------------------------------------------------------------------------
!
!*       6.  Urban green areas
!            ------------------
!
! Gardens
IF (tm%TOP%LGARDEN) CALL writesurf_teb_garden_n(dgu, u, gdm, &
                                             hprogram,ypatch)
!
! Grenn roofs
IF (tm%TOP%LGREENROOF) CALL writesurf_teb_greenroof_n(dgu, u, gdm%TVG, grm, &
                                                   hprogram,ypatch)
!
IF (lhook) CALL dr_hook('WRITESURF_TEB_N',1,zhook_handle)
!
!
!-------------------------------------------------------------------------------
 CONTAINS
SUBROUTINE road_dir(PDIR,HDIR)
REAL,             INTENT(IN)  :: pdir
 CHARACTER(LEN=7), INTENT(OUT) :: hdir
REAL :: zdir
zdir=pdir
IF (pdir<0) zdir = pdir +360.
IF (zdir>=  0.   .AND. zdir< 11.25) hdir='N-S    '
IF (zdir>= 11.25 .AND. zdir< 33.75) hdir='NNE-SSW'
IF (zdir>= 33.75 .AND. zdir< 56.25) hdir='NE-SW'
IF (zdir>= 56.25 .AND. zdir< 78.75) hdir='ENE-WSW'
IF (zdir>= 78.75 .AND. zdir<101.25) hdir='E-W    '
IF (zdir>=101.25 .AND. zdir<123.75) hdir='ESE-WNW'
IF (zdir>=123.75 .AND. zdir<146.25) hdir='SE-NW  '
IF (zdir>=146.25 .AND. zdir<168.75) hdir='SSE-NNW'
IF (zdir>=168.75 .AND. zdir<180.00) hdir='N-S    '
END SUBROUTINE road_dir
SUBROUTINE walla_dir(PDIR,HDIR)
REAL,             INTENT(IN)  :: pdir
 CHARACTER(LEN=7), INTENT(OUT) :: hdir
REAL :: zdir
zdir=pdir
IF (pdir<0) zdir = pdir +360.
IF (zdir>=  0.   .AND. zdir< 11.25) hdir='E      '
IF (zdir>= 11.25 .AND. zdir< 33.75) hdir='ESE    '
IF (zdir>= 33.75 .AND. zdir< 56.25) hdir='SE     ' 
IF (zdir>= 56.25 .AND. zdir< 78.75) hdir='SSE    '
IF (zdir>= 78.75 .AND. zdir<101.25) hdir='S      '
IF (zdir>=101.25 .AND. zdir<123.75) hdir='SSW    '
IF (zdir>=123.75 .AND. zdir<146.25) hdir='SW     '
IF (zdir>=146.25 .AND. zdir<168.75) hdir='WSW    '
IF (zdir>=168.75 .AND. zdir<180.00) hdir='W      '
END SUBROUTINE walla_dir
SUBROUTINE wallb_dir(PDIR,HDIR)
REAL,             INTENT(IN)  :: pdir
 CHARACTER(LEN=7), INTENT(OUT) :: hdir
REAL :: zdir
zdir=pdir
IF (pdir<0) zdir = pdir +360.
IF (zdir>=  0.   .AND. zdir< 11.25) hdir='W      '
IF (zdir>= 11.25 .AND. zdir< 33.75) hdir='WNW    '
IF (zdir>= 33.75 .AND. zdir< 56.25) hdir='NW     ' 
IF (zdir>= 56.25 .AND. zdir< 78.75) hdir='NNW    '
IF (zdir>= 78.75 .AND. zdir<101.25) hdir='N      '
IF (zdir>=101.25 .AND. zdir<123.75) hdir='NNE    '
IF (zdir>=123.75 .AND. zdir<146.25) hdir='NE     '
IF (zdir>=146.25 .AND. zdir<168.75) hdir='ENE    '
IF (zdir>=168.75 .AND. zdir<180.00) hdir='E      '
END SUBROUTINE wallb_dir
!-------------------------------------------------------------------------------
!
END SUBROUTINE writesurf_teb_n