pgd_teb_greenroof_par.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE pgd_teb_greenroof_par (DTCO, DTGR, UG, U, USS, TGRO, TG, &
                                        hprogram)
!     ##############################################################
!
!!**** *PGD_TEB_GREENROOF_PAR* monitor for averaging and interpolations of cover fractions
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    A. Lemonsu       Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original                     09/2009
!!    A. Lemonsu / C. de Munck     04/2011    : TEB GreenRoof
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_data_teb_greenroof_n, ONLY : data_teb_greenroof_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
USE modd_teb_greenroof_option_n, ONLY : teb_greenroof_options_t
USE modd_teb_grid_n, ONLY : teb_grid_t
!
USE modd_data_cover_par,       ONLY : nvegtype
USE modd_surf_par,             ONLY : xundef
USE modd_teb_veg,              ONLY : nlayer_gr_max, ntime_gr_max
!
USE modd_pgdwork,              ONLY : catype
!
USE modi_read_nam_pgd_teb_greenroof
USE modi_pgd_field
USE modi_test_nam_var_surf
!
USE mode_pos_surf
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(data_teb_greenroof_t), INTENT(INOUT) :: dtgr
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
TYPE(teb_greenroof_options_t), INTENT(INOUT) :: tgro
TYPE(teb_grid_t), INTENT(INOUT) :: tg
!
 CHARACTER(LEN=6),    INTENT(IN)             :: hprogram     ! Type of program
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER                                     :: iluout    ! output listing logical unit
INTEGER                                     :: ilunam    ! namelist file  logical unit
LOGICAL                                     :: gfound    ! true if namelist is found
!
INTEGER                                     :: jlayer    ! loop counter on layers
INTEGER                                     :: jlayer_gr ! loop counter on green roof layers
INTEGER                                     :: jtime     ! loop counter on time
INTEGER                                     :: jpatch    ! loop counter on patch
INTEGER                                     :: jvegtype  ! loop counter on vegtypes
!
!
INTEGER, PARAMETER                          :: jpground_max   = 20
INTEGER, PARAMETER                          :: jpvegtype_max  = 12
!
! declaration of namelist variables
INTEGER                                     :: ilayer_gr      ! number of green roof physical layers
INTEGER                                     :: itime_gr       ! ntime for green roof parameters
 CHARACTER(LEN=5)                            :: ytyp_gr        ! type of green roof
!
! uniform value
!
REAL,DIMENSION(NLAYER_GR_MAX)              :: zunif_om_gr      ! fraction of organic matter (OM) in green roof layer
REAL,DIMENSION(NLAYER_GR_MAX)              :: zunif_clay_gr    ! fraction of clay for the non-OM part of the green roof layer
REAL,DIMENSION(NLAYER_GR_MAX)              :: zunif_sand_gr    ! fraction of sand for the non-OM part of the green roof layer
REAL,DIMENSION(NTIME_GR_MAX)               :: zunif_lai_gr     ! LAI of green roof vegetation
!
! name of files containing data
!
 CHARACTER(LEN=28),DIMENSION(NLAYER_GR_MAX) :: yfnam_om_gr      ! fraction of organic matter (OM) in green roof layer
 CHARACTER(LEN=28),DIMENSION(NLAYER_GR_MAX) :: yfnam_clay_gr    ! fraction of clay for the non-OM part of the green roof layer
 CHARACTER(LEN=28),DIMENSION(NLAYER_GR_MAX) :: yfnam_sand_gr    ! fraction of sand for the non-OM part of the green roof layer
 CHARACTER(LEN=28),DIMENSION(NTIME_GR_MAX)  :: yfnam_lai_gr     ! LAI  of green roof
!
! type of files containing data
!
 CHARACTER(LEN=6 ),DIMENSION(NLAYER_GR_MAX) :: yftyp_om_gr      ! fraction of organic matter (OM) in green roof layer
 CHARACTER(LEN=6 ),DIMENSION(NLAYER_GR_MAX) :: yftyp_clay_gr    ! fraction of clay for the non-OM part of the green roof layer
 CHARACTER(LEN=6 ),DIMENSION(NLAYER_GR_MAX) :: yftyp_sand_gr    ! fraction of sand for the non-OM part of the green roof layer
 CHARACTER(LEN=6 ),DIMENSION(NTIME_GR_MAX)  :: yftyp_lai_gr     ! LAI  of green roof
!
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!
!*    1.      Initializations
!             ---------------
!
IF (lhook) CALL dr_hook('PGD_TEB_GREENROOF_PAR',0,zhook_handle)
!
ilayer_gr        = 0
itime_gr         = 0
ytyp_gr          = '     '           
!
zunif_om_gr      = xundef
zunif_clay_gr    = xundef
zunif_sand_gr    = xundef
zunif_lai_gr     = xundef
!
yfnam_om_gr      = '                            '
yfnam_clay_gr    = '                            '
yfnam_sand_gr    = '                            '
yfnam_lai_gr     = '                            '
!
yftyp_om_gr      = '      '
yftyp_clay_gr    = '      '
yftyp_sand_gr    = '      '
yftyp_lai_gr     = '      '
!
!-------------------------------------------------------------------------------
!
!*    2.      Input files for green roof characteristics
!             -------------------------------------------
!
 CALL read_nam_pgd_teb_greenroof(hprogram, itime_gr,ilayer_gr,ytyp_gr,                     &
                                zunif_om_gr, zunif_clay_gr, zunif_sand_gr, zunif_lai_gr,  &
                                yfnam_om_gr, yfnam_clay_gr, yfnam_sand_gr, yfnam_lai_gr,  &
                                yftyp_om_gr, yftyp_clay_gr, yftyp_sand_gr, yftyp_lai_gr)
!
tgro%NTIME_GR           = itime_gr
tgro%NLAYER_GR          = ilayer_gr
tgro%CTYP_GR            = ytyp_gr
!
!*           Coherence of options for the green roof type
!             -------------------------------------------
!
 CALL test_nam_var_surf(iluout,'CTYP_GR',tgro%CTYP_GR,'GRASS','SEDUM')
!
!
ALLOCATE(dtgr%XPAR_OM_GR       (tg%NDIM,tgro%NLAYER_GR))
ALLOCATE(dtgr%XPAR_CLAY_GR     (tg%NDIM,tgro%NLAYER_GR))
ALLOCATE(dtgr%XPAR_SAND_GR     (tg%NDIM,tgro%NLAYER_GR))
ALLOCATE(dtgr%XPAR_LAI_GR      (tg%NDIM,tgro%NTIME_GR ))
!
!-------------------------------------------------------------------------------
!
!*    3.2      Uniform fields are prescribed
!             -----------------------------
!
 catype = 'ARI'
!
!
DO jlayer_gr=1,tgro%NLAYER_GR
 CALL pgd_field(dtco, ug, u, uss, &
                hprogram,'OM_GR: fraction of OM in GR layer','BLD',yfnam_om_gr(jlayer_gr),   &
               yftyp_om_gr(jlayer_gr), zunif_om_gr(jlayer_gr), dtgr%XPAR_OM_GR(:,jlayer_gr))
ENDDO
!
DO jlayer_gr=1,tgro%NLAYER_GR
 CALL pgd_field(dtco, ug, u, uss, &
                hprogram,'CLAY_GR: fraction of CLAY in the non-OM part of GR layer','BLD',yfnam_clay_gr(jlayer_gr),   &
               yftyp_clay_gr(jlayer_gr), zunif_clay_gr(jlayer_gr), dtgr%XPAR_CLAY_GR(:,jlayer_gr))
ENDDO
!
DO jlayer_gr=1,tgro%NLAYER_GR
 CALL pgd_field(dtco, ug, u, uss, &
                hprogram,'SAND_GR: fraction of SAND in the non-OM part of GR layer','BLD',yfnam_sand_gr(jlayer_gr),   &
               yftyp_sand_gr(jlayer_gr), zunif_sand_gr(jlayer_gr), dtgr%XPAR_SAND_GR(:,jlayer_gr))
ENDDO
!
DO jtime=1,tgro%NTIME_GR
 CALL pgd_field(dtco, ug, u, uss, &
                hprogram,'LAI_GR: LAI of green roof','BLD',yfnam_lai_gr(jtime),  &
                yftyp_lai_gr(jtime),zunif_lai_gr(jtime),dtgr%XPAR_LAI_GR(:,jtime))
!
ENDDO
!
!
IF (lhook) CALL dr_hook('PGD_TEB_GREENROOF_PAR',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE pgd_teb_greenroof_par