prep_isba_netcdf.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_isba_netcdf (DTCO, U, &
                             hprogram,hsurf,hfile,kluout,pfield)
!     #################################################################################
!
!!****  *PREP_ISBA_NETCDF* - prepares ISBA fields from initialization files in NETCDF
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     M. Lafaysse
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    04/2012
!!      J.Escobar   11/2013  Add USE MODI_GET_TYPE_DIM_n
!!------------------------------------------------------------------
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_prep,           ONLY : cinterp_type
!
USE modi_abor1_sfx
USE modi_get_type_dim_n
!
USE mode_read_cdf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE

include 'netcdf.inc'
!
!*      0.1    declarations of arguments
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
 CHARACTER(LEN=6),   INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=7),   INTENT(IN)  :: hsurf     ! type of field
 CHARACTER(LEN=28),  INTENT(IN)  :: hfile     ! name of file
INTEGER,            INTENT(IN)  :: kluout    ! logical unit of output listing
REAL,DIMENSION(:,:,:), POINTER    :: pfield    ! field to interpolate horizontally
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(:),       POINTER :: zfield   ! field read

REAL,DIMENSION(:,:),ALLOCATABLE:: zfield_2d

! CHARACTER(LEN=28) :: YNCVAR
REAL(KIND=JPRB) :: zhook_handle
!
INTEGER::ierror !error status
INTEGER::jj,jk,jloop ! loop counters
INTEGER::inlayers ! vertical dimension length
INTEGER::il ! nature dimension length
INTEGER::id_file,id_var ! Netcdf IDs for file and variable
INTEGER::invardims !number of dimensions of netcdf input variable
INTEGER,DIMENSION(:),ALLOCATABLE::ivardimsid
INTEGER::ilendim,ilendim1,ilendim2

SELECT CASE (trim(hsurf))
  CASE ('TG','WG','WGI')
    inlayers=3 ! 3 soil layers for initialization
  CASE default
    CALL abor1_sfx('PREP_ISBA_NETCDF: '//trim(hsurf)//" initialization not implemented !")
END SELECT
!
inlayers=3
!
!------------------------------------------------------------------------------------
!              ---------
IF (lhook) CALL dr_hook('PREP_ISBA_NETCDF',0,zhook_handle)

!*      1.    get nature dimension
!
 CALL get_type_dim_n(dtco, u, &
                     'NATURE',il)
!
!*      2.     Reading of field
!              ----------------

! Open netcdf file
ierror=nf_open(hfile,nf_nowrite,id_file)
 CALL handle_err_cdf(ierror,"can't open file "//trim(hfile))

! Look for variable ID
ierror=nf_inq_varid(id_file,trim(hsurf),id_var)
 CALL handle_err_cdf(ierror,"can't find variable "//trim(hsurf))

! Number of dimensions
ierror=nf_inq_varndims(id_file,id_var,invardims)
if (ierror/=nf_noerr) CALL handle_err_cdf(ierror,"can't get variable dimensions number")

! Id of dimensions
ALLOCATE(ivardimsid(invardims))
ierror=nf_inq_vardimid(id_file,id_var,ivardimsid)
if (ierror/=nf_noerr) CALL handle_err_cdf(ierror,"can't get variable dimensions ids")

ALLOCATE(zfield(il))

SELECT CASE (invardims)
  CASE (1)
    ! Check dimension length
    ierror=nf_inq_dimlen(id_file,ivardimsid(1),ilendim)
    if (ierror/=nf_noerr) CALL handle_err_cdf(ierror,"can't get variable dimensions lengths")
  CASE (2)
    ierror=nf_inq_dimlen(id_file,ivardimsid(1),ilendim1)
    if (ierror/=nf_noerr) CALL handle_err_cdf(ierror,"can't get variable dimensions lengths")
    ierror=nf_inq_dimlen(id_file,ivardimsid(2),ilendim2)
    if (ierror/=nf_noerr) CALL handle_err_cdf(ierror,"can't get variable dimensions lengths")

    ilendim=ilendim1*ilendim2

  CASE default
    CALL abor1_sfx('PREP_ISBA_NETCDF: incorrect number of dimensions for variable '//trim(hsurf))

END SELECT
!
IF(ilendim/=il) CALL abor1_sfx('PREP_ISBA_NETCDF: incorrect number of points '// &
                                'in netcdf file for variable '//trim(hsurf))
!
! Read 1D variable
ierror=nf_get_var_double(id_file,id_var,zfield)
 CALL handle_err_cdf(ierror,"can't read variable "//trim(hsurf))
!
! Close netcdf file
ierror=nf_close(id_file)
!
ALLOCATE(pfield(il,inlayers,1)) !will be deallocated later by prep_hor_isba_field
!
! For now initial values are identical for all tiles / soil layers.
DO jj=1,inlayers
  pfield(:,jj,1)=zfield
END DO
!
DEALLOCATE(zfield)
!
!Interpolation method
 cinterp_type='NONE'
!
IF (lhook) CALL dr_hook('PREP_ISBA_NETCDF',1,zhook_handle)
!-------------------------------------------------------------------------------------
END SUBROUTINE prep_isba_netcdf