mass_layer_e_budget.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!   ##########################################################################
    SUBROUTINE mass_layer_e_budget(PT_MASS, PTSTEP, PHC_MASS, PTC_MASS, PD_MASS, &
                                    pflx_bld_mass, pdqs_mass, pimb_mass,           &
                                    pf_mass_wall, pf_mass_win,       &
                                    pf_mass_floor, pradht_in,           &
                                    prad_wall_mass, prad_roof_mass,       &
                                    prad_win_mass, pload_mass, pti_bld,             &
                                    prad_floor_mass, pconv_mass_bld                  )
!   ##########################################################################
!
!!****  *MASS_LAYER_E_BUDGET*  
!!
!!    PURPOSE
!!    -------
!
!     Computes the evoultion of building floor temperatures
!         
!     
!!**  METHOD
!     ------
!
!    6 : equations for evolution of Ts_floor 
!        *************************************************************
!
!     dTf_k(t) / dt = 1/(df_k*Cf_k) * (- 2*Kf_k-1*(Tf_k-Tf_k-1)/(df_k-1 +df_k) 
!                                      - 2*Kf_k  *(Tf_k-Tf_k+1)/(df_k+1 +df_k) )
!
!     dTf_1(t) / dt = 1/(df_1*Cf_1) * (- 2*Kw_1*(Tw_1-Tw_2)/(dw_1 +dw_2))
!
!       with
!
!   K*_k  = (d*_k+ d*_k+1)/(d*_k/k*_k+ d*_k+1/k*_k+1)
!
!
! The system is implicited (or semi-implicited).
!
! ZIMPL=1    ---> implicit system
! ZIMPL=0.5  ---> semi-implicit system
! ZIMPL=0    ---> explicit system
!
!
!
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    MODD_CST
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      G. Pigeon           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    11/11
!!      G. Pigeon   09/12 modif internal convection coef
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modi_layer_e_budget_get_coef
USE modi_layer_e_budget
USE mode_conv_doe
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL, DIMENSION(:,:), INTENT(INOUT) :: pt_mass     ! floor layers temperatures
REAL,                 INTENT(IN)    :: ptstep       ! time step
REAL, DIMENSION(:,:), INTENT(IN)    :: phc_mass    ! heat capacity for road layers
REAL, DIMENSION(:,:), INTENT(IN)    :: ptc_mass    ! thermal conductivity for 
                                                    !road layers
REAL, DIMENSION(:,:), INTENT(IN)  :: pd_mass       ! depth of road layers
REAL, DIMENSION(:),   INTENT(OUT)  :: pflx_bld_mass !flux from building to floor
REAL, DIMENSION(:),   INTENT(OUT) :: pdqs_mass !heat storage inside the floor
REAL, DIMENSION(:),   INTENT(OUT) :: pimb_mass !floor energy residual imbalance for verification
REAL, DIMENSION(:), INTENT(IN)    :: pf_mass_wall  ! View factor mass-wall
REAL, DIMENSION(:), INTENT(IN)    :: pf_mass_win   ! View factor mass-window
REAL, DIMENSION(:), INTENT(IN)    :: pf_mass_floor ! View factor mass-floor
REAL, DIMENSION(:), INTENT(IN)    :: pradht_in      ! Indoor radiant heat transfer coefficient
                                                    ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: prad_roof_mass ! rad. fluxes from roof to floor[W m-2(roof)]
REAL, DIMENSION(:), INTENT(IN)    :: prad_wall_mass ! rad. fluxes from wall to floor[W m-2(wall)]
REAL, DIMENSION(:), INTENT(IN)    :: prad_win_mass  ! rad. fluxes from win to floor[W m-2(win)]
REAL, DIMENSION(:), INTENT(IN)    :: pti_bld   ! indoor air temp.
REAL, DIMENSION(:), INTENT(IN)    :: pload_mass ! solar and internal load to the floor
REAL, DIMENSION(:), INTENT(IN)    :: prad_floor_mass  ! rad. fluxes from floor to mass [W m-2(floor)]
REAL, DIMENSION(:), INTENT(OUT)   :: pconv_mass_bld  ! conv. fluxes from floor to bld [W m-2(floor)]
!
!*      0.2    declarations of local variables
!
!
REAL :: zimpl=1.0      ! implicit coefficient
REAL :: zexpl=0.0      ! explicit coefficient
!
REAL, DIMENSION(SIZE(PT_MASS,1),SIZE(PT_MASS,2)) :: za,& ! lower diag.
                                                      zb,& ! main  diag.
                                                      zc,& ! upper diag.
                                                      zy   ! r.h.s.
!
REAL, DIMENSION(SIZE(PT_MASS,1)) :: zts_mass  ! surf. mass temp.
                                              ! used during calculation
REAL, DIMENSION(SIZE(PT_MASS,1)) :: zts_mass_conv  ! surf. mass temp. used for conv flux
REAL, DIMENSION(SIZE(PT_MASS,1)) :: zchtc_in_mass ! Indoor floor convec heat transfer coefficient
                                                ! [W K-1 m-2(bld)]
INTEGER :: jj
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('MASS_LAYER_E_BUDGET',0,zhook_handle)
!
! *Convection heat transfer coefficients [W m-2 K-1] from EP Engineering Reference
!
zchtc_in_mass(:) = chtc_vert_doe(pt_mass(:,1), pti_bld(:)) 
DO jj=1,SIZE(zchtc_in_mass)
   zchtc_in_mass(jj) = max(1., zchtc_in_mass(jj))
ENDDO
!
 CALL layer_e_budget_get_coef( pt_mass, ptstep, zimpl, phc_mass, ptc_mass, pd_mass, &
                              za, zb, zc, zy )
!
zts_mass(:) = pt_mass(:,1) 

zb(:,1) = zb(:,1) + zimpl * 4./3. * zchtc_in_mass(:)

zy(:,1) = zy(:,1)  &
   + zchtc_in_mass(:) * (pti_bld(:) - 1./3. * pt_mass(:, 1) * (4 * zexpl -1.))  &
   + pf_mass_win(:) * prad_win_mass(:)                    &
   + pf_mass_wall(:) * prad_wall_mass(:)                   &
   + pf_mass_floor(:) * (prad_roof_mass(:) +prad_floor_mass(:)) &
   + pload_mass(:)
!
 CALL layer_e_budget( pt_mass, ptstep, zimpl, phc_mass, ptc_mass, pd_mass, &
                     za, zb, zc, zy, pdqs_mass )
!
!*      calculation of temperature used in energy balance calculation
!       -------------------------------------------------------------
!
zts_mass_conv(:) = zimpl * 4./3. * pt_mass(:,1) +1./3 * zts_mass(:) * (4 * zexpl -1.)
zts_mass(:) = zexpl * zts_mass(:) + zimpl * pt_mass(:,1)
!
!*      calculation of convection flux between mass and building air
!       ------------------------------------------------------------
!
pconv_mass_bld(:) = zchtc_in_mass(:) * (zts_mass_conv(:) - pti_bld(:))
!
!*      For diagnostics calculation of flux exchanged between the mass and the
!       indoor
!       ------------------------------------------------
!
pflx_bld_mass(:) = - pconv_mass_bld(:) &
       + pf_mass_win(:) * prad_win_mass(:)                    &
       + pf_mass_wall(:) * prad_wall_mass(:)                   &
       + pf_mass_floor(:) * (prad_roof_mass(:) + prad_floor_mass(:)) &
       + pload_mass(:)
!
!*      Floor residual energy imbalance for verification
!       ------------------------------------------------
!
pimb_mass(:) = pflx_bld_mass(:) - pdqs_mass(:)
!
IF (lhook) CALL dr_hook('MASS_LAYER_E_BUDGET',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE mass_layer_e_budget