canopy.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE canopy(KI, KLVL, PZF, PDZ, PHEIGHT, PDENSITY, PCDRAG, PU, PAIRVOL, &
                  psv, pforc, pforc_u, pdforc_udu, pforc_e, pdforc_ede   )  
!     ###############################################################################
!
!!****  *ISBA_CANOPY_n * - prepares forcing for canopy air model
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2006
!!---------------------------------------------------------------
!
!
USE modd_csts,         ONLY : xrd, xcpd, xp00, xg
USE modd_surf_par,     ONLY : xundef
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
INTEGER,                  INTENT(IN)    :: ki        ! number of points
INTEGER,                  INTENT(IN)    :: klvl      ! number of levels in canopy
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pzf       ! heights of bottom of canopy levels    (m)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pdz       ! depth   of canopy levels              (m)
REAL, DIMENSION(KI), INTENT(IN)    :: pheight   ! canopy height                       (m)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pdensity  ! canopy density                  (-)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pcdrag
!
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pu        ! wind for each canopy layer            (m/s)
!
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pairvol   ! Fraction of air for each canopy level total volume
!
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: psv       ! vertical surface of building
                                                     ! (walls) for each canopy level
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pforc     !
!
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pforc_u   ! tendency of wind due to canopy drag   (m/s2)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pdforc_udu! formal derivative of the tendency of
!                                                    ! wind due to canopy drag               (1/s)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pforc_e   ! tendency of TKE  due to canopy drag   (m2/s3)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pdforc_ede! formal derivative of the tendency of
!                                                    ! TKE  due to canopy drag               (1/s)
!
!*      0.2    declarations of local variables
!
INTEGER                  :: jlayer    ! loop counter on canopy heights      
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('CANOPY',0,zhook_handle)
!
!*      1.     Computations of canopy grid characteristics
!              -------------------------------------------
!
!
!*      1.2    Discretization on each canopy level
!
psv(:,:) = 0.
DO jlayer = 1,klvl-1
  !
  WHERE ( pzf(:,jlayer) < pheight(:) )
    psv(:,jlayer) = pdensity(:,jlayer) / pheight(:)
    WHERE ( pzf(:,jlayer+1) > pheight(:) )
      psv(:,jlayer) = psv(:,jlayer) * ( pheight(:) - pzf(:,jlayer) )
    ELSEWHERE
      psv(:,jlayer) = psv(:,jlayer) *  pdz(:,jlayer)
    END WHERE
  END WHERE
  !
END DO
!
pforc(:,:) = pcdrag(:,:) * pu(:,:) * psv(:,:)/pairvol(:,:)/pdz(:,:)
!
!-------------------------------------------------------------------------------------
!
!*      2.     Computations of wind tendency due to canopy drag
!              ------------------------------------------------
!
pforc_u    = 0.
pdforc_udu = 0.
!
! Ext = - Cdrag  * u- * u- * Sv       tree canopy drag
!       - u'w'(ground)     * Sh       horizontal surfaces (ground)
!
!
!*      2.2    Drag force by wall surfaces
!              ---------------------------
!
!* drag force by vertical surfaces
!
pforc_u(:,:) = pforc_u    -      pforc(:,:) * pu(:,:)
pdforc_udu(:,:) = pdforc_udu - 2. * pforc(:,:)
!
!-------------------------------------------------------------------------------------
!
!*      3.     Computations of TKE  tendency due to canopy drag
!              ------------------------------------------------
!
!* Tendency due to drag for TKE
!
pforc_e(:,:) = 0.
pdforc_ede(:,:) = 0.
!
!*      3.1    Creation of TKE by wake
!              -----------------------
!
! from Kanda and Hino (1994)
!
! Ext = + Cd * u+^3  * Sv/Vair        vertical surfaces or trees
!
! with Vair = Vair/Vtot * Vtot = (Vair/Vtot) * Stot * Dz
! and  Sv/Vair = (Sv/Stot) * Stot/Vair = (Sv/Stot) / (Vair/Vtot) / Dz
!
pforc_e    = pforc_e    + pforc(:,:) * pu(:,:)**2
pdforc_ede = pdforc_ede + 0.
!
!
IF (lhook) CALL dr_hook('CANOPY',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE canopy