read_nam_grid_lonlat_reg.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ################################################################
      SUBROUTINE read_nam_grid_lonlat_reg(HPROGRAM,KGRID_PAR,KL,PGRID_PAR)
!     ################################################################
!
!!****  *READ_NAM_GRID_LONLAT_REG* - routine to read in namelist the horizontal grid
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE mode_pos_surf
!
USE modi_open_namelist
USE modi_close_namelist
USE modi_get_luout
!
USE mode_gridtype_lonlat_reg
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
 CHARACTER(LEN=6),           INTENT(IN)    :: hprogram   ! calling program
INTEGER,                    INTENT(INOUT) :: kgrid_par  ! size of PGRID_PAR
INTEGER,                    INTENT(OUT)   :: kl         ! number of points
REAL, DIMENSION(KGRID_PAR), INTENT(OUT)   :: pgrid_par  ! parameters defining this grid
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER :: iluout ! output listing logical unit
INTEGER :: ilunam ! namelist file  logical unit
!
REAL, DIMENSION(:), ALLOCATABLE :: zlat ! latitude  of all points
REAL, DIMENSION(:), ALLOCATABLE :: zlon ! longitude of all points
!
REAL,    DIMENSION(:), POINTER     :: zgrid_par
!
LOGICAL :: gfound
!
!
!*       0.3   Declarations of namelist
!              ------------------------
!
REAL    :: xlonmin  ! minimum longitude (degrees)
REAL    :: xlonmax  ! maximum longitude (degrees)
REAL    :: xlatmin  ! minimum latitude  (degrees)
REAL    :: xlatmax  ! maximum latitude  (degrees)
INTEGER :: nlon     ! number of points in longitude
INTEGER :: nlat     ! number of points in latitude
REAL(KIND=JPRB) :: zhook_handle
namelist/nam_lonlat_reg/xlonmin, xlonmax, xlatmin, xlatmax, nlon, nlat
!
!------------------------------------------------------------------------------
!
!*       1.    opening of namelist
! 
IF (lhook) CALL dr_hook('READ_NAM_GRID_LONLAT_REG',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
 CALL open_namelist(hprogram,ilunam)
!
!---------------------------------------------------------------------------
!
!*       2.    Reading of projection parameters
!              --------------------------------
!
 CALL posnam(ilunam,'NAM_LONLAT_REG',gfound,iluout)
IF (gfound) READ(unit=ilunam,nml=nam_lonlat_reg)
!
!---------------------------------------------------------------------------
!
!*       3.    Number of points
!              ----------------
!
kl = nlon * nlat
!
!---------------------------------------------------------------------------
 CALL close_namelist(hprogram,ilunam)
!---------------------------------------------------------------------------
!
!*       4.    All this information stored into pointer PGRID_PAR
!              --------------------------------------------------
!
ALLOCATE(zlat(kl))
ALLOCATE(zlon(kl))
!
 CALL latlon_lonlat_reg(xlonmin,xlonmax,xlatmin,xlatmax,&
                         nlon,nlat,zlon,zlat             )  
!
 CALL put_gridtype_lonlat_reg(zgrid_par,xlonmin,xlonmax,xlatmin,xlatmax, &
                               nlon,nlat,kl,zlon,zlat                     )  
!
DEALLOCATE(zlat)
DEALLOCATE(zlon)
!
!---------------------------------------------------------------------------
!
!* 1st call : initializes dimension
!
IF (kgrid_par==0) THEN
  kgrid_par = SIZE(zgrid_par)
!
ELSE
!
!* 2nd call : initializes grid array
!
  pgrid_par(:) = 0.
  pgrid_par(:) = zgrid_par
END IF
!
DEALLOCATE(zgrid_par)
IF (lhook) CALL dr_hook('READ_NAM_GRID_LONLAT_REG',1,zhook_handle)
!
!---------------------------------------------------------------------------
!
END SUBROUTINE read_nam_grid_lonlat_reg