read_gridtype_lonlat_reg.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ################################################################
      SUBROUTINE read_gridtype_lonlat_reg (&
                                           hprogram,kgrid_par,klu,oread,ksize,pgrid_par,kresp,hdir)
!     ################################################################
!
!!****  *READ_GRIDTYPE_LONLAT_REG* - routine to initialise the horizontal grid
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
USE modi_read_surf
USE modi_get_luout
!
USE mode_gridtype_lonlat_reg
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
!
 CHARACTER(LEN=6),       INTENT(IN)    :: hprogram   ! calling program
INTEGER,                INTENT(INOUT) :: kgrid_par  ! real size of PGRID_PAR
INTEGER,                INTENT(IN)    :: klu        ! number of points
LOGICAL,                INTENT(IN)    :: oread      ! flag to read the grid
INTEGER,                INTENT(IN)    :: ksize      ! estimated size of PGRID_PAR
REAL, DIMENSION(KSIZE), INTENT(OUT)   :: pgrid_par  ! parameters defining this grid
INTEGER,                INTENT(OUT)   :: kresp      ! error return code
 CHARACTER(LEN=1),       INTENT(IN)    :: hdir       ! reading directive
!                                                   ! 'A' : all field
!                                                   ! 'H' : field on this processor only
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL    :: zlonmin ! minimum longitude (degrees)
REAL    :: zlonmax ! maximum longitude (degrees)
REAL    :: zlatmin ! minimum latitude  (degrees)
REAL    :: zlatmax ! maximum latitude  (degrees)
INTEGER :: ilon    ! number of points in longitude
INTEGER :: ilat    ! number of points in latitude
REAL, DIMENSION(KLU) :: zlon ! longitudes
REAL, DIMENSION(KLU) :: zlat ! latitudes
!
INTEGER :: iluout
!---------------------------------------------------------------------------
REAL, DIMENSION(:),   POINTER     :: zgrid_par=>null()
!$OMP THREADPRIVATE(ZGRID_PAR)
REAL(KIND=JPRB) :: zhook_handle
!---------------------------------------------------------------------------
!
!*       1.    Reading of the grid
!              -------------------
!
IF (lhook) CALL dr_hook('READ_GRIDTYPE_LONLAT_REG',0,zhook_handle)
 CALL read_surf(&
                hprogram,'LONMIN',zlonmin,kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'LONMAX',zlonmax,kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'LATMIN',zlatmin,kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'LATMAX',zlatmax,kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'NLON',ilon,kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'NLAT',ilat,kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'REG_LON',zlon,kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'REG_LAT',zlat,kresp,hdir=hdir)
!
!---------------------------------------------------------------------------
!
!*       2.    All this information stored into pointer PGRID_PAR
!              --------------------------------------------------
!
 CALL put_gridtype_lonlat_reg(zgrid_par,zlonmin,zlonmax,               &
                               zlatmin,zlatmax,ilon,ilat,klu,zlon,zlat  )  
!
!---------------------------------------------------------------------------
IF (oread) THEN
  IF (SIZE(pgrid_par) /= SIZE(zgrid_par)) THEN
    CALL get_luout(hprogram,iluout)
    WRITE(iluout,*)'size of PGRID_PAR =', SIZE(pgrid_par)
    WRITE(iluout,*)'size of ZGRID_PAR =', SIZE(zgrid_par)
    CALL abor1_sfx('READ_GRIDTYPE_LONLAT_REG: SIZE OF PGRID_PAR IS NOT CORRECT')
  END IF
  !
  pgrid_par = zgrid_par
ELSE
  kgrid_par = SIZE(zgrid_par)
END IF
!
DEALLOCATE(zgrid_par)
IF (lhook) CALL dr_hook('READ_GRIDTYPE_LONLAT_REG',1,zhook_handle)
!---------------------------------------------------------------------------
!
END SUBROUTINE read_gridtype_lonlat_reg