prep_seaflux.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_seaflux (DTCO, UG, U, SM, &
                         hprogram,hatmfile,hatmfiletype,hpgdfile,hpgdfiletype)
!     #################################################################################
!
!!****  *PREP_SEAFLUX* - prepares variables for SEAFLUX scheme
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     S. Malardel 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      S. Riette   06/2009 PREP_SEAFLUX_SBL has no more argument
!!      Modified    07/2012, P. Le Moigne : CMO1D phasing
!!      Modified    01/2014, S. Senesi : introduce sea-ice model 
!!      Modified    01/2015, R. Séférian : introduce ocean surface albedo 
!!------------------------------------------------------------------
!
!
USE modd_surfex_n, ONLY : seaflux_model_t
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modi_prep_hor_seaflux_field
USE modi_prep_ver_seaflux
USE modi_prep_output_grid
USE modi_prep_seaflux_sbl
USE modi_prep_seaice
USE modi_get_luout
!
USE modn_prep_seaflux
USE modd_read_namelist,  ONLY : lnam_read
USE modd_prep,           ONLY : xzs_ls
USE modd_surf_atm,       ONLY : lvertshift
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_clean_prep_output_grid
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(seaflux_model_t), INTENT(INOUT) :: sm
!
 CHARACTER(LEN=6),   INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=28),  INTENT(IN)  :: hatmfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hatmfiletype! type of the Atmospheric file
 CHARACTER(LEN=28),  INTENT(IN)  :: hpgdfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hpgdfiletype! type of the Atmospheric file
!
!*      0.2    declarations of local variables
!
INTEGER :: jmth,inmth
INTEGER :: iluout
LOGICAL :: gfound         ! Return code when searching namelist
INTEGER :: ilunam         ! logical unit of namelist file
REAL(KIND=JPRB) :: zhook_handle

!-------------------------------------------------------------------------------------
!
!*      0.     Default of configuration
!
!
IF (lhook) CALL dr_hook('PREP_SEAFLUX',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
 CALL prep_output_grid(ug, u, &
                       iluout,sm%SG%CGRID,sm%SG%XGRID_PAR,sm%SG%XLAT,sm%SG%XLON)
!
!-------------------------------------------------------------------------------------
!
!*      1.     Read namelist
!
sm%S%LSBL = lsea_sbl
sm%O%LMERCATOR = locean_mercator
sm%O%LCURRENT  = locean_current
! Relaxation-forcing parameters
sm%OR%XTAU_REL   = xtime_rel
sm%OR%XQCORR     = xcorflx
!
sm%OR%LREL_CUR   = lcur_rel
sm%OR%LREL_TS    = lts_rel
sm%OR%LFLUX_NULL = lzero_flux
sm%OR%LFLX_CORR  = lcorr_flux
sm%OR%LDIAPYCNAL = ldiapyc
!
!-------------------------------------------------------------------------------------
!
!*      2.     Reading and horizontal interpolations
!
!
!*      2.0    Large scale orography
!
 CALL prep_hor_seaflux_field(dtco, ug, u, &
                            sm%DTS, sm%O, sm%OR, sm%SG, sm%S, &
                            hprogram,'ZS     ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype)
!
!*      2.1.1    Temperature
!
 CALL prep_hor_seaflux_field(dtco, ug, u, &
                            sm%DTS, sm%O, sm%OR, sm%SG, sm%S, &
                            hprogram,'SST    ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype)
!
!*      2.1.2    Salinity
!

 CALL prep_hor_seaflux_field(dtco, ug, u, &
                            sm%DTS, sm%O, sm%OR, sm%SG, sm%S, &
                            hprogram,'SSS    ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype)
!
!*      2.1.3   Sea-ice
!
IF (cseaice_scheme /= 'NONE  ') THEN 
   CALL prep_seaice(ug, &
                    dtco, sm%DTS, sm%O, sm%OR, sm%SG, sm%S, u, &
                    hprogram,hatmfile,hatmfiletype,hpgdfile,hpgdfiletype)
ENDIF
!
!
!*      2.2    Roughness
!
ALLOCATE(sm%S%XZ0(SIZE(sm%S%XSST)))
sm%S%XZ0 = 0.001
!
ALLOCATE(sm%S%XZ0H(SIZE(sm%S%XSST)))
sm%S%XZ0H = sm%S%XZ0
!
!*      2.3   Ocean Surface Albedo
!
IF(sm%S%CSEA_ALB=='RS14')THEN
  ALLOCATE(sm%S%XDIR_ALB(SIZE(sm%S%XSST)))
  ALLOCATE(sm%S%XSCA_ALB(SIZE(sm%S%XSST)))
  sm%S%XDIR_ALB = 0.065
  sm%S%XSCA_ALB = 0.065
ENDIF
!
!-------------------------------------------------------------------------------------
 CALL clean_prep_output_grid
!-------------------------------------------------------------------------------------
!
!*      3.     Vertical interpolations of all variables
!
IF(lvertshift)THEN
  CALL prep_ver_seaflux(sm%S)
ENDIF
!
DEALLOCATE(xzs_ls)
!
!-------------------------------------------------------------------------------------
!
!*      4.     Preparation of optional interpolation of monthly sst
!
sm%S%LINTERPOL_SST=.false.
IF(trim(sm%S%CINTERPOL_SST)/='NONE')THEN
!
  sm%S%LINTERPOL_SST=.true.
!
! Precedent, Current, Next, and Second-next Monthly SST
  inmth=4
!
  ALLOCATE(sm%S%XSST_MTH(SIZE(sm%S%XSST),inmth))
  DO jmth=1,inmth
     sm%S%XSST_MTH(:,jmth)=sm%S%XSST(:)
  ENDDO
!
ENDIF
!
!-------------------------------------------------------------------------------------
!
!
!*      5.     Optional preparation of interpolation of monthly Sea Surface salinity
!
sm%S%LINTERPOL_SSS=.false.
IF(trim(sm%S%CINTERPOL_SSS)/='NONE')THEN
!
   sm%S%LINTERPOL_SSS=.true.
   !
   ! Precedent, Current, Next, and Second-next Monthly SSS
   inmth=4
   !
   ALLOCATE(sm%S%XSSS_MTH(SIZE(sm%S%XSSS),inmth))
   DO jmth=1,inmth
      sm%S%XSSS_MTH(:,jmth)=sm%S%XSSS(:)
   ENDDO
   !
ENDIF
!
!-------------------------------------------------------------------------------------
!
!*      6.     Preparation of SBL air variables
!
!
IF (sm%S%LSBL) CALL prep_seaflux_sbl(sm%SG, sm%SSB)
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('PREP_SEAFLUX',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_seaflux