isba_canopy.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE isba_canopy (I, &
                        ki,klvl,pz,pzf,pdz,pdzf,pheight,pcanopy_density,pu,ptke,   &
                        puw_ground, pduwdu_ground,                                &
                        pforc_u,pdforc_udu,pforc_e,pdforc_ede)  
!     ###############################################################################
!
!!****  *ISBA_CANOPY_n * - prepares forcing for canopy air model
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2006
!!---------------------------------------------------------------
!
!
USE modd_isba_n, ONLY : isba_t
!
USE modd_csts,         ONLY : xrd, xcpd, xp00, xg
USE modd_surf_par,     ONLY : xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_canopy
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(isba_t), INTENT(INOUT) :: i
!
INTEGER,                  INTENT(IN)    :: ki        ! number of points
INTEGER,                  INTENT(IN)    :: klvl      ! number of levels in canopy
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pz        ! heights of canopy levels              (m)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pzf       ! heights of bottom of canopy levels    (m)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pdz       ! depth   of canopy levels              (m)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pdzf      ! depth between canopy levels           (m)
REAL, DIMENSION(KI),      INTENT(IN)    :: pheight     ! canopy height                       (m)
REAL, DIMENSION(KI),      INTENT(IN)    :: pcanopy_density ! canopy density                  (-)

REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pu        ! wind for each canopy layer            (m/s)
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: ptke      ! Tke  for each canopy layer            (m2/s2)
!
REAL, DIMENSION(KI),      INTENT(IN)    :: puw_ground  ! friction flux for ground surface       (m2/s2)
REAL, DIMENSION(KI),      INTENT(IN)    :: pduwdu_ground  ! derivative of ground friction flux   (m/s)
!
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pforc_u   ! tendency of wind due to canopy drag   (m/s2)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pdforc_udu! formal derivative of the tendency of
!                                                    ! wind due to canopy drag               (1/s)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pforc_e   ! tendency of TKE  due to canopy drag   (m2/s3)
REAL, DIMENSION(KI,KLVL), INTENT(OUT)   :: pdforc_ede! formal derivative of the tendency of
!                                                    ! TKE  due to canopy drag               (1/s)
!
!*      0.2    declarations of local variables
!
INTEGER                  :: jlayer, jj    ! loop counter on canopy heights
!         
REAL, DIMENSION(KI,KLVL) :: zcdrag    ! drag coefficient in canopy
REAL, DIMENSION(KI,KLVL) :: zdensity  ! vegetation density for each canopy level
REAL, DIMENSION(KI,KLVL) :: zsv       ! vertical surface for each canopy level
REAL, DIMENSION(KI,KLVL) :: zforc
REAL, DIMENSION(KI,KLVL) :: zairvol   ! Fraction of air for each canopy level total volume
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!
!*      1.     Computations of canopy grid characteristics
!              -------------------------------------------
!
!
!*      1.1    Proportion of leaves for each canopy level 
!             (parabolic shape, maximum at mid canopy height, with the same
!             total LAI on the canopy)
!
IF (lhook) CALL dr_hook('ISBA_CANOPY',0,zhook_handle)
zdensity(:,:) = 0.
DO jlayer = 1,klvl
  DO jj = 1,ki
    IF (pheight(jj)>0.) THEN
      zdensity(jj,jlayer) = 1.5 * &
        max( pcanopy_density(jj)*4.*pz(jj,jlayer)*(pheight(jj)-pz(jj,jlayer))/pheight(jj)**2, 0.)
    ENDIF
  ENDDO
END DO
!
!*      2.1    Drag coefficient by vegetation (Patton et al 2001)
!              ------------------------------
!
zcdrag(:,:) = i%XCDRAG
!
!*      1.4    No building volume
!
! * in order to take into account building volume, further developments must be
!   done in the atmospheric model.
!   If these changes are not done, to take into account building volume in the
!   present routine alone would not be energetically coeherent (there would be
!   too much energy release for heat and vapor or consumed for wind).
!
zairvol(:,:) = 1.
!
!*      1.2    Discretization on each canopy level
!
 CALL canopy(ki, klvl, pzf, pdz, pheight, zdensity, zcdrag, pu, zairvol, &
            zsv, zforc, pforc_u, pdforc_udu, pforc_e, pdforc_ede )
!
!
!*      2.4    Drag force by ground surface
!              ----------------------------
!
pforc_u(:,1) = puw_ground(:) / pdz(:,1)
pdforc_udu(:,1) = pdforc_udu(:,1) + pduwdu_ground(:) / pdz(:,1)

!-------------------------------------------------------------------------------------
!
!*      3.2    Destruction of TKE due to small-scale motions forced by leaves
!              --------------------------------------------------------------
!
! from Kanda and Hino (1994)
!
! Ext = - Cd * e * u  * Sv        trees
!
pforc_e(:,:) = pforc_e    - 2.*ptke(:,:)*zforc(:,:)
pdforc_ede(:,:) = pdforc_ede - 2.*zforc(:,:)
!
IF (lhook) CALL dr_hook('ISBA_CANOPY',1,zhook_handle)
!-------------------------------------------------------------------------------------
!
END SUBROUTINE isba_canopy