read_teb_greenroofn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_teb_greenroof_n (DTCO, U, TVG, GRM, &
                                       hprogram,hpatch)
!     ##################################
!
!!****  *READ_TEB_GREENROOF_n* - routine to initialise ISBA variables
!!                         
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!    based on read_teb_greenroofn
!!
!!    AUTHOR
!!    ------
!!      C. de Munck & A. Lemonsu *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2011
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_teb_veg_n, ONLY : teb_veg_options_t
USE modd_surfex_n, ONLY : teb_greenroof_model_t
!
USE modd_co2v_par,          ONLY : xanfminit, xcondctmin
!                                
USE modd_surf_par,          ONLY : xundef
USE modd_snow_par,          ONLY : xz0sn
!
USE modi_read_surf
!
USE modi_read_gr_snow
!
!
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_get_type_dim_n
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(teb_veg_options_t), INTENT(INOUT) :: tvg
TYPE(teb_greenroof_model_t), INTENT(INOUT) :: grm

!
 CHARACTER(LEN=6),  INTENT(IN)  :: hprogram ! calling program
 CHARACTER(LEN=3),  INTENT(IN)  :: hpatch   ! current TEB patch identificator
!
!*       0.2   Declarations of local variables
!              -------------------------------
INTEGER           :: ilu                             ! 1D physical dimension
INTEGER           :: iresp                           ! Error code after redding
INTEGER           :: iwork                           ! Work integer
INTEGER           :: jlayer, jnbiomass               ! loop counter on layers
 CHARACTER(LEN=30) :: yrecfm                          ! Name of the article to be read
 CHARACTER(LEN=4)  :: ylvl
REAL, DIMENSION(:),ALLOCATABLE  :: zwork             ! 2D array to write data in file
!
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
!
!* 1D physical dimension
!
IF (lhook) CALL dr_hook('READ_TEB_GREENROOF_N',0,zhook_handle)
yrecfm='SIZE_TOWN'
 CALL get_type_dim_n(dtco, u, &
                     'TOWN  ',ilu)
!
!
!*       2.     Prognostic fields:
!               -----------------
!
ALLOCATE(zwork(ilu))
!
!* soil temperatures
!
iwork = grm%TGRO%NLAYER_GR
!
DO jlayer=1,iwork
  WRITE(ylvl,'(I2)') jlayer
  yrecfm=hpatch//'GR_TG'//adjustl(ylvl(:len_trim(ylvl)))
  yrecfm=adjustl(yrecfm)
  CALL read_surf(&
                 hprogram,yrecfm,zwork(:),iresp)
  grm%TGR%CUR%XTG(:,jlayer) = zwork
END DO
!
!
!* soil liquid water content
!
DO jlayer=1,grm%TGRO%NLAYER_GR
  WRITE(ylvl,'(I2)') jlayer
  yrecfm=hpatch//'GR_WG'//adjustl(ylvl(:len_trim(ylvl)))
  yrecfm=adjustl(yrecfm)
  CALL read_surf(&
                 hprogram,yrecfm,zwork(:),iresp)
  grm%TGR%CUR%XWG(:,jlayer) = zwork
END DO
!
!* soil ice water content
!
DO jlayer=1,grm%TGRO%NLAYER_GR
  WRITE(ylvl,'(I2)') jlayer
  yrecfm=hpatch//'GR_WGI'//adjustl(ylvl(:len_trim(ylvl)))
  yrecfm=adjustl(yrecfm)
  CALL read_surf(&
                 hprogram,yrecfm,zwork(:),iresp)
  grm%TGR%CUR%XWGI(:,jlayer) = zwork
END DO
!
!* water intercepted on leaves
!
yrecfm=hpatch//'GR_WR'
yrecfm=adjustl(yrecfm)
 CALL read_surf(&
                 hprogram,yrecfm,grm%TGR%CUR%XWR(:),iresp)
!
!* Leaf Area Index
!
IF (tvg%CPHOTO=='LAI' .OR. tvg%CPHOTO=='LST' .OR. tvg%CPHOTO=='NIT' .OR. tvg%CPHOTO=='NCB') THEN
  yrecfm = hpatch//'GR_LAI'
  yrecfm=adjustl(yrecfm)
  CALL read_surf(&
                 hprogram,yrecfm,grm%TGRPE%CUR%XLAI(:),iresp)
END IF
!
!* snow mantel
!
 CALL read_gr_snow(&
                   hprogram,'GR',hpatch,ilu,1,grm%TGR%CUR%TSNOW  )! GROO:GreenROOf 
!
!-------------------------------------------------------------------------------
!
!*       4.  Semi-prognostic variables
!            -------------------------
!
!* aerodynamical resistance
!
yrecfm = hpatch//'GR_RESA'
yrecfm=adjustl(yrecfm)
grm%TGR%CUR%XRESA(:) = 100.
 CALL read_surf(&
                 hprogram,yrecfm,grm%TGR%CUR%XRESA(:),iresp)
!
grm%TGR%CUR%XLE(:) = xundef
!
!* ISBA-AGS variables
!
IF (tvg%CPHOTO/='NON') THEN
  grm%TGR%CUR%XAN(:)    = 0.
  grm%TGR%CUR%XANDAY(:) = 0.
  grm%TGR%CUR%XANFM(:)  = xanfminit
  grm%TGR%CUR%XLE(:)    = 0.
END IF
!
IF (tvg%CPHOTO=='AGS' .OR. tvg%CPHOTO=='AST') THEN
  grm%TGR%CUR%XBIOMASS(:,:)      = 0.
  grm%TGR%CUR%XRESP_BIOMASS(:,:) = 0.
ELSEIF (tvg%CPHOTO=='LAI' .OR. tvg%CPHOTO=='LST') THEN
  grm%TGR%CUR%XBIOMASS(:,1)      = grm%TGRP%XBSLAI(:) * grm%TGRPE%CUR%XLAI(:)
  grm%TGR%CUR%XRESP_BIOMASS(:,:) = 0.
ELSEIF (tvg%CPHOTO=='NIT') THEN
  grm%TGR%CUR%XBIOMASS(:,:) = 0.
  DO jnbiomass=1,tvg%NNBIOMASS
    WRITE(ylvl,'(I1)') jnbiomass
    yrecfm=hpatch//'GR_BIOMA'//adjustl(ylvl(:len_trim(ylvl)))
    yrecfm=adjustl(yrecfm)
    CALL read_surf(&
                 hprogram,yrecfm,grm%TGR%CUR%XBIOMASS(:,jnbiomass),iresp)
  END DO

  grm%TGR%CUR%XRESP_BIOMASS(:,:) = 0.
  DO jnbiomass=2,tvg%NNBIOMASS
    WRITE(ylvl,'(I1)') jnbiomass
    yrecfm=hpatch//'GR_RESPI'//adjustl(ylvl(:len_trim(ylvl)))
    yrecfm=adjustl(yrecfm)
    CALL read_surf(&
                 hprogram,yrecfm,grm%TGR%CUR%XRESP_BIOMASS(:,jnbiomass),iresp)
  END DO
ENDIF
!
!
DEALLOCATE(zwork)
IF (lhook) CALL dr_hook('READ_TEB_GREENROOF_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_teb_greenroof_n