pgd_seaflux_par.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE pgd_seaflux_par (DTCO, DTS, SG, UG, U, USS, &
                                  hprogram,osst_data)
!     ##############################################################
!
!!**** *PGD_SEAFLUX_PAR* monitor for averaging and interpolations of sst
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    P. Le Moigne        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    09/2007
!!
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_data_seaflux_n, ONLY : data_seaflux_t
USE modd_seaflux_grid_n, ONLY : seaflux_grid_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
!
USE modd_surf_par,       ONLY : xundef, nundef
!
USE modd_pgdwork,       ONLY : catype
!
USE modd_type_date_surf
!
USE modi_get_luout
USE modi_open_namelist
USE modi_close_namelist
USE modi_pgd_field
!
USE mode_pos_surf
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(data_seaflux_t), INTENT(INOUT) :: dts
TYPE(seaflux_grid_t), INTENT(INOUT) :: sg
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
!
 CHARACTER(LEN=6),    INTENT(IN)    :: hprogram     ! Type of program
LOGICAL         ,    INTENT(OUT)   :: osst_data
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER               :: iluout    ! output listing logical unit
INTEGER               :: ilunam    ! namelist file  logical unit
LOGICAL               :: gfound    ! true if namelist is found
!
INTEGER               :: jtime     ! loop counter on time
!
!*    0.3    Declaration of namelists
!            ------------------------
!
INTEGER            :: ntime_sst
INTEGER, PARAMETER :: ntime_max    = 800
!
REAL, DIMENSION(NTIME_MAX)     :: xunif_sst        ! sea surface temperature

INTEGER, DIMENSION(NTIME_MAX)  :: nyear_sst
INTEGER, DIMENSION(NTIME_MAX)  :: nmonth_sst
INTEGER, DIMENSION(NTIME_MAX)  :: nday_sst
REAL, DIMENSION(NTIME_MAX)     :: xtime_sst
LOGICAL                        :: lsst_data
!
! name of files containing data
!
 CHARACTER(LEN=28), DIMENSION(NTIME_MAX)   :: cfnam_sst        ! sea surface temperature
 CHARACTER(LEN=6),  DIMENSION(NTIME_MAX)   :: cftyp_sst        ! sea surface temperature
REAL(KIND=JPRB) :: zhook_handle
!
namelist/nam_data_seaflux/ntime_sst, lsst_data, xunif_sst, cfnam_sst, cftyp_sst, &
                            nyear_sst, nmonth_sst, nday_sst, xtime_sst  
!-------------------------------------------------------------------------------
!
!*    1.      Initializations
!             ---------------
!
IF (lhook) CALL dr_hook('PGD_SEAFLUX_PAR',0,zhook_handle)
ntime_sst         = 12
xunif_sst(:)     = xundef ! sea surface temperature
!
 cfnam_sst(:)     = '                            '
!
 cftyp_sst(:)     = '      '
!
nyear_sst(:)    = nundef
nmonth_sst(:)    = nundef
nday_sst(:)    = nundef
xtime_sst(:)    = xundef
!
lsst_data         = .false.
!-------------------------------------------------------------------------------
!
!*    2.      Input file for cover types
!             --------------------------
!
 CALL get_luout(hprogram,iluout)
 CALL open_namelist(hprogram,ilunam)
!
 CALL posnam(ilunam,'NAM_DATA_SEAFLUX',gfound,iluout)
IF (gfound) READ(unit=ilunam,nml=nam_data_seaflux)
!
 CALL close_namelist(hprogram,ilunam)
!
osst_data         = lsst_data
IF (.NOT. lsst_data .AND. lhook) CALL dr_hook('PGD_SEAFLUX_PAR',1,zhook_handle)
IF (.NOT. lsst_data) RETURN
!
IF (ntime_sst > ntime_max) THEN
   WRITE(iluout,*)'NTIME_SST SHOULD NOT EXCEED',ntime_max
   CALL abor1_sfx('PGD_SEAFLUX_PAR: NTIME TOO BIG')
ENDIF
ALLOCATE(dts%XDATA_SST     (sg%NDIM,ntime_sst))
ALLOCATE(dts%TDATA_SST     (ntime_sst))
!
!-------------------------------------------------------------------------------
!
!*    3.      Uniform fields are prescribed
!             -----------------------------
!
 catype = 'ARI'
!
DO jtime=1,ntime_sst
  CALL pgd_field(dtco, ug, u, uss, &
                 hprogram,'SST: sea surface temperature','SEA',cfnam_sst(jtime),   &
                   cftyp_sst(jtime),xunif_sst(jtime),dts%XDATA_SST(:,jtime))  
!                 
  dts%TDATA_SST(jtime)%TDATE%YEAR  = nyear_sst(jtime)
  dts%TDATA_SST(jtime)%TDATE%MONTH = nmonth_sst(jtime)
  dts%TDATA_SST(jtime)%TDATE%DAY   = nday_sst(jtime)
  dts%TDATA_SST(jtime)%TIME        = xtime_sst(jtime)
!  
END DO
IF (lhook) CALL dr_hook('PGD_SEAFLUX_PAR',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE pgd_seaflux_par