layer_e_budget_get_coef.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!   ##########################################################################
    SUBROUTINE layer_e_budget_get_coef(PT, PTSTEP, PIMPL, PHC, PTC, PD, PA, PB, PC, PY)
!   ##########################################################################
!
!!****  *LAYER_E_BUDGET_GET_COEF*  
!!
!!    PURPOSE
!!    -------
!
!     Computes the evoultion of building floor temperatures
!         
!     
!!**  METHOD
!     ------
!
!    6 : equations for evolution of Ts_floor 
!        *************************************************************
!
!     dTf_k(t) / dt = 1/(df_k*Cf_k) * (- 2*Kf_k-1*(Tf_k-Tf_k-1)/(df_k-1 +df_k) 
!                                      - 2*Kf_k  *(Tf_k-Tf_k+1)/(df_k+1 +df_k) )
!
!     dTf_1(t) / dt = 1/(df_1*Cf_1) * (- 2*Kw_1*(Tw_1-Tw_2)/(dw_1 +dw_2))
!
!       with
!
!   K*_k  = (d*_k+ d*_k+1)/(d*_k/k*_k+ d*_k+1/k*_k+1)
!
!
! The system is implicited (or semi-implicited).
!
! ZIMPL=1    ---> implicit system
! ZIMPL=0.5  ---> semi-implicit system
! ZIMPL=0    ---> explicit system
!
!
!
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    MODD_CST
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      G. Pigeon           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    15/04/09 
!!                     08/10 (G. Pigeon) computation of residual of energy balance 
!!                                       modification of the limit condition for
!!                                       the deep temp. from the deep road temp.
!!                                       to zero flux condition. idem for sfce T
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL, DIMENSION(:,:), INTENT(IN) :: pt     ! floor layers temperatures
REAL,                 INTENT(IN) :: ptstep ! time step
REAL, DIMENSION(:,:), INTENT(IN) :: phc    ! heat capacity for road layers
REAL, DIMENSION(:,:), INTENT(IN) :: ptc    ! thermal conductivity for road layers
REAL, DIMENSION(:,:), INTENT(IN) :: pd     ! depth of road layers
REAL, DIMENSION(:,:), INTENT(OUT) :: pa 
REAL, DIMENSION(:,:), INTENT(OUT) :: pb 
REAL, DIMENSION(:,:), INTENT(OUT) :: pc
REAL, DIMENSION(:,:), INTENT(OUT)  :: py
REAL,                 INTENT(IN)   :: pimpl  ! implicitation coefficient
!
!*      0.2    declarations of local variables
!
REAL :: zimpl          ! implicit coefficient
REAL :: zexpl          ! explicit coefficient
!
! mean thermal conductivity over distance between 2 layers
REAL, DIMENSION(SIZE(PT,1),SIZE(PT,2)) :: zmtc_o_d
! thermal capacity times layer depth
REAL, DIMENSION(SIZE(PT,1),SIZE(PT,2)) :: zhc_d
!
INTEGER :: ilayer          ! number of floor layers
INTEGER :: jlayer          ! loop counter
INTEGER :: jj              ! loop counter
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('LAYER_E_BUDGET_GET_COEF',0,zhook_handle)
!
!*      1.     layer thermal properties
!              ------------------------
!
zimpl = pimpl
zexpl = 1. - pimpl
!
ilayer = SIZE(pt,2)
zmtc_o_d(:,:) = 0.
!
DO jlayer=1,ilayer-1
  DO jj=1,SIZE(pt,1)
    zmtc_o_d(jj,jlayer) = 2./( pd(jj,jlayer)/ptc(jj,jlayer) + pd(jj,jlayer+1)/ptc(jj,jlayer+1) )
    zhc_d(jj,jlayer) = phc(jj,jlayer) * pd(jj,jlayer)
  ENDDO
END DO
!
DO jj=1,SIZE(pt,1)
  zhc_d(jj,ilayer) = phc(jj,ilayer) * pd(jj,ilayer)
ENDDO
!
!-------------------------------------------------------------------------------
!
!*      3.    Surface layer coefficients
!             ------------------------------
!
! no implication for Ts and use of flux from BEM or BLD_E_BUDGET
DO jlayer = 1, ilayer
  DO jj = 1, SIZE(pt,1)
    !
    IF ( jlayer == 1 ) THEN 
      pa(jj,jlayer) = 0.
    ELSE
      pa(jj,jlayer) = - zimpl * zmtc_o_d(jj,jlayer-1)
    ENDIF
    !
    IF ( jlayer ==  ilayer ) THEN
      pc(jj,jlayer) = 0. 
    ELSE
      pc(jj,jlayer) = - zimpl * zmtc_o_d(jj,jlayer)
    ENDIF
    !
    pb(jj,jlayer) = zhc_d(jj,jlayer)/ptstep
    py(jj,jlayer) = zhc_d(jj,jlayer)/ptstep * pt(jj,jlayer)
    !
    IF ( jlayer .GT. 1.) THEN
      pb(jj,jlayer) = pb(jj,jlayer) + zimpl * zmtc_o_d(jj,jlayer-1)
      py(jj,jlayer) = py(jj,jlayer) + zexpl * zmtc_o_d(jj,jlayer-1) * ( pt(jj,jlayer-1) - pt(jj,jlayer) )
    ENDIF
    !
    IF ( jlayer .LT. ilayer) THEN
      pb(jj,jlayer) = pb(jj,jlayer) + zimpl * zmtc_o_d(jj,jlayer)
      py(jj,jlayer) = py(jj,jlayer) + zexpl * zmtc_o_d(jj,jlayer) * ( pt(jj,jlayer+1) - pt(jj,jlayer) )
    ENDIF
    !
  ENDDO
  !
ENDDO
!
IF (lhook) CALL dr_hook('LAYER_E_BUDGET_GET_COEF',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE layer_e_budget_get_coef