teb_canopy.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE teb_canopy(KI,KLVL,PZ,PZF,PDZ,PDZF,PBLD,PBLD_HEIGHT,PWALL_O_HOR,PPA,PRHOA,PU,         &
                      pduwdu_road, puw_roof, pduwdu_roof,                                        &
                      ph_wall,ph_roof,pe_roof,pac_road,pac_road_wat,                             &
                      pforc_u,pdforc_udu,pforc_e,pdforc_ede,pforc_t,pdforc_tdt,pforc_q,pdforc_qdq)
!     ###############################################################################
!
!!****  *TEB_CANOPY_n * - prepares forcing for canopy air model
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2006
!!---------------------------------------------------------------
!
!
USE modd_csts,         ONLY : xrd, xcpd, xp00, xg, xpi
USE modd_surf_par,     ONLY : xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_canopy
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
INTEGER,                  INTENT(IN)    :: ki        ! number of points
INTEGER,                  INTENT(IN)    :: klvl      ! number of levels in canopy
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pz        ! heights of canopy levels              (m)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pzf       ! heights of bottom of canopy levels    (m)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pdz       ! depth   of canopy levels              (m)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pdzf      ! depth between canopy levels           (m)
REAL, DIMENSION(KI),      INTENT(IN)    :: pbld        ! building density                    (-)
REAL, DIMENSION(KI),      INTENT(IN)    :: pbld_height ! building height                     (m)
REAL, DIMENSION(KI),      INTENT(IN)    :: pwall_o_hor ! wall surf. / hor. surf.             (-)

REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pu        ! wind for each canopy layer            (m/s)
!
REAL, DIMENSION(KI),      INTENT(IN)    :: ppa       ! air pressure                          (Pa)
REAL, DIMENSION(KI),      INTENT(IN)    :: prhoa     ! air density                           (kg/m3)
!
REAL, DIMENSION(KI),      INTENT(IN)    :: pduwdu_road  ! derivative of road friction flux   (m/s)
REAL, DIMENSION(KI),      INTENT(IN)    :: puw_roof  ! friction flux for roof surfaces       (m2/s2)
REAL, DIMENSION(KI),      INTENT(IN)    :: pduwdu_roof  ! derivative of roof friction flux   (m/s)
REAL, DIMENSION(KI),      INTENT(IN)    :: ph_wall   ! flux of heat for wall surfaces        (W/m2)
REAL, DIMENSION(KI),      INTENT(IN)    :: ph_roof   ! flux of heat for roof surfaces        (W/m2)
REAL, DIMENSION(KI),      INTENT(IN)    :: pe_roof   ! flux of vapor for roof surfaces       (kg/m2/s)
REAL, DIMENSION(KI),      INTENT(IN)    :: pac_road  ! road aerodynamical conductance        ()
REAL, DIMENSION(KI),      INTENT(IN)    :: pac_road_wat ! road water aerodynamical conductance        ()
!
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pforc_u   ! tendency of wind due to canopy drag   (m/s2)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pdforc_udu! formal derivative of the tendency of
!                                                    ! wind due to canopy drag               (1/s)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pforc_e   ! tendency of TKE  due to canopy drag   (m2/s3)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pdforc_ede! formal derivative of the tendency of
!                                                    ! TKE  due to canopy drag               (1/s)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pforc_t   ! tendency of Temp due to canopy drag   (T/s)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pdforc_tdt! formal derivative of the tendency of
!                                                    ! Temp due to canopy drag               (1/s)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pforc_q   ! tendency of Temp due to canopy drag   (kg/m3/s)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pdforc_qdq! formal derivative of the tendency of
!                                                    ! Temp due to canopy drag               (1/s)
!
!*      0.2    declarations of local variables
!
INTEGER                  :: jlayer    ! loop counter on canopy heights
!         
REAL, DIMENSION(KI,KLVL) :: zcdrag    ! drag coefficient in canopy
REAL, DIMENSION(KI,KLVL) :: zsh       ! horizontal surface of building
                                      ! (road&roof) for each canopy level
REAL, DIMENSION(KI,KLVL) :: zsv       ! vertical surface of building
                                      ! (walls) for each canopy level
REAL, DIMENSION(KI,KLVL) :: zforc
REAL, DIMENSION(KI,KLVL) :: zdensity
REAL, DIMENSION(KI,KLVL) :: zairvol   ! Fraction of air for each canopy level total volume
REAL, DIMENSION(KI,KLVL) :: zp        ! pressure              at full levels
REAL, DIMENSION(KI,KLVL) :: zexn      ! Exner function        at full levels
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!
!*      1.     Computations of canopy grid characteristics
!              -------------------------------------------
!
!
!*      1.2    Proportion of horizontal surfaces for each canopy level
!
IF (lhook) CALL dr_hook('TEB_CANOPY',0,zhook_handle)
zsh(:,:) = 0.
zsh(:,1) = (1.-pbld(:))
!
WHERE( pzf(:,2)>=pbld_height(:) ) zsh(:,2) = pbld(:) ! the roofs cannot be at the same level as roads
DO jlayer = 2,klvl-1
  WHERE( pzf(:,jlayer)<pbld_height(:) .AND. pzf(:,jlayer+1)>=pbld_height(:) ) zsh(:,jlayer) = pbld(:)
END DO
WHERE( pzf(:,klvl)<pbld_height(:) ) zsh(:,klvl) = pbld(:)
!
!*      2.1    Drag coefficient by walls
!              -------------------------
!
zcdrag(:,:) = 0.40
!* integration for all canyon directions (for facing wind walls)
zcdrag(:,:) = zcdrag(:,:) / xpi
!
!*      1.4    No building volume
!
! * in order to take into account building volume, further developments must be
!   done in the atmospheric model.
!   If these changes are not done, to take into account building volume in the
!   present routine alone would not be energetically coeherent (there would be
!   too much energy release for heat and vapor or consumed for wind).
!
zairvol = 1.
!
!*      1.2    Discretization on each canopy level
!
DO jlayer=1,klvl
  zdensity(:,jlayer) = pwall_o_hor(:)
ENDDO  
!
 CALL canopy(ki, klvl, pzf, pdz, pbld_height, zdensity, zcdrag, pu, zairvol, &
            zsv, zforc, pforc_u, pdforc_udu, pforc_e, pdforc_ede      )
!
!-------------------------------------------------------------------------------------
!
!*      2.     Computations of wind tendency due to canopy drag
!              ------------------------------------------------
!
! Ext = - Cdrag  * u- * u- * Sv/Vair        vertical surfaces or trees
!       - u'w'(roof)       * Sh/Vair        horizontal surfaces (except road)
!       - u'w'(road)       * Sh/Vair        horizontal surfaces (road)
!
! with Vair = Vair/Vtot * Vtot = (Vair/Vtot) * Stot * Dz
! and  Sv/Vair = (Sv/Stot) * Stot/Vair = (Sv/Stot) / (Vair/Vtot) / Dz
! and  Sh/Vair = (Sh/Stot) * Stot/Vair = (Sv/Stot) / (Vair/Vtot) / Dz
!
!* Note that for the time being, air is assumed to occupy all the space of the grid
! (buildings have no volume), so that Vair = Vtot
!
zforc(:,:) = zsh(:,:)/zairvol(:,:)/pdz(:,:)
!
!*      2.3    Drag force by roof surfaces
!              ---------------------------
!
!* drag force by horizontal surfaces
!
DO jlayer=2,klvl
  pforc_u(:,jlayer) = pforc_u(:,jlayer) + puw_roof(:) * zforc(:,jlayer)
  pdforc_udu(:,jlayer) = pdforc_udu(:,jlayer) + pduwdu_roof(:) * zforc(:,jlayer)
END DO
!
!*      2.4    Drag force by road surfaces
!              ---------------------------
!
!PFORC_U(:,1)    = PUW_ROAD(:) / PDZ(:,1) * ZSH(:,1)
pforc_u(:,1) = pforc_u(:,1)    
pdforc_udu(:,1) = pdforc_udu(:,1) + pduwdu_road(:) * zsh(:,1)/pdz(:,1)
!
!-------------------------------------------------------------------------------------
!
!*      4.     Computations of potential temperature tendency due to canopy drag
!              -----------------------------------------------------------------
!
pforc_t(:,:) = 0.
pdforc_tdt(:,:) = 0.
!
!*      4.1    Heating from the road surface flux
!              ----------------------------------
!
!* surface flux
!
pdforc_tdt(:,1) = pdforc_tdt(:,1) - pac_road(:)
!!* Warning, the "  - PAC_ROAD(:)  " term in the equation above is used
!   to improve stability for the first layer of canopy. But the TEB equations
!   for road temperature are not implicited, so this implies that the energy
!   coming from the road as seen by canopy is not equal to the one emitted by
!   TEB.
!   This has no consequence on the conservation of the energy between the
!   surface and the atmosphere, because the heat flux goes directly from TEB to
!   SURF_ATM and then to the atmosphere. Only the canopy air profiles are
!   affected.
!
!
!*      4.2    Heating from the walls surface flux
!              -----------------------------------
!
DO jlayer=1,klvl
  zforc(:,jlayer) = 1. / zairvol(:,jlayer) / pdz(:,jlayer) / prhoa(:) / xcpd 
  pforc_t(:,jlayer) = pforc_t(:,jlayer) + ph_wall * zsv(:,jlayer) * zforc(:,jlayer)
  pdforc_tdt(:,jlayer) = pdforc_tdt(:,jlayer) + 0.
END DO
!
!*      4.3    Heating from the roof surface flux
!              ----------------------------------
!
DO jlayer=2,klvl
  pforc_t(:,jlayer) = pforc_t(:,jlayer) + ph_roof * zsh(:,jlayer) * zforc(:,jlayer)
  pdforc_tdt(:,jlayer) = pdforc_tdt(:,jlayer) + 0.
END DO
!
!-------------------------------------------------------------------------------------
!
!*      5.     Conversion into temperature tendency
!              ------------------------------------
!
DO jlayer=1,klvl
  zp(:,jlayer) = ppa(:) + xg * prhoa(:) * (pz(:,klvl) - pz(:,jlayer))
END DO
zexn = (zp/xp00)**(xrd/xcpd)
!
pforc_t    = pforc_t    * zexn
pdforc_tdt = pdforc_tdt * zexn
!
!-------------------------------------------------------------------------------------
!
!*      6.     Computations of humidity tendency due to canopy
!              -----------------------------------------------
!
!
pforc_q(:,:) = 0.
pdforc_qdq(:,:) = 0.
!
!
!*      4.1    Evaporation from the road surface flux
!              --------------------------------------
!
!* surface flux
!
!
pdforc_qdq(:,1) = pdforc_qdq(:,1) - pac_road_wat(:)
!!* Warning, the "  - PAC_ROAD_WAT(:)  " term in the equation above is used
!   to improve stability for the first layer of canopy. But the TEB equations
!   for road latent heat flux are not implicited, so this implies that the energy
!   coming from the road as seen by canopy is not equal to the one emitted by
!   TEB.
!   This has no consequence on the conservation of the energy between the
!   surface and the atmosphere, because the latent heat flux goes directly from TEB to
!   SURF_ATM and then to the atmosphere. Only the canopy air profiles are
!   affected.
!
!*      4.2    Evaporation from the roof surface flux
!              --------------------------------------
!
DO jlayer=2,klvl
  pforc_q(:,jlayer) = pforc_q(:,jlayer) + pe_roof * zsh(:,jlayer)/zairvol(:,jlayer)/pdz(:,jlayer)
  pdforc_qdq(:,jlayer) = pdforc_qdq(:,jlayer) + 0.
END DO
IF (lhook) CALL dr_hook('TEB_CANOPY',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE teb_canopy