mode_gridtype_lonlat_reg.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ##############################
      MODULE mode_gridtype_lonlat_reg
!     ##############################
!
!############################################################################
!############################################################################
!############################################################################
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
 CONTAINS
!############################################################################
!############################################################################
!############################################################################
!     ####################################################################
      SUBROUTINE put_gridtype_lonlat_reg(PGRID_PAR,PLONMIN,PLONMAX,             &
                                           platmin,platmax,klon,klat,kl,plon,plat )  
!     ####################################################################
!
!!****  *PUT_GRIDTYPE_LONLAT_REG* - routine to store in PGRID_PAR the horizontal grid
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
IMPLICIT NONE
!
!
!*       0.1   Declarations of arguments
!              -------------------------
!
REAL,               INTENT(IN)  :: plonmin  ! minimum longitude
REAL,               INTENT(IN)  :: plonmax  ! maximum longitude
REAL,               INTENT(IN)  :: platmin  ! minimum latitude
REAL,               INTENT(IN)  :: platmax  ! maximum latitude
INTEGER,            INTENT(IN)  :: klon     ! number of points in longitude
INTEGER,            INTENT(IN)  :: klat     ! number of points in latitude
INTEGER,            INTENT(IN)  :: kl       ! number of points used
REAL, DIMENSION(:), INTENT(IN)  :: plon     ! longitudes of all points
REAL, DIMENSION(:), INTENT(IN)  :: plat     ! latitudes  of all points
REAL,   DIMENSION(:),POINTER    :: pgrid_par! parameters defining this grid
REAL(KIND=JPRB) :: zhook_handle
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('MODE_GRIDTYPE_LONLAT_REG:PUT_GRIDTYPE_LONLAT_REG',0,zhook_handle)
ALLOCATE(pgrid_par(7+2*kl))
pgrid_par(1) = plonmin
pgrid_par(2) = plonmax
pgrid_par(3) = platmin
pgrid_par(4) = platmax
pgrid_par(5) = float(klon)
pgrid_par(6) = float(klat)
pgrid_par(7) = float(kl)
pgrid_par(8:7+kl)      = plon(:)
pgrid_par(8+kl:7+2*kl) = plat(:)
IF (lhook) CALL dr_hook('MODE_GRIDTYPE_LONLAT_REG:PUT_GRIDTYPE_LONLAT_REG',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE put_gridtype_lonlat_reg
!############################################################################
!############################################################################
!############################################################################
!     ####################################################################
      SUBROUTINE get_gridtype_lonlat_reg(PGRID_PAR,PLONMIN,PLONMAX, &
                                           platmin,platmax,klon,klat, &
                                           kl,plon,plat               )  
!     ####################################################################
!
!!****  *GET_GRIDTYPE_LONLAT_REG* - routine to get from PGRID_PAR the horizontal grid
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
IMPLICIT NONE
!
!
!*       0.1   Declarations of arguments
!              -------------------------
!
REAL, DIMENSION(:), INTENT(IN)            :: pgrid_par! parameters defining this grid
REAL,               INTENT(OUT), OPTIONAL :: plonmin  ! minimum longitude
REAL,               INTENT(OUT), OPTIONAL :: plonmax  ! maximum longitude
REAL,               INTENT(OUT), OPTIONAL :: platmin  ! minimum latitude
REAL,               INTENT(OUT), OPTIONAL :: platmax  ! maximum latitude
INTEGER,            INTENT(OUT), OPTIONAL :: klon     ! number of points in longitude
INTEGER,            INTENT(OUT), OPTIONAL :: klat     ! number of points in latitude
INTEGER,            INTENT(OUT), OPTIONAL :: kl       ! number of points used
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: plon     ! longitudes of all points
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: plat     ! latitudes  of all points
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER :: ilon, ilat
INTEGER :: il
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('MODE_GRIDTYPE_LONLAT_REG:GET_GRIDTYPE_LONLAT_REG',0,zhook_handle)
ilon = nint(pgrid_par(5))
ilat = nint(pgrid_par(6))
il   = nint(pgrid_par(7))
!
IF (present(plonmin))  plonmin = pgrid_par(1)
IF (present(plonmax))  plonmax = pgrid_par(2)
IF (present(platmin))  platmin = pgrid_par(3)
IF (present(platmax))  platmax = pgrid_par(4)
IF (present(klon    )) klon    = ilon
IF (present(klat    )) klat    = ilat
IF (present(kl      )) kl      = il
IF (present(plon    )) plon(:) = pgrid_par(8:7+il)
IF (present(plat    )) plat(:) = pgrid_par(8+il:7+2*il)
IF (lhook) CALL dr_hook('MODE_GRIDTYPE_LONLAT_REG:GET_GRIDTYPE_LONLAT_REG',1,zhook_handle)
!
!-------------------------------------------------------------------------------
END SUBROUTINE get_gridtype_lonlat_reg
!---------------------------------------------------------------------------------
!
!      ###################################################
       SUBROUTINE latlon_lonlat_reg(PLONMIN,PLONMAX,PLATMIN,PLATMAX,&
                                      klon,klat,plon,plat             )  
!      ###################################################
!
!!****  *LATLON_LONLAT_REG * - Routine to compute geographical coordinates
!!
!!     PURPOSE
!!     -------
!!       
!!     AUTHOR
!!     ------
!!      V. Masson  *Meteo-France*
!!
!!     MODIFICATION
!!     ------------
!!       Original   03/2004
!-------------------------------------------------------------------------------
!
!*     0.     DECLARATIONS
!             ------------
!
IMPLICIT NONE
!
!*     0.1    Declarations of arguments and results
!
REAL,               INTENT(IN)  :: plonmin  ! minimum longitude
REAL,               INTENT(IN)  :: plonmax  ! maximum longitude
REAL,               INTENT(IN)  :: platmin  ! minimum latitude
REAL,               INTENT(IN)  :: platmax  ! maximum latitude
INTEGER,            INTENT(IN)  :: klon     ! number of points in longitude
INTEGER,            INTENT(IN)  :: klat     ! number of points in latitude
REAL, DIMENSION(:), INTENT(OUT) :: plon,plat    
                                            ! returned geographic latitudes and 
                                            ! longitudes of the processed points 
                                            ! (degrees).
!
!*     0.2    Declarations of local variables
! 
INTEGER :: jlon, jlat
INTEGER :: jl
INTEGER :: jc
REAL(KIND=JPRB) :: zhook_handle
!--------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('MODE_GRIDTYPE_LONLAT_REG:LATLON_LONLAT_REG',0,zhook_handle)
jl = 0
!
DO jlat=1,klat
  DO jlon=1,klon
    jc = jlon + (jlat-1) * klon 
    jl = jl + 1
    plon(jl) = plonmin + (plonmax-plonmin) * (float(jlon)-0.5) / float(klon)
    plat(jl) = platmin + (platmax-platmin) * (float(jlat)-0.5) / float(klat)
  END DO
END DO
IF (lhook) CALL dr_hook('MODE_GRIDTYPE_LONLAT_REG:LATLON_LONLAT_REG',1,zhook_handle)
!---------------------------------------------------------------------------------
END SUBROUTINE latlon_lonlat_reg
!---------------------------------------------------------------------------------
!
!############################################################################
!############################################################################
!############################################################################
!############################################################################
!############################################################################
!############################################################################
!
END MODULE mode_gridtype_lonlat_reg