pgd_teb.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE pgd_teb (DTCO, DGU, UG, U, USS, DTI, TM, GDM, GRM, &
                          hprogram,oecoclimap,ogarden)
!     ##############################################################
!
!!**** *PGD_TEB* monitor for averaging and interpolations of TEB physiographic fields
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    10/12/97
!!    A. Lemonsu      05/2009         Key for garden option
!!    G. Pigeon     /09/12: WALL, ROOF, FLOOR, MASS LAYER default to 5
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_diag_surf_atm_n, ONLY : diag_surf_atm_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
USE modd_data_isba_n, ONLY : data_isba_t
!
USE modd_surfex_n, ONLY : teb_model_t
USE modd_surfex_n, ONLY : teb_garden_model_t
USE modd_surfex_n, ONLY : teb_greenroof_model_t
!
USE modd_data_cover_par, ONLY : jpcover
!
USE modi_get_surf_size_n
USE modi_pack_pgd
USE modi_pgd_teb_par
USE modi_pgd_teb_veg
USE modi_get_luout
USE modi_read_nam_pgd_teb
USE modi_test_nam_var_surf
USE modi_pgd_bem_par
USE modi_abor1_sfx
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_write_cover_tex_teb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(diag_surf_atm_t), INTENT(INOUT) :: dgu
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
TYPE(data_isba_t), INTENT(INOUT) :: dti
TYPE(teb_model_t), INTENT(INOUT) :: tm
TYPE(teb_garden_model_t), INTENT(INOUT) :: gdm
TYPE(teb_greenroof_model_t), INTENT(INOUT) :: grm
!
 CHARACTER(LEN=6), INTENT(IN)  :: hprogram   ! Type of program
LOGICAL,          INTENT(IN)  :: oecoclimap ! T if parameters are computed with ecoclimap
!                                           ! F if all parameters must be specified
LOGICAL,          INTENT(IN)  :: ogarden    ! T if urban green areas
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER         :: iluout    ! output listing logical unit
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
!*    1.      Initializations of defaults
!             ---------------------------
!
IF (lhook) CALL dr_hook('PGD_TEB',0,zhook_handle)
 CALL get_luout(hprogram,iluout)

tm%TOP%NROOF_LAYER  = 5
tm%TOP%NROAD_LAYER  = 5
tm%TOP%NWALL_LAYER  = 5
tm%BOP%NFLOOR_LAYER = 5
!
!-------------------------------------------------------------------------------
!
!*    2.      Reading of namelist
!             -------------------
!
 CALL read_nam_pgd_teb(hprogram,tm%TOP%NTEB_PATCH,tm%TOP%CBEM,tm%BOP%CCOOL_COIL,&
                       tm%BOP%CHEAT_COIL,tm%BOP%LAUTOSIZE,tm%TOP%NROAD_LAYER,&
                       tm%TOP%NROOF_LAYER,tm%TOP%NWALL_LAYER,tm%BOP%NFLOOR_LAYER, &
                      tm%TOP%LGREENROOF,tm%TOP%LHYDRO,tm%TOP%LSOLAR_PANEL     )
!
!-------------------------------------------------------------------------------
!
!*    3.      Coherence of options
!             --------------------
!
 CALL test_nam_var_surf(iluout,'CBLD',tm%TOP%CBEM,'DEF','BEM ')
 CALL test_nam_var_surf(iluout,'CCOOL_COIL',tm%BOP%CCOOL_COIL,'IDEAL ','DXCOIL')
 CALL test_nam_var_surf(iluout,'CHEAT_COIL',tm%BOP%CHEAT_COIL,'IDEAL ','FINCAP')
!
IF (.NOT. ogarden) THEN
  IF (tm%TOP%LGREENROOF) CALL abor1_sfx('ERROR: You cannot activate LGREENROOF if LGARDEN is FALSE')
  IF (tm%TOP%LHYDRO    ) CALL abor1_sfx('ERROR: You cannot activate LHYDRO     if LGARDEN is FALSE')
ENDIF
!
!-------------------------------------------------------------------------------
!
!*    4.      Number of points and packing
!             ----------------------------
!
 CALL get_surf_size_n(dtco, u, &
                      'TOWN  ',tm%TG%NDIM)
!
ALLOCATE(tm%TOP%LCOVER     (jpcover))
ALLOCATE(tm%TOP%XCOVER     (tm%TG%NDIM,jpcover))
ALLOCATE(tm%TOP%XZS        (tm%TG%NDIM))
ALLOCATE(tm%TG%XLAT       (tm%TG%NDIM))
ALLOCATE(tm%TG%XLON       (tm%TG%NDIM))
ALLOCATE(tm%TG%XMESH_SIZE (tm%TG%NDIM))
!
 CALL pack_pgd(dtco, u, &
               hprogram, 'TOWN  ',                    &
                tm%TG%CGRID,  tm%TG%XGRID_PAR,      &
                tm%TOP%LCOVER, tm%TOP%XCOVER, tm%TOP%XZS,  &
                tm%TG%XLAT, tm%TG%XLON, tm%TG%XMESH_SIZE      )  
!
!-------------------------------------------------------------------------------
!
!*    5.      TEB specific fields
!             -------------------
!
tm%TOP%LECOCLIMAP = oecoclimap
 CALL pgd_teb_par(dtco, dgu, ug, u, uss, tm%BDD, tm%DTT, dti, tm%TG, &
                  hprogram,ogarden,tm%TOP%LGREENROOF,tm%TOP%CBLD_ATYPE)
!
!-------------------------------------------------------------------------------
!
!*    6.      Prints of cover parameters in a tex file
!             ----------------------------------------
!
IF (oecoclimap) CALL write_cover_tex_teb
!
!
!-------------------------------------------------------------------------------
!
!*    7.      Case of urban green areas (and hydrology)
!             -----------------------------------------
!
tm%TOP%LGARDEN       = ogarden
!
IF (tm%TOP%LGARDEN) CALL pgd_teb_veg(dtco, ug, u, uss, gdm, grm, tm%TOP, tm%TG,  &
                                  hprogram)
!
!-------------------------------------------------------------------------------
!
!*    8.      Case of Building Energy Model
!             -----------------------------
!
IF (tm%TOP%CBEM .EQ. 'BEM') CALL pgd_bem_par(dtco, dgu, ug, u, uss, tm%DTB, dti, tm%TG, &
                                          hprogram,tm%BOP%LAUTOSIZE)
!
IF (lhook) CALL dr_hook('PGD_TEB',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE pgd_teb