writesurf_teb_gardenn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE writesurf_teb_garden_n (DGU, U, GDM, &
                                         hprogram,hpatch)
!     #####################################
!
!!****  *WRITESURF_TEB_GARDEN_n* - writes ISBA prognostic fields
!!                        
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!!      P. LeMoigne 12/2004 : correct dimensionning if more than 10 layers in
!!                            the soil (diffusion version)
!!      B. Decharme  2008    : Floodplains
!!      B. Decharme  01/2009 : Optional Arpege deep soil temperature write
!!      B. Decharme  09/2012 : suppress NWG_LAYER (parallelization problems)
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------

!
!
!
!
USE modd_diag_surf_atm_n, ONLY : diag_surf_atm_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surfex_n, ONLY : teb_garden_model_t
!
USE modd_surf_par, ONLY : nundef
!
USE modi_write_surf
USE modi_writesurf_gr_snow
USE modd_dst_surf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
!
TYPE(diag_surf_atm_t), INTENT(INOUT) :: dgu
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(teb_garden_model_t), INTENT(INOUT) :: gdm
!
 CHARACTER(LEN=6),  INTENT(IN)  :: hprogram ! program calling
 CHARACTER(LEN=3),  INTENT(IN)  :: hpatch   ! current teb patch
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER           :: iresp          ! IRESP  : return-code if a problem appears
 CHARACTER(LEN=12) :: yrecfm         ! Name of the article to be read
 CHARACTER(LEN=100):: ycomment       ! Comment string
 CHARACTER(LEN=14) :: yform          ! Writing format
 CHARACTER(LEN=4 ) :: ylvl
!
INTEGER :: jlayer ! loop counter on soil layers
!
REAL, DIMENSION(:),ALLOCATABLE  :: zwork      ! 2D array to write data in file
!
INTEGER :: jnbiomass
REAL(KIND=JPRB) :: zhook_handle
!
!------------------------------------------------------------------------------
!
!*       2.     Prognostic fields:
!               -----------------
!
IF (lhook) CALL dr_hook('WRITESURF_TEB_GARDEN_N',0,zhook_handle)
ALLOCATE(zwork(SIZE(gdm%TGD%CUR%XTG,1)))
!* soil temperatures
!
DO jlayer=1,gdm%TGDO%NGROUND_LAYER
  WRITE(ylvl,'(I2)') jlayer
  yrecfm=hpatch//'GD_TG'//adjustl(ylvl(:len_trim(ylvl)))
  yrecfm=adjustl(yrecfm)
  yform='(A11,I1.1,A4)'
  IF (jlayer >= 10)  yform='(A11,I2.2,A4)'
  WRITE(ycomment,fmt=yform) 'X_Y_GD_TG',jlayer,' (K)'
  zwork=gdm%TGD%CUR%XTG(:,jlayer)
  CALL write_surf(dgu, u, &
                  hprogram,yrecfm,zwork,iresp,hcomment=ycomment)
END DO
!
!
!* soil liquid water content
!
DO jlayer=1,gdm%TGDO%NGROUND_LAYER
  WRITE(ylvl,'(I2)') jlayer
  yrecfm=hpatch//'GD_WG'//adjustl(ylvl(:len_trim(ylvl)))
  yrecfm=adjustl(yrecfm)
  yform='(A11,I1.1,A8)'
  IF (jlayer >= 10)  yform='(A11,I2.2,A8)'
  WRITE(ycomment,fmt=yform) 'X_Y_GD_WG',jlayer,' (m3/m3)'
  zwork=gdm%TGD%CUR%XWG(:,jlayer)
  CALL write_surf(dgu, u, &
                  hprogram,yrecfm,zwork,iresp,hcomment=ycomment)
END DO
!
!
!* soil ice water content
!
DO jlayer=1,gdm%TGDO%NGROUND_LAYER
  WRITE(ylvl,'(I2)') jlayer
  yrecfm=hpatch//'GD_WGI'//adjustl(ylvl(:len_trim(ylvl)))
  yrecfm=adjustl(yrecfm)
  yform='(A11,I1.1,A8)'
  IF (jlayer >= 10)  yform='(A11,I2.2,A8)'
  WRITE(ycomment,yform) 'X_Y_GD_WGI',jlayer,' (m3/m3)'
  zwork=gdm%TGD%CUR%XWGI(:,jlayer)
  CALL write_surf(dgu, u, &
                  hprogram,yrecfm,zwork,iresp,hcomment=ycomment)
END DO
!
DEALLOCATE(zwork)
!
!* water intercepted on leaves
!
yrecfm=hpatch//'GD_WR'
yrecfm=adjustl(yrecfm)
ycomment='X_Y_GD_WR (kg/m2)'
 CALL write_surf(dgu, u, &
                  hprogram,yrecfm,gdm%TGD%CUR%XWR(:),iresp,hcomment=ycomment)
!
!* Leaf Area Index
!
IF (gdm%TVG%CPHOTO/='NON' .AND. gdm%TVG%CPHOTO/='AGS' .AND. gdm%TVG%CPHOTO/='AST') THEN
  yrecfm=hpatch//'GD_LAI'
  yrecfm=adjustl(yrecfm)
  ycomment='X_Y_GD_LAI (m2/m2)'
 CALL write_surf(dgu, u, &
                  hprogram,yrecfm,gdm%TGDPE%CUR%XLAI(:),iresp,hcomment=ycomment)
END IF
!
IF (gdm%TVG%CPHOTO=='NIT') THEN
  !
  DO jnbiomass=1,gdm%TVG%NNBIOMASS
    WRITE(ylvl,'(I1)') jnbiomass
    yrecfm=hpatch//'GD_BIOMA'//adjustl(ylvl(:len_trim(ylvl)))
    yrecfm=adjustl(yrecfm)
    yform='(A11,I1.1,A8)'
    WRITE(ycomment,fmt=yform) 'X_Y_BIOMASS',jnbiomass,' (kg/m2)'
    CALL write_surf(dgu, u, &
                  hprogram,yrecfm,gdm%TGD%CUR%XBIOMASS(:,jnbiomass),iresp,hcomment=ycomment)
  END DO
  !
  !
  DO jnbiomass=2,gdm%TVG%NNBIOMASS
    WRITE(ylvl,'(I1)') jnbiomass
    yrecfm=hpatch//'GD_RESPI'//adjustl(ylvl(:len_trim(ylvl)))
    yrecfm=adjustl(yrecfm)
    yform='(A16,I1.1,A10)'
    WRITE(ycomment,fmt=yform) 'X_Y_RESP_BIOMASS',jnbiomass,' (kg/m2/s)'
    CALL write_surf(dgu, u, &
                  hprogram,yrecfm,gdm%TGD%CUR%XRESP_BIOMASS(:,jnbiomass),iresp,hcomment=ycomment)
  END DO
  !
END IF
!
!* aerodynamical resistance
!
yrecfm=hpatch//'GD_RES'
yrecfm=adjustl(yrecfm)
ycomment='X_Y_GD_RESA (s/m)'
 CALL write_surf(dgu, u, &
                  hprogram,yrecfm,gdm%TGD%CUR%XRESA(:),iresp,hcomment=ycomment)
!
!* snow mantel
!
yrecfm='GD'
 CALL writesurf_gr_snow(dgu, u, &
                        hprogram,yrecfm,hpatch,gdm%TGD%CUR%TSNOW)
IF (lhook) CALL dr_hook('WRITESURF_TEB_GARDEN_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE writesurf_teb_garden_n