read_covern.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_cover_n (DTCO, U, &
                               hprogram)
!     ################################
!
!!****  *READ_COVER_n* - routine to read a file for
!!                         physiographic data file of model _n 
!!
!!    PURPOSE
!!    -------
!!       The purpose of this routine is to initialise the 
!!       physiographic data file.
!!
!!
!!**  METHOD
!!    ------
!!      The data are read in the initial surface file :
!!        - 2D physiographic data fields
!!          
!!      It does not read the grid definition. This should have been
!!      read already.
!!
!!    EXTERNAL
!!    --------
!!      
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_assim, ONLY : lassim, lread_all
!
USE modd_data_cover_par, ONLY : nbare_soil, jpcover
!
USE mode_read_surf_cov, ONLY : read_surf_cov
!
USE modi_read_lcover
USE modi_read_surf
USE modi_convert_cover_frac
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
 CHARACTER(LEN=6),  INTENT(IN)  :: hprogram ! calling program
!
!*       0.2   Declarations of local variables
!              -------------------------------
!

INTEGER           :: iresp          ! Error code after redding
! 
INTEGER           :: iversion       ! surface version
!
LOGICAL :: gread_all
!
 CHARACTER(LEN=12) :: yrecfm         ! Name of the article to be read
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
!
!*       2.     Physiographic data fields:
!               -------------------------
!
!*       2.1    Cover classes :
!               -------------
!
IF (lhook) CALL dr_hook('READ_COVER_N',0,zhook_handle)
!
IF (lassim) THEN
  gread_all = lread_all
  lread_all = .true.
ENDIF
!
yrecfm='VERSION'
 CALL read_surf(&
                hprogram,yrecfm,iversion,iresp)
!
ALLOCATE(u%LCOVER(jpcover))
 CALL read_lcover(&
                  hprogram,u%LCOVER)
!
!
ALLOCATE(u%XCOVER(u%NSIZE_FULL,count(u%LCOVER)))
 CALL read_surf_cov(&
                    hprogram,'COVER',u%XCOVER(:,:),u%LCOVER,iresp)
!
!*       2.1    Fractions :
!               ---------
!
ALLOCATE(u%XSEA   (u%NSIZE_FULL))
ALLOCATE(u%XNATURE(u%NSIZE_FULL))
ALLOCATE(u%XWATER (u%NSIZE_FULL))
ALLOCATE(u%XTOWN  (u%NSIZE_FULL))
!
IF (iversion>=7) THEN
  !
  CALL read_surf(&
                hprogram,'FRAC_SEA   ',u%XSEA,   iresp)
  CALL read_surf(&
                hprogram,'FRAC_NATURE',u%XNATURE,iresp)
  CALL read_surf(&
                hprogram,'FRAC_WATER ',u%XWATER, iresp)
  CALL read_surf(&
                hprogram,'FRAC_TOWN  ',u%XTOWN,  iresp)
  !
ELSE
  CALL convert_cover_frac(dtco, &
                          u%XCOVER,u%LCOVER,u%XSEA,u%XNATURE,u%XTOWN,u%XWATER)
ENDIF
!
!*       2.2    Orography :
!               ---------
!
!
ALLOCATE(u%XZS(u%NSIZE_FULL))
yrecfm='ZS'
 CALL read_surf(&
                hprogram,yrecfm,u%XZS(:),iresp)
!
IF (lassim) lread_all = gread_all
!
IF (lhook) CALL dr_hook('READ_COVER_N',1,zhook_handle)
!
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_cover_n